Merging JSL setup using "Join"

osbornsarah9

I found I can merge two data sets best by using the "Join" data tables command, this best elminates possible duplicate entries that may exist - column 1 contains unique number for each entry.  I have a script which opens multiple data tables and manipulates the data, but I'm having trouble calling out each data table separately in order to get the "join" script to work correctly:

If I am manually doing this the code is as such:

Data Table( "Untitled 322" ) << Join(Data Table( "Untitled 318" )),

                                  Merge Same Name Columns,

                                  By Matching Columns(:REPLICATE_ID = :REPLICATE_ID ),

                                  Drop multiples(1, 1),

                                  Name("Include non-matches" )(1, 1),

                                  Preserve main table order(1),

                                  Output Table("Merged")

My problem comes in when I try to code this form multiple tables.  The Untitled tables (untitled 322, untitled 318, etc - there may be more depending how many files i open) are designated in my code as .  So I want to somehow take my max and join with every other w.

I set up something as follows:

For (f = Data Table , f >= 1, f--,

     Try(v = w << Join( With(Data Table (f)),

                    *and the rest follows the join table properties listed above*

However my code doesn't work.  Anyone have an idea how I can do this?

ms

Looks like all tables are closed prior the Join(). The List OTs is just a list of datatable references. They are not "scriptable objects" if the corresponding tables are gone.

Try something like this:

my_path = "/Users/.../Files/"; //path to directory of the.txt files

flist = Files In Directory( my_path ); //List of all files

n = N Items( flist );

// Remove non-text files from flist

For( i = n, i > 0, i--,

  If( Contains( flist[i], ".txt" ) == 0,

  Remove From( flist, i );

  n--;

  )

);

// Function for open text files (edit column and import settings if necessary)

open_file = Function( {x},

  Open(

  my_path || flist[x],

  Import Settings(

  End Of Line( CRLF, CR, LF ),

  End Of Field( Tab ),

  Strip Quotes( 1 ),

  Use Apostrophe as Quotation Mark( 0 ),

  Scan Whole File( 1 ),

  Labels( 1 ),

  Column Names Start( 1 ),

  Data Starts( 2 ),

  Lines To Read( All ),

  Year Rule( "10-90" )

  )

  )

);

// Open first file

MT = open_file( 1 );

//Join all files in flist

For( i = 2, i <= n, i++,

  ST = open_file( i );

  FT = MT;

  MT = FT << Join(

  With( ST ),

  Update,

  By Matching Columns( :Column_1 = :Column_1 ),

  Drop multiples( 1, 0 ),

  Name( "Include non-matches" )(1, 1),

  Preserve main table order( 1 ),

  Output Table( "Merged" )

  );

  // Clean up

  Close( ST, no save );

  Close( FT, no save );

);