637482_zh-CN

liliconcom

回复：使用日期进行中的项目计数

我可能会把它写成 SQL 查询，但它也可以在 JSL 中完成。 以下是一种可能的选择（有许多更简单和更复杂的选择）

Names Default To Here(1);

dt = New Table("Project Status",
 Add Rows(5),
 New Column("Project", Character, "Nominal", Formula("Project " || Char(Row()))),
 New Column("Start Date", Numeric, "Ordinal", Format("m/d/y", 12), Formula(Date Increment(Today() - In Days(Row() * 10), "Day"))),
 New Column("End Date", Numeric, "Ordinal", Format("m/d/y", 12), Formula(Date Increment(Today() + In Days(Row() * 10), "Day")))
);
dt << Run Formulas;
:Start Date << Delete Formula;
:End Date << Delete Formula;

// Add monthyear column based on Start Date
new_col1 = dt << New Column("MonthYear1",
 Numeric,
 "Ordinal",
 Format("m/y", 12),
 Formula(Date DMY(1, Month(:Start Date), Year(:Start Date)))
);

new_col2 = dt << New Column("MonthYear2",
 Numeric,
 "Ordinal",
 Format("m/y", 12),
 Formula(Date DMY(1, Month(:End Date), Year(:Start Date)))
);

// calculation should be based on min date and max date found from dataset in my opinion
// not based on the found values, but this is easier so I'll use this
date_months = Associative Array(new_col1);
date_months << Insert(Associative Array(new_col2));
dt << Delete Columns({"MonthYear1", "MonthYear2"});

aa_results = Associative Array();

For Each({month_start}, date_months << get keys,
 // last day of month
 max_day = In Days(Days In Month(Year(month_start), Month(month_start))) + month_start - Time Of Day(month_start);
 // some logic to get projects
 r = dt << Get Rows Where((:Start Date <= month_start & :End Date >= month_start) | (month_start <= :Start Date < max_day));
 aa_results[month_start] = N Items(r);
);

dt_results = New Table("Results",
 New Column("MY", Numeric, Continuous, Values(aa_results << get keys)),
 New Column("ProjInProg", Numeric, Continuous, Values(aa_results << get values)),
);

 

使用日期进行中的项目计数

你好，我制作了这个示例数据集来展示我正在解决的问题：

New Table("Project Status",
 Add Rows(5),
 New Column("Project", Character, "Nominal", Formula("Project " || Char(Row()))),
 New Column("Start Date", Numeric, "Ordinal", Format("m/d/y", 12), Formula(Date Increment( Today() - In Days( Row() * 10 ), "Day" ))),
 New Column("End Date", Numeric, "Ordinal", Format("m/d/y", 12), Formula(Date Increment( Today() + In Days( Row() * 10 ), "Day" )))
);

以下代码将创建一个 5x3 数据表，其中包含 5 个不同项目的开始日期和结束日期。 我想做的是计算数据集中所有月/年组合的“正在进行的项目”。 我的意思是，任何开始日期的项目都应计入该月，直到结束日期已过。 这是我希望制作的图像示例：

 

有没有办法使用 JSL 将这些计数放入自己的数据表中？

 

请让我知道是否可以提供有关我要完成的工作的更多信息。

 

谢谢

高级统计建模自动化和脚本内容组织数据访问大规模定制质量与工艺工程