637482_zh-TW

liliconcom

回复：使用日期進行中的項目計數

我可能會把它寫成 SQL 查詢，但它也可以在 JSL 中完成。 以下是一種可能的選擇（有許多更簡單和更複雜的選擇）

Names Default To Here(1);

dt = New Table("Project Status",
 Add Rows(5),
 New Column("Project", Character, "Nominal", Formula("Project " || Char(Row()))),
 New Column("Start Date", Numeric, "Ordinal", Format("m/d/y", 12), Formula(Date Increment(Today() - In Days(Row() * 10), "Day"))),
 New Column("End Date", Numeric, "Ordinal", Format("m/d/y", 12), Formula(Date Increment(Today() + In Days(Row() * 10), "Day")))
);
dt << Run Formulas;
:Start Date << Delete Formula;
:End Date << Delete Formula;

// Add monthyear column based on Start Date
new_col1 = dt << New Column("MonthYear1",
 Numeric,
 "Ordinal",
 Format("m/y", 12),
 Formula(Date DMY(1, Month(:Start Date), Year(:Start Date)))
);

new_col2 = dt << New Column("MonthYear2",
 Numeric,
 "Ordinal",
 Format("m/y", 12),
 Formula(Date DMY(1, Month(:End Date), Year(:Start Date)))
);

// calculation should be based on min date and max date found from dataset in my opinion
// not based on the found values, but this is easier so I'll use this
date_months = Associative Array(new_col1);
date_months << Insert(Associative Array(new_col2));
dt << Delete Columns({"MonthYear1", "MonthYear2"});

aa_results = Associative Array();

For Each({month_start}, date_months << get keys,
 // last day of month
 max_day = In Days(Days In Month(Year(month_start), Month(month_start))) + month_start - Time Of Day(month_start);
 // some logic to get projects
 r = dt << Get Rows Where((:Start Date <= month_start & :End Date >= month_start) | (month_start <= :Start Date < max_day));
 aa_results[month_start] = N Items(r);
);

dt_results = New Table("Results",
 New Column("MY", Numeric, Continuous, Values(aa_results << get keys)),
 New Column("ProjInProg", Numeric, Continuous, Values(aa_results << get values)),
);

 

使用日期進行中的項目計數

你好，我製作了這個示例數據集來展示我正在解決的問題：

New Table("Project Status",
 Add Rows(5),
 New Column("Project", Character, "Nominal", Formula("Project " || Char(Row()))),
 New Column("Start Date", Numeric, "Ordinal", Format("m/d/y", 12), Formula(Date Increment( Today() - In Days( Row() * 10 ), "Day" ))),
 New Column("End Date", Numeric, "Ordinal", Format("m/d/y", 12), Formula(Date Increment( Today() + In Days( Row() * 10 ), "Day" )))
);

以下代碼將創建一個 5x3 數據表，其中包含 5 個不同項目的開始日期和結束日期。 我想做的是計算數據集中所有月/年組合的“正在進行的項目”。 我的意思是，任何開始日期的項目都應計入該月，直到結束日期已過。 這是我希望製作的圖像示例：

 

有沒有辦法使用 JSL 將這些計數放入自己的數據表中？

 

請讓我知道是否可以提供有關我要完成的工作的更多信息。

 

謝謝

高級統計建模自動化和腳本內容組織數據訪問大規模定制質量與工藝工程