629144_es-ES

liliconcom

Re: Cuadro combinado GUI basado en dos columnas relacionadas

Debe agregar una función (o secuencia de comandos) para limitar las opciones en el segundo cuadro combinado. Una opción a continuación (creo que debería funcionar con JMP14)

Names Default To Here(1);

v1 = "";
v2 = "";

dt = Open("$DOWNLOADS/JMP_Question.xlsx", Worksheets("Sheet1"), invisible);

Summarize(dt, uniqvals = by(:Column 1));

aa_options = Associative Array();
For(i = 1, i <= N Items(uniqvals), i++,
 col1_idx = dt << Get Rows Where(:Column 1 == uniqvals[i]);
 col2_vals = dt[col1_idx, "Column 2"];
 aa_options[uniqvals[i]] = col2_vals;
);



nw = New Window("Set the Value",
 Lineup Box(N Col(2),
  Text Box("Col1"), 
  cb1 = Combo Box(uniqvals, << set function(function({this},
   cb2_vals = aa_options[(this << get selected)];
   cb2 << Set Items(cb2_vals);
  )), << Set(1)
  ),
  Text Box("Col2"), 
  cb2 = Combo Box(aa_options[uniqvals[1]])
 ),
 H List Box(
  Button Box("OK", 
   v1 = cb1 << get selected;
   v2 = cb2 << get selected;
   nw << close window;
   show(v1, v2);
  ),
  Button Box("Cancel", nw << close window)
 )
);

Re: Cuadro combinado GUI basado en dos columnas relacionadas

Gracias Jarmo! Hiciste que pareciera fácil.

 

Funcionó.

Re: Cuadro combinado GUI basado en dos columnas relacionadas

Hola Jarmo,

 

Otro problema que he tenido con el cuadro de diálogo es tomar una lista como entrada.

 

Si uso el siguiente código.

 

Names Default To Here(1);

v1 = "";
v2 = "";

dt = Open("JMP_Question.xlsx", Worksheets("Sheet1"), invisible);

Summarize(dt, uniqvals = by(:Column 1));

aa_options = Associative Array();
For(i = 1, i <= N Items(uniqvals), i++,
 col1_idx = dt << Get Rows Where(:Column 1 == uniqvals[i]);
 col2_vals = dt[col1_idx, "Column 2"];
 aa_options[uniqvals[i]] = col2_vals;
);



nw = New Window("Set the Value",
 Lineup Box(N Col(2),
  Text Box("Col1"),
  cb1 = Combo Box(
   uniqvals,
   <<SET function=""></SET>

 

No está tomando la lista como entrada. ¿Estoy haciendo algo mal?

 

¡Gracias!

 

 

 

 

Re: Cuadro combinado GUI basado en dos columnas relacionadas

Incluso si JMP le permite poner la lista en el cuadro de texto (no estoy seguro de por qué, creo que debería arrojar un error), sigue siendo una cadena (lo más probable es que JMP realice una conversión), por lo que no puede hacer referencia directamente con el índice.

 

Puede dividirlo en una lista usando Words (y tal vez sustituir para eliminar caracteres adicionales como corchetes) o Parse() en una lista

Names Default To Here(1);

nw = new window("",
 tb = Text Edit Box({"list1", "list2", "list3"}), 
);

tb_txt = tb << get text;

show(tb_txt);
show(type(tb_txt));

show(Parse(tb << get text));
show(type(Parse(tb << get text)));

Re: Cuadro combinado GUI basado en dos columnas relacionadas

Hola Jarmo,

 

Si trato de aplicar la solución a tres columnas, funciona. Sin embargo, no puedo crear una selección única basada en la primera Y la segunda columna.

 

Names Default To Here(1);

v1 = "";
v2 = "";
v3 = "";

dt = Open("JMP_Question.xlsx", Worksheets("Sheet1"), invisible);

Summarize(dt, uniqvals_1 = by(:Column 1));
Summarize(dt, uniqvals_2 = by(:Column 2));
Summarize(dt, uniqvals_3 = by(:Column 2,:Column 3));



aa_options = Associative Array();
For(i = 1, i <= N Items(uniqvals_1), i++,
 col1_idx = dt << Get Rows Where(:Column 1 == uniqvals_1[i]);
 col2_vals = dt[col1_idx, "Column 2"];
 aa_options[uniqvals_1[i]] = col2_vals;
);

ab_options = Associative Array();
For(i = 1, i <= N Items(uniqvals_2), i++,
 col2_idx = dt << Get Rows Where(:Column 2 == uniqvals_2[i]);
 col3_vals = dt[col2_idx, "Column 3"];
 ab_options[uniqvals_2[i]] = col3_vals;
);

/*
ac_options = Associative Array();
For(i = 1, i <= N Items(uniqvals_1), i++,
 col1_idx = dt << Get Rows Where(:Column 1 == uniqvals_1[i]);
 col2_vals = dt[col1_idx, "Column 2"];
 
 For(j=1, j<=N Items(uniqvals_2),j++
 
  col2_idx = dt << Get Rows Where(:Column 2 == uniqvals_2[j]);
  col3_vals = dt[col2_idx, "Column 3"];
  ac_options[uniqvals_2[j]] = col3_vals;
  
 );
 
);
*/

print(ac_options);


nw = New Window("Set the Value",
 Lineup Box(N Col(2),
  Text Box("Col1"), 
  cb1 = Combo Box(uniqvals_1, << set function(function({this},
   
   cb2_vals = aa_options[(this << get selected)];
   cb2 << Set Items(cb2_vals);

  )), << Set(1)
  ),
  
  Text Box("Col2"), 
  cb2 = Combo Box(uniqvals_2, << set function(function({this},
  
   cb3_vals = ab_options[(this << get selected)];
   cb3 << Set Items(cb3_vals);
   
  )), << Set(1)
  ),
  
  Text Box("Col3"), 
  cb3 = Combo Box(ab_options[uniqvals_2[1]])
 ),
 H List Box(
  Button Box("OK", 
   v1 = cb1 << get selected;
   v2 = cb2 << get selected;
   v3 = cb3 << get selected;
   nw << close window;
   show(v1, v2, v3);
  ),
  Button Box("Cancel", nw << close window)
 )
);

El código anterior funciona. Sin embargo, si observa las imágenes adjuntas, no puedo crear listas únicas para Col2 y Col3.

 

Probablemente hay una solución sencilla que me falta.

 

¡Gracias!

Re: Cuadro combinado GUI basado en dos columnas relacionadas

Puede crear una nueva columna que sea una combinación de: Columna 1 y: Columna 2 y usar eso para las teclas

Cuadro combinado de GUI basado en dos columnas relacionadas

Hola,

 

Si tengo dos columnas en un archivo, puedo crear un cuadro combinado usando las dos columnas por separado (vea el archivo JSL adjunto). Sin embargo, lo que realmente quiero es que una vez que seleccione la primera opción (por ejemplo, "a"), debería restringir las opciones de mi segundo cuadro a "a1", "a2" y "a3" únicamente. Ver el archivo de Excel adjunto.

 

Cualquier ayuda sería apreciada.

 

v1 = "m";
v2 = "n";

dt = Open("JMP_Question.xlsx", Worksheets("Sheet1"), invisible);

subDt1 = dt << Subset(Columns(:Column 1), invisible);
Summarize(col1_unique_vals = by(Column 1));
subDt2 = dt << Subset(Columns(:Column 2), invisible);
Summarize(col2_unique_vals = by(Column 2));


win = New Window("Set the Value",
 H List Box(Text Box("Col1"), combo_box1 = Combo Box(col1_unique_vals)),
 H List Box(Text Box("Col2"), combo_box2 = Combo Box(col2_unique_vals)), 

 H List Box(
  Button Box("OK", 

   v1 = combo_box1 << get selected;
   v2 = combo_box2 << get selected;

   win << close window;

  ), 

//a cancel button that closes the window and doesn't store store the results
  Button Box("Cancel", win << close window)
 )
);

 

Versión JMP - JMP Pro 14

Automatización y secuencias de comandosIngeniería de Calidad y Procesos