634328_es-ES

liliconcom

¿Puede JMP Tabulate proporcionar cambios relativos de datos paramétricos en relación con un punto de referencia en el tiempo (como tablas dinámicas)?

Tengo muchos conjuntos de datos que normalmente reviso con tablas dinámicas de Excel, pero me pregunto si sería posible usar tablas tabuladas en JMP para revisarlos de manera similar.

Los datos se parecen al ejemplo de la tabla de Excel adjunta. Se prueban cuatro dispositivos cinco veces: a las 0 h, 1 h, 20 h, 50 h y 100 h.

En cada medición se miden los parámetros 1 y 2. Me gustaría una tabla con datos en tres columnas.

para cada dispositivo/hora: Valor de los datos, Diferencia en el valor de los datos relativa a la primera medición, Diferencia en el valor de los datos en porcentaje relativa a la primera medición.

Hoy importo conjuntos de datos muy grandes a JMP (10-100 parámetros, miles de dispositivos) y exporto datos a Excel.

para crear tablas dinámicas que reorganizan los datos con tablas dinámicas para agregar las columnas que muestran cambios paramétricos

y luego importo datos nuevamente a JMP para graficarlos, analizar la degradación, realizar gráficos de correlación, etc.

Por supuesto, puedo hacer esto en JMP con scripts que dividen la tabla, agregan nuevas columnas con fórmulas, las apilan, renombran nuevas columnas, etc., pero esa es una forma muy inflexible de hacerlo y no he encontrado una forma de hacerlo dinámicamente sin codificar los tiempos de prueba.

Lamentablemente, trabajar con las tablas dinámicas de Excel es mucho más sencillo, pero no me gusta el hecho de tener que ir y volver a Excel.

con todos los datos.

¿Alguna idea de si esto se puede hacer en JMP con las tablas tabuladas?

Automatización y scriptingAcceso a datosCombinación y limpieza de datosExploración y visualización de datosPersonalización masivaIngeniería de Calidad y ProcesosAnálisis de confiabilidadRe: ¿JMP Tabulate puede proporcionar cambios relativos de datos paramétricos relativos a un punto de referencia en el tiempo (como tablas dinámicas)?

Creo que tendrá que agregar un par de fórmulas y luego puede crear una tabla de tabulación/resumen como esta

Crearía una columna para calcular el valor cero. Dependiendo de sus datos, se podría usar algo más simple (o más complicado)

Col Mean(
 If(Col Min(:Time, :Device, :Group, :Batch, :Name) == :Time,
  :Value,
  .
 ),
 :Device, :Group, :Batch, :Name
);

Luego crea las columnas de cálculo.

:Value / :GroupZero - 1

y

:Value - :GroupZero

 

A continuación se muestra el script que JMP creó para mí (lo limpiaría mucho y lo haría más robusto)

// Delete column: Column 7
Data Table("Data") << Delete Columns(:Column 7);

// New column: Column 7
Data Table("Data") << New Column("Column 7",
 Numeric,
 "Continuous",
 Format("Best", 12)
);

// Change column info: GroupZero
Data Table("Data"):Column 7 << Set Name("GroupZero") <<
Set Formula(
 Col Mean(
  If(Col Min(:Time, :Device, :Group, :Batch, :Name) == :Time,
   :Value,
   .
  ),
  :Device,
  :Group,
  :Batch,
  :Name
 )
);

// New column: Column 8
Data Table("Data") << New Column("Column 8",
 Numeric,
 "Continuous",
 Format("Best", 12)
);

// Change column info: Diff to 0
Data Table("Data"):Column 8 << Set Name("Diff to 0") <<
Set Formula(:Value - :GroupZero);

// New column: Column 9
Data Table("Data") << New Column("Column 9",
 Numeric,
 "Continuous",
 Format("Best", 12)
);

// Change column info: Diff to 0perc
Data Table("Data"):Column 9 << Set Name("Diff to 0perc") << Format("Percent", 12, 2)
 << Set Formula(:Value / :GroupZero - 1);

// Change column modeling type: Device
Data Table("Data"):Device << Set Modeling Type("Nominal");

// Change column modeling type: Batch
Data Table("Data"):Batch << Set Modeling Type("Nominal");

// Change column modeling type: Time
Data Table("Data"):Time << Set Modeling Type("Nominal");

// Report snapshot: Data - Tabulate
Tabulate(
 Show Control Panel(0),
 Add Table(
  Column Table(Analysis Columns(:Value), Statistics(Mean)),
  Column Table(Analysis Columns(:Diff to 0, :Diff to 0perc), Statistics(Mean)),
  Row Table(Grouping Columns(:Device, :Group, :Batch, :Name, :Time))
 )
);

 

Re: ¿JMP Tabulate puede proporcionar cambios relativos de datos paramétricos relativos a un punto de referencia en el tiempo (como tablas dinámicas)?

¡Guau! Gracias Jarmo!

 

Nunca imaginé que Col Mean podría usarse de esa manera...

Obviamente me he perdido algunos conceptos básicos.

Muchas, muchas gracias, tengo que hacer una limpieza seria en mis guiones

 

/Jessica