637577_es-ES

liliconcom

¿Cómo puedo crear una columna de descripción con los nombres de los valores de las celdas y los nombres de las columnas?

Me gustaría etiquetar mis gráficos con los valores y nombres de columna para ese punto (como en un diagrama de caja). Actualmente hago esto en Excel concatenando el nombre de la columna con el valor en las celdas. Sin embargo, si puedo hacerlo en JMP, me ahorraría una cantidad significativa de tiempo.

 

Por ejemplo, puedo tener columnas

 

A B C

1 2 100

1 2 200

2 5 300

 

Me gustaría crear una nueva columna que describa la información en las otras columnas:

A = 1 : B = 2 : C = 100

A = 1 : B = 2 : C = 200

A = 2 : B = 5 : C = 300

 

Hasta ahora he podido crear una lista con los nombres de las columnas, pero no puedo averiguar cómo iterar y concatenar los otros valores.

 

cdt = Tabla de datos actuales ();
NombresCol = {};
EstaEtiqueta = {};
ColNames = cdt << Obtener nombres de columna (cadena);
para(i=3;i<=5;i++)
concat(EstaEtiqueta,NombresCol[i]);

// se requiere más trabajo para obtener los valores de la tabla

 

gracias de antemano

 

 

Automatización y secuencias de comandosRe: ¿Cómo puedo crear una columna de descripción con los nombres de los valores de las celdas y los nombres de las columnas?

Aquí hay una forma de hacer lo que quieras.Mi ejemplo muestra una forma codificada de resolver el problema y también un método más genérico

 

Names Default To Here( 1 );

// Script to create the required column when the names of the columns are known
dt = New Table( "Example 1",
 New Column( "A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 1, 2] ) ),
 New Column( "B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [2, 2, 5] ) ),
 New Column( "C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [100, 200, 300] ) ),
 New Column( "D", Character, Nominal, Formula( "A = " || Char( :A ) || ": B = " || Char( :B ) || ": C = " || Char( :C ) ) )
);

// Example where script examines the data table and from it, generates the new column
dt2 = New Table( "Example 2",
 New Column( "A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 1, 2] ) ),
 New Column( "B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [2, 2, 5] ) ),
 New Column( "C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [100, 200, 300] ) )
);

colNames = dt2 << get column names( string );
// Build the formula in a string variable
theCMD = "dt2 << New Column( \!"D\!", character, Nominal, formula(";
For Each( {col, index}, colNames,
 If( index == 1,
  theCMD = theCMD || "\!" " || col,
  theCMD = theCMD || "\!" : " || col
 );
 theCMD = theCMD || " = \!" || Char( :" || col || ") || ";
);
theCMD = theCMD || "));";
Eval( Parse( theCMD ) );

Re: ¿Cómo puedo crear una columna de descripción con los nombres de los valores de las celdas y los nombres de las columnas?

Si realmente no necesita los nombres de las columnas, una forma más rápida es seleccionar sus 3 columnas, luego hacer clic derecho en uno de los encabezados de columna y seleccionar "Nueva columna de fórmula -> Carácter -> Concatenar con coma".

 

O si realmente necesita los nombres, puede hacer clic con el botón derecho en el nuevo encabezado de columna y seleccionar "Fórmula..." y editar manualmente la fórmula para incluir los nombres de encabezado de columna.Es más lento pero no requiere el paso JSL.

 

Tenga en cuenta que si todas sus columnas son numéricas, es posible que deba agregar una columna temporal que sea una columna de caracteres para que la opción "Carácter" aparezca en la lista "Nueva columna de fórmula".Esperamos que esto se simplifique en una versión futura: https://community.jmp.com/t5/JMP-Wish-List/Enable-string-concatenation-in-quot-New-Formula-Column-quot-gt/idc-p/582366#M3504