623675_zh-TW

liliconcom

連接具有循環中更改的變數的列表

你好，
我很難連接其中包含變數的多個列表。我有一個列表，每個項目都是從用戶輸入變數連接起來的字串。由於變數每個循環都會更改，因此我如何更新列表並將該列表連接到其他列表。

bank_pcs = {"BGB1BESS001_B"||bank||"_W","BGB1BESS001_B"||bank||"_A","BGB1BESS001_V"||bank||"_W"};
For (i = 1, i<=6, i++,
		bank_num = 6*(k-1)+i;
		bank = char(bank_num,10,0);
		Eval list (bank_pcs);
		bank_tags_i = bank_pcs;	
		bank_tags = concat (bank_tags, bank_tags_i)
)

謝謝

資料混合與清理回复：連接具有在循環中更改的變量的列表

看看這是否會給你你想要的

For( i = 1, i <= 6, i++,
 bank_num = 6 * (k - 1) + i;
 theBankValue = Char( bank_num, 10, 0 );
 Eval(
  Substitute(
    Expr(
     bank_pcs = {"BGB1BESS001_B" || bank || "_W", "BGB1BESS001_B" || bank || "_A", "BGB1BESS001_V" || bank ||
     "_W"}
    ),
   Expr( bank ), theBankValue
  )
 );
 bank_tags_i = bank_pcs;
 bank_tags = Concat( bank_tags, bank_tags_i );
);

回复：連接具有在循環中更改的變量的列表

你快到了。你有 evallist(bank_pcs) 但這不是你分配給 bank_tags_i 的。這對我有用。  

 

NamesDefaultToHere(1);
bank_pcs = {"BGB1BESS001_B"||bank||"_W","BGB1BESS001_B"||bank||"_A","BGB1BESS001_V"||bank||"_W"};
For (i = 1, i<=6, i++,
    bank_num = i; // changing this from yours because I assume you also have a k loop
    bank = char(bank_num,10,0);
    bank_tags_i = Evallist(bank_pcs); 
    if(i==1, 
        bank_tags = bank_tags_i // just if it isn't started yet. you're probably doing this in your k loop
    , //else
        bank_tags = concat (bank_tags, bank_tags_i)
    )
);
bank_tags;

回复：連接具有在循環中更改的變量的列表

或者，如果你想要一個列表列表：

k = 11;
bank_tags = {};
bank_pcs = {"BGB1BESS001_B" || bank || "_W", "BGB1BESS001_B" || bank || "_A", "BGB1BESS001_V" || bank || "_W"};
For( i = 1, i <= 6, i++,
 bank_num = 6 * (k - 1) + i;
 bank = Char( bank_num, 10, 0 );
 bank_tags_i = Eval List( bank_pcs );
 bank_tags[1 + N Items( bank_tags )] = bank_tags_i;
);
Show( bank_tags );
/*{{"BGB1BESS001_B61_W", "BGB1BESS001_B61_A", "BGB1BESS001_V61_W"}, 
{"BGB1BESS001_B62_W", "BGB1BESS001_B62_A", "BGB1BESS001_V62_W"}, 
{"BGB1BESS001_B63_W", "BGB1BESS001_B63_A", "BGB1BESS001_V63_W"}, 
{"BGB1BESS001_B64_W", "BGB1BESS001_B64_A", "BGB1BESS001_V64_W"}, 
{"BGB1BESS001_B65_W", "BGB1BESS001_B65_A", "BGB1BESS001_V65_W"}, 
{"BGB1BESS001_B66_W", "BGB1BESS001_B66_A", "BGB1BESS001_V66_W"}}*/

如果你想要一個字符串而不是一個列表，試試@vince_faller回答Concat Items（bank_tags，“，”）獲取帶逗號的字符串中的列表項。

回复：連接具有在循環中更改的變量的列表

謝謝你！ 它按我的預期工作。