637577_ja-JP

liliconcom

セル値と列名を含む説明列を作成するにはどうすればよいですか?

(箱ひげ図のように) その点の値と列名をグラフにラベル付けしたいと考えています。 現在、Excel で列名とセルの値を連結することでこれを行っています。 ただし、それを JMP で実行できれば、時間を大幅に節約できるでしょう。

 

たとえば、列があるとします。

 

A B C

1 2 100

1 2 200

2 5 300

 

他の列の情報を説明する新しい列を作成したいと思います。

A = 1 : B = 2 : C = 100

A = 1 : B = 2 : C = 200

A = 2 : B = 5 : C = 300

 

これまでのところ、列名を含むリストを作成できましたが、他の値を反復して連結する方法がわかりません。

 

cdt = 現在のデータ テーブル();
ColNames = {};
このラベル = {};
ColNames = cdt << Get Column Names( string );
for(i=3;i<=5;i++)
concat(ThisLabel,ColNames[i]);

// テーブルから値を取得するにはさらに多くの作業が必要です

 

前もって感謝します

 

 

自動化とスクリプト作成Re: セル値と列名を含む説明列を作成するにはどうすればよいですか?

ここでは、やりたいことを実現する 1 つの方法を紹介します。私の例では、問題を解決するためのハードコードされた方法と、より一般的な方法を示しています。

 

Names Default To Here( 1 );

// Script to create the required column when the names of the columns are known
dt = New Table( "Example 1",
 New Column( "A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 1, 2] ) ),
 New Column( "B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [2, 2, 5] ) ),
 New Column( "C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [100, 200, 300] ) ),
 New Column( "D", Character, Nominal, Formula( "A = " || Char( :A ) || ": B = " || Char( :B ) || ": C = " || Char( :C ) ) )
);

// Example where script examines the data table and from it, generates the new column
dt2 = New Table( "Example 2",
 New Column( "A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 1, 2] ) ),
 New Column( "B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [2, 2, 5] ) ),
 New Column( "C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [100, 200, 300] ) )
);

colNames = dt2 << get column names( string );
// Build the formula in a string variable
theCMD = "dt2 << New Column( \!"D\!", character, Nominal, formula(";
For Each( {col, index}, colNames,
 If( index == 1,
  theCMD = theCMD || "\!" " || col,
  theCMD = theCMD || "\!" : " || col
 );
 theCMD = theCMD || " = \!" || Char( :" || col || ") || ";
);
theCMD = theCMD || "));";
Eval( Parse( theCMD ) );

Re: セル値と列名を含む説明列を作成するにはどうすればよいですか?

本当に列名が必要ない場合は、3 つの列を選択し、列ヘッダーの 1 つを右クリックして、[新しい数式列 -> 文字 -> カンマで連結] を選択する方が早い方法です。

 

または、本当に名前が必要な場合は、新しい列ヘッダーを右クリックして [数式...] を選択し、手動で数式を編集して列ヘッダー名を含めることができます。速度は遅くなりますが、JSL ステップは必要ありません。

 

すべての列が数値の場合、「新しい数式列」リストに「文字」オプションを表示するには、文字列である一時列を追加する必要がある場合があることに注意してください。これが将来のバージョンで合理化されることを期待しています。 https://community.jmp.com/t5/JMP-Wish-List/Enable-string-concatenation-in-quot-New-Formula-Column-quot-gt/idc-p/582366#M3504