일반적으로 Excel 피벗 테이블로 검토하는 데이터 세트가 많이 있지만, JMP에서 표 형태로 된 테이블을 사용하여 비슷한 방식으로 검토할 수 있을지 궁금합니다.
데이터는 첨부된 Excel 표의 예와 같습니다. 4개의 장치를 0h, 1h, 20h, 50h, 100h로 5번 테스트합니다.
각 측정에서 매개변수1과 매개변수2가 측정됩니다. 트리 열에 데이터가 있는 테이블을 원합니다.
각 장치/시간에 대해: 데이터 값, 첫 번째 측정값을 기준으로 한 데이터 값의 차이, 첫 번째 측정값을 기준으로 한 데이터 값의 차이 백분율.
오늘 저는 매우 큰 데이터 세트(10-100개의 매개변수, 수천 개의 장치)를 JMP로 가져오고 Excel로 데이터를 내보냅니다.
피벗 테이블을 생성하여 매개변수 변경 사항을 보여주는 열을 추가하여 데이터를 재구성합니다.
그 후 플로팅, 저하 분석, 상관 관계 플롯 등을 위해 JMP로 데이터를 다시 가져옵니다.
물론 JMP에서 스크립트를 사용하여 테이블을 분할하고, 수식을 사용하여 새 열을 추가하고, 이를 스택하고, 새 열의 이름을 바꾸는 등의 작업을 할 수는 있지만, 이는 매우 융통성이 없는 방법이고, 테스트 시간을 하드 코딩하지 않고는 동적으로 이 작업을 수행할 방법을 찾지 못했습니다.
불행히도 Excel 피벗 테이블은 작업하기가 훨씬 쉽습니다. 하지만 Excel로 앞뒤로 이동해야 한다는 사실이 마음에 들지 않습니다.
모든 데이터를 포함하여.
JMP에서 표 형식으로 이 작업을 할 수 있을지에 대한 아이디어가 있나요?
몇 가지 수식을 추가해야 한다고 생각하고 다음과 같이 표/요약 표를 만들 수 있습니다.
Zero 값을 계산하는 열을 만들겠습니다. 데이터에 따라 더 간단한(또는 더 복잡한) 것을 사용할 수 있습니다.
Col Mean(
If(Col Min(:Time, :Device, :Group, :Batch, :Name) == :Time,
:Value,
.
),
:Device, :Group, :Batch, :Name
);
그런 다음 계산 열을 만듭니다.
:Value / :GroupZero - 1
그리고
:Value - :GroupZero
아래는 저에게 JMP가 만든 스크립트입니다(많이 정리하고 더 견고하게 만들겠습니다).
// Delete column: Column 7
Data Table("Data") << Delete Columns(:Column 7);
// New column: Column 7
Data Table("Data") << New Column("Column 7",
Numeric,
"Continuous",
Format("Best", 12)
);
// Change column info: GroupZero
Data Table("Data"):Column 7 << Set Name("GroupZero") <<
Set Formula(
Col Mean(
If(Col Min(:Time, :Device, :Group, :Batch, :Name) == :Time,
:Value,
.
),
:Device,
:Group,
:Batch,
:Name
)
);
// New column: Column 8
Data Table("Data") << New Column("Column 8",
Numeric,
"Continuous",
Format("Best", 12)
);
// Change column info: Diff to 0
Data Table("Data"):Column 8 << Set Name("Diff to 0") <<
Set Formula(:Value - :GroupZero);
// New column: Column 9
Data Table("Data") << New Column("Column 9",
Numeric,
"Continuous",
Format("Best", 12)
);
// Change column info: Diff to 0perc
Data Table("Data"):Column 9 << Set Name("Diff to 0perc") << Format("Percent", 12, 2)
<< Set Formula(:Value / :GroupZero - 1);
// Change column modeling type: Device
Data Table("Data"):Device << Set Modeling Type("Nominal");
// Change column modeling type: Batch
Data Table("Data"):Batch << Set Modeling Type("Nominal");
// Change column modeling type: Time
Data Table("Data"):Time << Set Modeling Type("Nominal");
// Report snapshot: Data - Tabulate
Tabulate(
Show Control Panel(0),
Add Table(
Column Table(Analysis Columns(:Value), Statistics(Mean)),
Column Table(Analysis Columns(:Diff to 0, :Diff to 0perc), Statistics(Mean)),
Row Table(Grouping Columns(:Device, :Group, :Batch, :Name, :Time))
)
);
우와! 자모 감사합니다!
나는 Col Mean이 그런 식으로 사용될 수 있다고 결코 생각하지 않습니다 ...
분명히 몇 가지 기본 사항을 놓친 경우.
많은 감사를 드립니다. 스크립트를 정리할 수 있게 되었습니다. 
/제시카
