36971_fr-FR

liliconcom

Enregistrement de l'animation JMP

Bonjour, je suis assez nouveau sur JMP et j'ai une question : est-il possible de sauvegarder une animation ?

Par exemple, si je fais Ajuster Y par X sur une table, puis que j'utilise une animation de filtre de données. Serait-il possible de sauvegarder l'animation/le clip ?

Merci!

  

Re : Sauvegarde de l'animation JMP

Merci beaucoup!:)

Re : Sauvegarde de l'animation JMP

Vous pouvez trouver un autre exemple d'enregistrement d'un GIF animé avec un filtre de données ici : Enregistrer une animation de filtre de données sous forme de GIF animé .

 

 

Re : Sauvegarde de l'animation JMP

Si vous utilisez JMP 13 sous Windows, vous pouvez utiliser la nouvelle fonctionnalité JSL pour créer des GIF animés afin d'enregistrer votre animation de filtre de données.

Vous trouverez ci-dessous un exemple qui créera un générateur de graphiques avec un filtre de données local et un GIF animé sera enregistré et ouvert. Pour plus d'informations, consultez @JohnPonte c'est article sur les GIF animés utilisant Bubble Plot . J'ai emprunté beaucoup de code à son exemple d'ouragans dans le script ci-dessous. Théoriquement, cela peut fonctionner sur une fenêtre actuelle que vous avez ouverte si vous exécutez tout ce qui commence par la ligne "report = Current Report()".

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Big Class.jmp" );
gb = dt << Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ), Overlay( :sex ) ),
 Elements( Points( X, Y, Legend( 1 ) ), Smoother( X, Y, Legend( 2 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :age ),
   Where( :age == 12 ),
   Display( :age, Size( 202, 114 ), List Display )
  )
 )
);

report = Current Report();

ldf_listBox = report[ListBoxBox(1)];

numLevels = NItems(ldf_ListBox << Get ITems);

// Create a new image, same size as the graph we are going to capture
graphFrame = report[FrameBox(1)] << getPicture();
{w, h} = graphFrame << getSize();
img = newImage(w, h);

for(i=1,i<=numLevels,i++,
 
 // deselect old selection
 selectedItems = ldf_listBox << Get Selected Indices;
 for(k=1,k<=nitems(selectedItems),k++,
  ldf_listBox << set selected(selectedItems[k],0);
 );
 
 // set the next item selected
 ldf_listBox << set selected(i);
 
 wait(0); // wait for the display to update
 // Capture frame for current graph and save to animated image
 graphFrame = report[FrameBox(1)] << getPicture();
 {r, g, b} = graphFrame << getPixels("rgb");
 img << addFrame();
 img << setFrameDuration(1000);  // Time between frames, in ms
 img << setPixels("rgb", {r, g, b}); 
 wait(0.5); // for demonstration purposes
);

// Remove inital blank frame
img << removeFrame(0);

// Write out animated image
img << saveImage ("$temp\animated.gif", gif);

// open the gif
open("$temp\animated.gif");

Modifié pour ajouter le fichier GIF résultant :Resulting animated gifResulting animated gif Gif animé résultant