626006_de-DE

liliconcom

Betreff: Skript zum Konvertieren einer Zeichenfolge aus einer Liste in den Körper einer Formel in einer neuen Spalte.

In diesem Beispiel haben alle "Formeln" einen Spaltennamen, der nach "(" beginnt, also könnten Sie das durch "(:" ersetzen und dann Parse verwenden

Names Default To Here(1);

dtinit = Open("$SAMPLE_DATA/Bands Data.jmp");

dtfeat = New Table("features",
 Add Rows(14),
 New Column("Term",
  Character,
  "Nominal",
  Set Property("ID Column", 1),
  Set Values(
   {"press speed", "(roller durometer-34.5151)*(anode space ratio-102.914)", "(proof cut-44.9671)*(blade pressure-30.8904)",
   "(anode space ratio-102.914)*(chrome content-99.6164)", "(humidity-78.6849)*(press speed-1851.21)", "roller durometer",
   "(roller durometer-34.5151)*(current density-39.0164)", "(humidity-78.6849)*(wax-2.4037)",
   "(wax-2.4037)*(chrome content-99.6164)", "(viscosity-50.7836)*(press speed-1851.21)", "(wax-2.4037)*(hardener-0.96014)",
   "(roughness-0.71969)*(current density-39.0164)", "(humidity-78.6849)*(ink pct-55.6473)",
   "(blade pressure-30.8904)*(press speed-1851.21)"}
  )
 ),
 Set Label Columns(:Term)
);

dtfeat << New Column("interaction", Character, "Nominal", Formula(If(Starts With(:term, "("), :term, ""))) <<
Move Selected Columns({:interaction}, after(:term));

value = dtfeat:interaction << get values();

uniqueinteraction = Associative Array(value) << get keys;

For Each({uniq}, uniqueinteraction,
 f_str = Substitute(uniq, "(", "(:");
 If(IsMissing(f_str),
  continue();
 );
 Eval(EvalExpr(
  dtinit << New Column(uniq, Numeric, "Continuous", 
   Formula(Expr(Parse(f_str)))
 )));
);

Fügen Sie mit Eval Insert, Eval Expr, Parse und Substitute einen Ausdruck in einen anderen ein

Betreff: Skript zum Konvertieren einer Zeichenfolge aus einer Liste in den Körper einer Formel in einer neuen Spalte.

Hervorragend. Hat den Trick gemacht. Vielen Dank.

Skript zum Konvertieren einer Zeichenfolge aus einer Liste in den Hauptteil einer Formel in einer neuen Spalte.

Verfolgen Sie den Prozess der Identifizierung einiger interagierender Spalten nach Verwendung der Anpassungsplattform und der Suche nach einer Interaktion (Fakultät ...). Ich möchte den resultierenden Term (z. B. cA*0,1+cB*0,3) aus der Interaktion als Ausgangspunkt verwenden, um automatisch Spaltenformeln aus diesen Termen zu erstellen. Ich habe Schwierigkeiten, eine Möglichkeit zu finden, den Inhalt einer Zeichenfolge wie „cA*0,1+cB*0,3“ zu verwenden, wobei cA und cB die Namen von zwei in einer Tabelle vorhandenen Spalten darstellen, um neue Formeln zu erstellen.

 

Der letzte Teil des Skripts erstellt die Formel, stellt jedoch nur den Inhalt der Zeichenfolge dar, anstatt ihren Inhalt auszuwerten.

 

Jeder Vorschlag wäre sehr dankbar.

 

Sebastian

 names default to here(1);
clear log();

dtinit=Open( "$SAMPLE_DATA/Bands Data.jmp" );

// Make TableBox into a Data Table
// → Data Table( "Untitled 3" )
//terms tables resulting from a generalized regression taking into consideration term interaction.

dtfeat = New Table( "features",
 Add Rows( 14 ),
 New Column( "Term",
  Character,
  "Nominal",
  Set Property( "ID Column", 1 ),
  Set Values(
   {"press speed", "(roller durometer-34.5151)*(anode space ratio-102.914)", "(proof cut-44.9671)*(blade pressure-30.8904)",
   "(anode space ratio-102.914)*(chrome content-99.6164)", "(humidity-78.6849)*(press speed-1851.21)", "roller durometer",
   "(roller durometer-34.5151)*(current density-39.0164)", "(humidity-78.6849)*(wax-2.4037)", "(wax-2.4037)*(chrome content-99.6164)",
   "(viscosity-50.7836)*(press speed-1851.21)", "(wax-2.4037)*(hardener-0.96014)", "(roughness-0.71969)*(current density-39.0164)",
   "(humidity-78.6849)*(ink pct-55.6473)", "(blade pressure-30.8904)*(press speed-1851.21)"}
  )
 ),
 Set Label Columns( :Term )
);

//Identifies interacting terms
// New column: interaction
dtfeat << New Column( "interaction", Character, "Nominal", Formula( If( Starts With( :term, "(" ), :term, "" ) ) ) <<
Move Selected Columns( {:interaction}, after( :term ) );



value = dtfeat:interaction << get values();

uniqueinteraction = Associative Array( value ) << get keys;
nvinteract = N Items( uniqueinteraction );
 
//Will create a column named after the interacting terms
//Should apply a formula based on the interacting terms 
//However, not sure how to extract the string from the list 'uniqueinteraction' so that is it not seen as a string but rather as 'formula instruction' where some portion of the term is recognized as a column namealready present in the original table
For( i = 1, i <= nvinteract, i++,
 dtinit << New Column( uniqueinteraction[i], Numeric, "Continuous", Format( "Best", 12 ), Formula( Eval( uniqueinteraction[i] ) )

 

Verbraucher- und Marktforschung