637577_de-DE

liliconcom

Wie kann ich eine Beschreibungsspalte mit den Namen, Zellwerten und Spaltennamen erstellen?

Ich möchte meine Diagramme mit den Werten und Spaltennamen für diesen Punkt beschriften (wie in einem Boxplot). Derzeit mache ich das in Excel, indem ich den Spaltennamen mit dem Wert in den Zellen verkette. Wenn ich es jedoch in JMP tun könnte, würde es mir eine erhebliche Zeitersparnis bringen.

 

Zum Beispiel kann ich Spalten haben

 

A B C

1 2 100

1 2 200

2 5 300

 

Ich möchte eine neue Spalte erstellen, die die Informationen in den anderen Spalten beschreibt:

A = 1 : B = 2 : C = 100

A = 1 : B = 2 : C = 200

A = 2 : B = 5 : C = 300

 

Bisher konnte ich eine Liste mit den Spaltennamen erstellen, konnte aber nicht herausfinden, wie ich die anderen Werte iterieren und verketten kann.

 

cdt = Aktuelle Datentabelle();
ColNames = {};
ThisLabel = {};
ColNames = cdt << Get Column Names( string );
for(i=3;i<=5;i++)
concat(ThisLabel,ColNames[i]);

// Es ist mehr Arbeit erforderlich, um die Werte aus der Tabelle zu erhalten

 

Vielen Dank im Voraus

 

 

Automatisierung und SkripterstellungBetreff: Wie kann ich eine Beschreibungsspalte mit den Namen der Zellenwerte und Spaltennamen erstellen?

Hier ist eine Möglichkeit, das zu tun, was Sie wollen.Mein Beispiel zeigt einen fest codierten Weg zur Lösung des Problems und auch eine allgemeinere Methode

 

Names Default To Here( 1 );

// Script to create the required column when the names of the columns are known
dt = New Table( "Example 1",
 New Column( "A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 1, 2] ) ),
 New Column( "B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [2, 2, 5] ) ),
 New Column( "C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [100, 200, 300] ) ),
 New Column( "D", Character, Nominal, Formula( "A = " || Char( :A ) || ": B = " || Char( :B ) || ": C = " || Char( :C ) ) )
);

// Example where script examines the data table and from it, generates the new column
dt2 = New Table( "Example 2",
 New Column( "A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [1, 1, 2] ) ),
 New Column( "B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [2, 2, 5] ) ),
 New Column( "C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [100, 200, 300] ) )
);

colNames = dt2 << get column names( string );
// Build the formula in a string variable
theCMD = "dt2 << New Column( \!"D\!", character, Nominal, formula(";
For Each( {col, index}, colNames,
 If( index == 1,
  theCMD = theCMD || "\!" " || col,
  theCMD = theCMD || "\!" : " || col
 );
 theCMD = theCMD || " = \!" || Char( :" || col || ") || ";
);
theCMD = theCMD || "));";
Eval( Parse( theCMD ) );

Betreff: Wie kann ich eine Beschreibungsspalte mit den Namen der Zellenwerte und Spaltennamen erstellen?

Wenn Sie die Spaltennamen nicht wirklich benötigen, können Sie schneller Ihre drei Spalten auswählen, dann mit der rechten Maustaste auf eine der Spaltenüberschriften klicken und „Neue Formelspalte -> Zeichen -> Mit Komma verketten“ auswählen.

 

Oder wenn Sie die Namen wirklich benötigen, können Sie mit der rechten Maustaste auf die neue Spaltenüberschrift klicken, „Formel…“ auswählen und die Formel manuell bearbeiten, um die Namen der Spaltenüberschriften einzuschließen.Es ist langsamer, erfordert aber nicht den JSL-Schritt.

 

Beachten Sie: Wenn alle Ihre Spalten numerisch sind, müssen Sie möglicherweise eine temporäre Spalte hinzufügen, die eine Zeichenspalte ist, damit die Option „Zeichen“ in der Liste „Neue Formelspalte“ angezeigt wird.Wir hoffen, dass dies in einer zukünftigen Version optimiert wird: https://community.jmp.com/t5/JMP-Wish-List/Enable-string-concatenation-in-quot-New-Formula-Column-quot-gt/idc-p/582366#M3504