639829_it-IT

liliconcom

Aggiunta di testo con riepilogo statistico e posizionamento automatico sotto box plot

Ciao, ho creato un generatore di grafici con lo script generato come segue:

Graph Builder(
 Transform Column( "Unit Number", Nominal, Formula( Char( :"Unit S/N"n ) ) ),
 Size( 570, 817 ),
 Show Legend( 0 ),
 Variables( X( :Unit Number ), Y( :Bounding_Circle_Diameter um ) ),
 Elements( Box Plot( X, Y, Legend( 6 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :Aperture Name ),
   Where( :Aperture Name == "F_4.8" ),
   Display( :Aperture Name, N Items( 3 ), "List Display" )
  )
 ),
 SendToReport(
  Dispatch(
   {},
   "Bounding_Circle_Diameter um",
   ScaleBox,
   {Min( 1500 ), Max( 5000 ), Inc( 500 ), Minor Ticks( 1 )}
  ),
  Dispatch(
   {},
   "graph title",
   TextEditBox,
   {Set Text( "Bounding_Circle_Diameter um (F/4.8)" ), Set Font Size( 20 )}
  ),
  Dispatch( {}, "X title", TextEditBox, {Set Font Size( 18 )} ),
  Dispatch( {}, "Y title", TextEditBox, {Set Font Size( 18 )} ),
  Dispatch(
   {},
   "Graph Builder",
   FrameBox,
   {Reference Line Order( 6 ),
   Add Graphics Script(
    2,
    Description( "" ),
    Text( Center Justified, {0, 2150}, "Range: 44.4638" );
    Text( Center Justified, {0, 2050}, "Mean: 2288.48" );
    Text( Center Justified, {1, 2500}, "Range: 136.315" );
    Text( Center Justified, {1, 2400}, "Mean: 2681.81" );
    Text( Center Justified, {2, 2100}, "Range: 97.6151" );
    Text( Center Justified, {2, 2000}, "Mean: 2278.41" );
   )}
  )
 )
);

Ma il testo e le posizioni sono stati creati manualmente con valori hardcoded. Come si può vedere, i dati vengono filtrati con determinati valori di colonna. C'è un modo per sostituire quei valori hardcoded con le statistiche dai dati rispettivamente?
Posizione Y del testo -> dai valori Min del sottoinsieme di dati
Media -> valore medio dal sottoinsieme di dati
intervallo -> Max - Min dal sottoinsieme di dati

Grazie

Automazione e scriptingEsplorazione e visualizzazione dei datiMac OSRe: Aggiunta di testo con riepilogo statistico e posizionamento automatico sotto box plot

L'elemento Caption può aggiornare automaticamente le statistiche man mano che viene applicato il filtro e ha alcune opzioni su dove posizionare le statistiche.Se stai utilizzando JMP 17, una delle opzioni è posizionare le statistiche in una tabella sotto l'asse.Il mantenimento del posizionamento personalizzato richiederebbe probabilmente l'implementazione di un gestore dello stato di riga JSL per calcolare e sostituire le statistiche tramite script.

 

 

 

dt = Open("$SAMPLE_DATA/Big Class.jmp");
dt << Graph Builder(
 Size( 528, 464 ),
 Show Control Panel( 0 ),
 Variables( X( :age ), Y( :height ) ),
 Elements(
  Box Plot( X, Y, Legend( 6 ) ),
  Caption Box(
   X,
   Y,
   Legend( 7 ),
   Summary Statistic( "Mean" ),
   Summary Statistic 2( "Range" ),
   Location( "Axis Table" )
  )
 ),
 Local Data Filter( Add Filter( columns( :sex ), Where( :sex == "M" ) ) )
);

 

 

Re: Aggiunta di testo con riepilogo statistico e posizionamento automatico sotto box plot

Esiste una metodologia migliore da utilizzare per aggiungere l'output grafico a un grafico.Dai un'occhiata allo script di esempio qui sotto per vedere come determinare dinamicamente dove e cosa visualizzare su un grafico.

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );

// Create the graph
gb = Graph Builder(
 Size( 528, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) )
);

// Access the report output
rgb = gb << report;

// Add a graphics script to the report output
rgb[framebox( 1 )] << add graphics script(

// Find the parametrics of the displayed graph
 xMaxAxis = rgb[AxisBox( 1 )] << get max;
 xMinAxis = rgb[AxisBox( 1 )] << get min;
 yMaxAxis = rgb[AxisBox( 2 )] << get max;
 yMinAxis = rgb[AxisBox( 2 )] << get min;
 
 // Calculate the desired column stats
 heightMean = Col Mean( :height );
 heightRange = Col Max( :height ) - Col Min( :height );
 
 // Calculate the xy position on the graph to display the text
 pos = As List(
  Matrix( (xMinAxis + .1 * (xMaxAxis - xMinAxis)) |/ (yMaxAxis - .1 * (yMaxAxis - yMinaxis)) )
 );

 // Write out the text
 Text( Center Justified, pos, "Mean: " || Format( heightMean, "fixed dec", 7, , 2 ) );
 
 // Change the display position for the next line to be displayed
 pos[2] = pos[2] - .05 * (yMaxAxis - yMinaxis);
 
 // Write out the new line
 Text( Center Justified, pos, "Range: " || Format( heightMean, "fixed dec", 7, , 2 ) );
);

 

Re: Aggiunta di testo con riepilogo statistico e posizionamento automatico sotto box plot

Alcuni punti sull'utilizzo di uno script grafico:

• Il calcolo dello script grafico avverrà ad ogni aggiornamento dello schermo
• Il calcolo non utilizza gli stati di riga, quindi avrà ancora problemi con i filtri
• Se salvi lo script dalla piattaforma e lo riesegui in un secondo momento, non funzionerà perché non è autonomo.Ciò influisce anche sul salvataggio in un flusso di lavoro, progetto, dashboard o in un file JRP.