627075_fr-FR

liliconcom

Re : Comment remplacer le contenu de la fonction par un espace réservé ?

Découvrez Expressions - vous devez utiliser des expressions pour ce faire.Voici un exemple qui devrait fonctionner pour vous :

 

//Define variables for X, X1, X2, Y, Y1, Y2, and Group X
vars = {X(colX[i]), X(colX1[i], Position( 1 )), X(colX2[i], Position( 1 ))
,
  Y(colY[i]), Y(colY1[i], Position( 1 )), Y(colY2[i], Position( 1 ))
};

  
If( Is Missing(colGroupX[i]) != 1, 
 vars = Insert Into( vars, Group X( colGroupX[i] ) )
);

 
vars = Substitute( vars, {}, Expr( Variables() ) );

Eval( Eval Expr(
GB = Current Data Table() << Graph Builder(
 Size( 1413, 999 ),
 Expr( Name Expr( vars ) ),
 Elements(
  Points( X( 1 ), X( 2 ), X( 3 ), Y( 1 ), Y( 2 ), Legend( 11 ) ),
  Smoother( X( 1 ), X( 2 ), Y( 3 ), Y( 1 ), Y( 2 ), Legend( 14 ) )
 ),
 SendToReport(
  Dispatch( {}, "Graph", ScaleBox,
   {Label Row( {Show Major Grid( 1 ), Show Minor Grid( 1 )} )}
  )
 )
)
) )

Re : Comment remplacer le contenu de la fonction par un espace réservé ?

Merci pour votre réponse, en utilisant ce que vous avez envoyé, j'ai essayé de créer ma propre version où elle s'ajoutera à vars si elle n'est pas vide

If( Is Missing(colGroupX[i]) != 1, Insert Into( vars, Group X(colGroupX[i])));        vars = {}; 
  If( Is Missing(colX[i]) != 1, Insert Into( vars, X(colX[i])));
  If( Is Missing(colX1[i]) != 1, Insert Into( vars, X(colX1[i], Position( 1 ))));
  If( Is Missing(colX2[i]) != 1, Insert Into( vars, X(colX2[i], Position( 1 ))));
  If( Is Missing(colX3[i]) != 1, Insert Into( vars, X(colX3[i], Position( 1 ))));
  If( Is Missing(colX4[i]) != 1, Insert Into( vars, X(colX4[i], Position( 1 )))); 

  If( Is Missing(colY[i]) != 1, Insert Into( vars, Y(colY[i])));  
  If( Is Missing(colY1[i]) != 1, Insert Into( vars, Y(colY1[i], Position( 1 ))));
  If( Is Missing(colY2[i]) != 1, Insert Into( vars, Y(colY2[i], Position( 1 ))));
  If( Is Missing(colY3[i]) != 1, Insert Into( vars, Y(colY3[i], Position( 1 ))));
  If( Is Missing(colY4[i]) != 1, Insert Into( vars, Y(colY4[i], Position( 1 )))); <BR />

Quand je le lance, il y aura une erreur

Nom non résolu : X dans l'accès ou l'évaluation de 'X' , X( colX[i] ) /*###*/

Mais si j'inclus dans l'instruction vars ci-dessous, cela fonctionne

vars = {X(colX[i]), X(colX1[i], Position( 1 )), X(colX2[i], Position( 1 ))
,
  Y(colY[i]), Y(colY1[i], Position( 1 )), Y(colY2[i], Position( 1 ))
};

 

S'il vous plaît aviser merci!

Re : Comment remplacer le contenu de la fonction par un espace réservé ?

Vous devez insérer des expressions dans la liste.Avec le prototype Insérer dans( var, valeur, position ) , JMP effectuera uniquement une recherche de nom sur var (n'essaiera pas d'évaluer tout ce qui est renvoyé à partir de la recherche de nom), effectuera une recherche de nom et évaluera valeur , et effectuera une recherche de nom et évaluera position .Vous souhaitez insérer une expression dans la liste -- vous ne voulez donc pas que JMP évalue tout ce que vous avez placé dans la valeur position.Cependant, JMP l'évaluera _toujours_, donc pour conserver une expression même si JMP l'évalue, encapsulez-la dans un Expr() fonction, comme ceci :

         vars = {}; 
  If( Is Missing(colX[i]) != 1, Insert Into( vars, Expr( X(colX[i]) )));
  If( Is Missing(colX1[i]) != 1, Insert Into( vars, Expr( X(colX1[i], Position( 1 )) )));
  If( Is Missing(colX2[i]) != 1, Insert Into( vars, Expr( X(colX2[i], Position( 1 )) )));
  If( Is Missing(colX3[i]) != 1, Insert Into( vars, Expr( X(colX3[i], Position( 1 )) )));
  If( Is Missing(colX4[i]) != 1, Insert Into( vars, Expr( X(colX4[i], Position( 1 )) ))); 

  If( Is Missing(colY[i]) != 1, Insert Into( vars, Expr( Y(colY[i]) )));  
  If( Is Missing(colY1[i]) != 1, Insert Into( vars, Expr( Y(colY1[i], Position( 1 )) )));
  If( Is Missing(colY2[i]) != 1, Insert Into( vars, Expr( Y(colY2[i], Position( 1 )) )));
  If( Is Missing(colY3[i]) != 1, Insert Into( vars, Expr( Y(colY3[i], Position( 1 )) )));
  If( Is Missing(colY4[i]) != 1, Insert Into( vars, Expr( Y(colY4[i], Position( 1 )) ))); 
If( Is Missing(colGroupX[i]) != 1, Insert Into( vars, Expr( Group X(colGroupX[i]) )));

 

Re : Comment remplacer le contenu de la fonction par un espace réservé ?

Essayez-vous vraiment de rendre dynamique le générateur de graphiques ?Quelque chose comme ça?  

 

Names default to here( 1 );
dt = open("$SAMPLE_DATA\Big Class.jmp");

some_func = function({dt, list_x, list_y, list_group_x={}}, 
 {varExpr, i}, 
 varExpr=Expr(Variables());
 for(i=1, i<=nitems(list_x), i++,
  insert into(varExpr, EvalExpr(X(Expr(list_x[i]))));
 );
 for(i=1, i<=nitems(list_y), i++,
  insert into(varExpr, EvalExpr(Y(Expr(list_y[i]))));
 );
 for(i=1, i<=nitems(list_group_x), i++,
  insert into(varExpr, EvalExpr(Group X(Expr(list_group_x[i]))));
 );
 Eval(Substitute(
  Expr(
   dt << Graph Builder(
    Size( 696, 578 ),
    DV_VARS
   )
  ), 
  Expr(DV_VARS), nameexpr(varExpr)
 ))
);
some_func(dt, {:weight}, {:height, :height});
some_func(dt, {:weight, :weight}, {:height}, {:age});

Re : Comment remplacer le contenu de la fonction par un espace réservé ?

Salut vince merci pour la réponse, ça a l'air super. Cependant, comment changer le type de tracé en etc Ligne d'ajustement ou tracé à barres puisque la méthode ci-dessus ne fonctionne que pour un tracé de type plus lisse.

 

Merci!

 

Comment remplacer le contenu de la fonction par un espace réservé ?

Le premier morceau de code est à quel point il aime que cela fonctionne, mais ce n'est pas le cas.

Le deuxième morceau de code fonctionne si je remplace Variables( vars ) par celui-ci

Existe-t-il un moyen de faire fonctionner le premier morceau? S'il vous plaît aviser si je fais quelque chose de mal ici merci. JMP16

  //Define variables for X, X1, X2, Y, Y1, Y2, and Group X
  vars = {X(colX[i]), X(colX1[i], Position( 1 )), X(colX2[i], Position( 1 )),
    Y(colY[i]), Y(colY1[i], Position( 1 )), Y(colY2[i], Position( 1 ))<BR />        };<BR /><BR />        //If colGroupX[i] is not missing, add Group X statement to the variables block
  If( Is Missing(colGroupX[i]) != 1, 
   vars = Insert Into( vars, Group X( colGroupX[i] ) )
  );<BR /><BR />// Graph builder code where vars is inserted into the variables <BR /><BR />&nbsp;                GB = Current Data Table() << Graph Builder(
     Size( 1413, 999 ),
     Variables( vars ), // vars is placed here
     Elements(
      Points( X( 1 ), X( 2 ), X( 3 ), Y( 1 ), Y( 2 ), Legend( 11 ) ),
      Smoother( X( 1 ), X( 2 ), Y( 3 ), Y( 1 ), Y( 2 ), Legend( 14 ) )
     ),     
     SendToReport(
      Dispatch(
       {},
       "Graph",
       ScaleBox,
       {Label Row( {Show Major Grid( 1 ), Show Minor Grid( 1 )} )}
      )
     )
     
    );

 

Variables(
X(colX[i]),
X(colX1[i], Position( 1 )),
X(colX2[i], Position( 1 )),
Y(colY[i]),
Y(colY1[i], Position( 1 )),
Y(colY2[i], Position( 1 ))
),

 

Modélisation statistique avancéeÉtudes de consommation et de marchéConception d'expériencesIngénierie de la qualité et des procédésles fenêtres