访问健身组项目你好，
我不明白什么是拟合组（矩阵、列表……）。
如何向适合组中的特定对象发送命令？
谢谢。
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Group = Fit Group(
Bivariate (Y( :weight ),X( :height )),
Oneway (Y( :weight ),X( :age )),
Oneway (Y( :weight ),X( :sex )));
//在第一个oneway上运行分位数的方法是什么？
Group[Oneway(2)] << Quantiles(1);//this doesn't work
回复：访问适合组项目这里有两种方法：
- 保存对组内每个对象的引用。
- 在组的显示树中找到对象。
Names default to here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
//The easy way: save references to each element
Group = Fit Group(
bv1 = Bivariate ( Y( :weight ),X( :height ) ),
ow1 = Oneway (Y( :weight ),X( :age )),
ow2 = Oneway (Y( :weight ),X( :sex ))
);
//And send messages like you normally would
ow1 << Quantiles(1);
//The harder way is to find the analysis in the tree structure:
((Group << Find( OutlineBox(5) ) ) << Get Scriptable Object) << Quantiles(1);
//Here is how I put the second method together:
//Find the OutlineBox to reference, note the 'helpkey' to verify that you at the right spot
Group << Show Tree Structure;
//Get a reference to the child outlinebox
Group << Find( OutlineBox(5) );
//Get the object that is normally returned from that function, similar to ow2
((Group << Find( OutlineBox(5) ) ) << Get Scriptable Object)
