nav[aria-label="Primary Navigation"] { padding: 0; & ul { list-style: none; width: 100%; display: flex; flex-direction: row; justify-content: start; align-items: start; gap: 30px; padding: 0; & li { margin: 0; } & ul li { list-style: none; } } }

How to pass a variable in the formula of custom profiler

flo_kussener

We can define a custom formula in the custom profiler and it is quite easy, as the following example shows

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );
obj = Custom Profiler( Y( :Pred Formula ABRASION, :Pred Formula MODULUS ) );
obj << Objective Formula(
	:Pred Formula ABRASION + .5 * :Pred Formula MODULUS
);
obj << Optimize;

Now, let's say that I would like to change the coefficient value from 0.5 to another setting. So I define the following formula:

coef=4;
myFormula=Parse(eval(EvalExpr(":Pred Formula ABRASION + "||Char(coef)||" * :Pred Formula MODULUS")));

the result in the log is ok:

:Pred Formula ABRASION + 4 * :Pred Formula MODULUS

but, if I use the same sentence in the previous statement, I do not succeed to have the expected result:

obj << Objective Formula(Parse(eval(EvalExpr(":Pred Formula ABRASION + "||Char(coef)||" * :Pred Formula MODULUS"))));

I probably did a basic mistake, but I am having trouble with it. and I would like to adapt this method to a more complex situation (change desirability coeffcients in the native expression)
Thank you for your suggestions

Accepted answers

DonMcCormack

Florence,

In general, it's preferable to treat expression as expressions rather than text string to be evaluated. This will work:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );
obj = Custom Profiler( Y( :Pred Formula ABRASION, :Pred Formula MODULUS ) );


cVal = 4;

Eval(Substitute(
	Expr(
		obj << Objective Formula(
			:Pred Formula ABRASION + coefVal * :Pred Formula MODULUS
		)
	),
	Expr(coefVal),cVal
));

obj << Optimize;

Don

All comments

DonMcCormack

Florence,

In general, it's preferable to treat expression as expressions rather than text string to be evaluated. This will work:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );
obj = Custom Profiler( Y( :Pred Formula ABRASION, :Pred Formula MODULUS ) );


cVal = 4;

Eval(Substitute(
	Expr(
		obj << Objective Formula(
			:Pred Formula ABRASION + coefVal * :Pred Formula MODULUS
		)
	),
	Expr(coefVal),cVal
));

obj << Optimize;

Don

flo_kussener

Hi Don,

Thank a lot for your answer.
In this basic example, it works pretty well, as my formula is simple.
In the real life, I have a more complex situation. I want to be able to set the content of desirabilities that I will catch from a data table.

y1_target_value=175;
y1_min=150;
y1_max=200;

y2_target=500;
y2_min=450;
y2_max=550;



Eval(Substitute(
	Expr(
		obj << Objective Formula(
			Exp((0.25 * Log(Desirability([100, y1_target, 200], [0.0183, 1, 0.0183], Pred Formula Abrasion)) + 0.25 * Log(Desirability([400, 475, 550], [0.0183, 1, 0.0183], Pred Formula Elongation))) / 0.5)
		)
	),
	Expr(y1_target),y1_target_value
));

obj << Optimize;

if I apply the substitute in this case, I have an error.

and yes.... I want to change the content of the 6 variables (target and spec for the two Y)!!

thank you for your suggestions,

Florence

DonMcCormack

Florence,

The issue has to do with the way the matrix operator (the open and close square brackets) work. The simplest approach I can think of is to create the matrices beforehand and treat them as a whole, rather than trying to construct them in Substitute. This should work

y1_target_value=175;
y1_min=150;
y1_max=200;

y2_target=500;
y2_min=450;
y2_max=550;

y1Mat = Matrix({y1_min,y1_target_value,y1_max});
y2Mat = Matrix({y2_min,y2_target,y1_max});

Eval(Substitute(
	Expr(
		obj << Objective Formula(
			Exp((0.25 * Log(Desirability(y1Mat, [0.0183, 1, 0.0183], Pred Formula Abrasion)) + 0.25 * Log(Desirability(y2Mat, [0.0183, 1, 0.0183], Pred Formula Elongation))) / 0.5)
		)
	),
	Expr(y1Mat),y1Mat,
	Expr(y2Mat),y2Mat,
));

obj << Optimize;

Jed_Campbell

I feel like I'm missing something here. Why use the Expr/Eval, etc. instead of just putting the formula in?

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );

y1_target_value = 175;
y1_min = 150;
y1_max = 200;

y2_target = 500;
y2_min = 450;
y2_max = 550;

y1Mat = Matrix( {y1_min, y1_target_value, y1_max} );
y2Mat = Matrix( {y2_min, y2_target, y1_max} );

obj = Custom Profiler( Y( :Pred Formula ABRASION, :Pred Formula MODULUS ) );

obj << Objective Formula(
	Exp(
		(0.25 * Log( Desirability( y1Mat, [0.0183, 1, 0.0183], :Pred Formula Abrasion ) ) + 0.25 * Log(
			Desirability( y2Mat, [0.0183, 1, 0.0183], :Pred Formula Elongation )
		)) / 0.5
	)
);
	
obj << Optimize;