285869_ja-JP

liliconcom

グラフビルダー - 列のグループを含む箱ひげ図?

複数の列を含む小さなデータセットがあります。

これらの列の一部はグループ化されています。 グラフ ビルダーで、個別の列ではなく、グループごとのデータを含む単一の箱ひげ図を作成できますか?

 

 

データ表グラフィックスRe: グラフ ビルダー - 列のグループを含む箱ひげ図?

これを行う方法は簡単です

1. 柱を積み重ねる
2. データをグループ化する新しい列を作成する
3. グループ化列を X 軸としてグラフ ビルダーを実行します。

以下は JSL を使用した例ですが、スクリプトの各ステップは対話的に簡単に実行できます。以下のスクリプトを参照してください

names default to here(1);

// Create a sample data table for illustration
dt=new table("TO_CPTO_C",
 add rows(5),
 new column("A.1", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("A.2", formula(randomuniform(70,140)),format("fixed dec",6,2)), 
 new column("A.3", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("A.4", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("A.5", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("A.6", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("B.1", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("B.2", formula(randomuniform(70,140)),format("fixed dec",6,2)), 
 new column("B.3", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("B.4", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("C.1", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("C.2", formula(randomuniform(70,140)),format("fixed dec",6,2)), 
 new column("C.3", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("C.4", formula(randomuniform(70,140)),format("fixed dec",6,2))
);

// Pause so one can see initial data table before moving on
Wait( 5 );

// Stack the columns
// Tables==>Stack
dtStack = dt << Stack(
 columns(
  :A.1,
  :A.2,
  :A.3,
  :A.4,
  :A.5,
  :A.6,
  :B.1,
  :B.2,
  :B.3,
  :B.4,
  :C.1,
  :C.2,
  :C.3,
  :C.4
 ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Data" )
);

// Pause so one can see stacked data table before moving on
Wait( 5 );

// Create a grouping column
dtStack << New Column("Group", character, formula( left(:Label,1 )));

// Pause so one can see new column before moving on
Wait( 5 );

// Create the Graph, using the Group column as the X axis and Data as the Y axis
dtStack << Graph Builder(
 Size( 534, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :Group ), Y( :Data ) ),
 Elements( Box Plot( X, Y, Legend( 3 ) ) )
);

 

Re: グラフ ビルダー - 列のグループを含む箱ひげ図?

質問を誤解している可能性があります。将来、JMP データ テーブルを添付すると表示しやすくなるかもしれませんが、A、B、C 列を積み重ねることができるので、A、B の 3 つのデータ列ができます。そしてCラベル。