623675_zh-CN

liliconcom

连接在循环中改变变量的列表

你好，
我正在努力连接多个包含变量的列表。我有一个列表，每个项目都是从用户输入变量连接起来的字符串。由于变量每次循环都会更改，我如何才能更新列表，并将该列表连接到其他列表。

bank_pcs = {"BGB1BESS001_B"||bank||"_W","BGB1BESS001_B"||bank||"_A","BGB1BESS001_V"||bank||"_W"};
For (i = 1, i<=6, i++,
		bank_num = 6*(k-1)+i;
		bank = char(bank_num,10,0);
		Eval list (bank_pcs);
		bank_tags_i = bank_pcs;	
		bank_tags = concat (bank_tags, bank_tags_i)
)

谢谢

数据混合和清理回复：连接具有在循环中更改的变量的列表

看看这是否会给你你想要的

For( i = 1, i <= 6, i++,
 bank_num = 6 * (k - 1) + i;
 theBankValue = Char( bank_num, 10, 0 );
 Eval(
  Substitute(
    Expr(
     bank_pcs = {"BGB1BESS001_B" || bank || "_W", "BGB1BESS001_B" || bank || "_A", "BGB1BESS001_V" || bank ||
     "_W"}
    ),
   Expr( bank ), theBankValue
  )
 );
 bank_tags_i = bank_pcs;
 bank_tags = Concat( bank_tags, bank_tags_i );
);

回复：连接具有在循环中更改的变量的列表

你快到了。你有 evallist(bank_pcs) 但这不是你分配给 bank_tags_i 的。这对我有用。  

 

NamesDefaultToHere(1);
bank_pcs = {"BGB1BESS001_B"||bank||"_W","BGB1BESS001_B"||bank||"_A","BGB1BESS001_V"||bank||"_W"};
For (i = 1, i<=6, i++,
    bank_num = i; // changing this from yours because I assume you also have a k loop
    bank = char(bank_num,10,0);
    bank_tags_i = Evallist(bank_pcs); 
    if(i==1, 
        bank_tags = bank_tags_i // just if it isn't started yet. you're probably doing this in your k loop
    , //else
        bank_tags = concat (bank_tags, bank_tags_i)
    )
);
bank_tags;

回复：连接具有在循环中更改的变量的列表

或者，如果你想要一个列表列表：

k = 11;
bank_tags = {};
bank_pcs = {"BGB1BESS001_B" || bank || "_W", "BGB1BESS001_B" || bank || "_A", "BGB1BESS001_V" || bank || "_W"};
For( i = 1, i <= 6, i++,
 bank_num = 6 * (k - 1) + i;
 bank = Char( bank_num, 10, 0 );
 bank_tags_i = Eval List( bank_pcs );
 bank_tags[1 + N Items( bank_tags )] = bank_tags_i;
);
Show( bank_tags );
/*{{"BGB1BESS001_B61_W", "BGB1BESS001_B61_A", "BGB1BESS001_V61_W"}, 
{"BGB1BESS001_B62_W", "BGB1BESS001_B62_A", "BGB1BESS001_V62_W"}, 
{"BGB1BESS001_B63_W", "BGB1BESS001_B63_A", "BGB1BESS001_V63_W"}, 
{"BGB1BESS001_B64_W", "BGB1BESS001_B64_A", "BGB1BESS001_V64_W"}, 
{"BGB1BESS001_B65_W", "BGB1BESS001_B65_A", "BGB1BESS001_V65_W"}, 
{"BGB1BESS001_B66_W", "BGB1BESS001_B66_A", "BGB1BESS001_V66_W"}}*/

如果你想要一个字符串而不是一个列表，试试@vince_faller回答Concat Items（bank_tags，“，”）获取带逗号的字符串中的列表项。

回复：连接具有在循环中更改的变量的列表

谢谢你！ 它按我的预期工作。