622464_es-ES

liliconcom

Re: Script JSL para crear o condicionar mediante un bucle de nombres de columna completos en una lista

Aquí hay un ejemplo de una forma de hacerlo ....... otros pueden tener formas más elocuentes

Names Default To Here( 1 );
dt = 
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );

my_func = Function( {input_dt, input_col_list, x},
 {input_dt, input_col_list, x, the_cmd},
 input_dt << New Column( "d" );
 current data table(input_dt);
 the_cmd = "current data table():d << set formula( If(  current data table():\!"" ||
 Char( input_col_list[1] ) || "\!"n >= " || Char( x );
 For( i = 2, i <= N Items( input_col_list ), i++,
  the_cmd = the_cmd || " | current data table():\!"" || Char( input_col_list[i] ) || "\!"n >= "
   || Char( x )
 );
 the_cmd = the_cmd || ", 1, 0) );";
 Eval( Parse( the_cmd ) );
);

input_col_listx = {"Height", weight};
dtx = Data Table( "big class" );
xx = 101;

theReturn = my_func( dtx, input_col_listx, xx );

 

Re: Script JSL para crear o condicionar mediante un bucle de nombres de columna completos en una lista

Construir esto usando cadenas es probablemente la opción más simple ya que la expresión es bastante simple. Pero... No me gusta usar Eval (Parse()), así que aquí hay algunas opciones que no usan eso (la segunda opción podría no hacer lo que quiere con los valores faltantes)

Names Default To Here(1);

dt = New Table("Untitled 3",
 Add Rows(0),
 Compress File When Saved(1),
 New Column("a", Numeric, "Continuous", Format("Best", 12), Set Values([0,1])),
 New Column("b", Numeric, "Continuous", Format("Best", 12), Set Values([0,0])),
 New Column("c", Numeric, "Continuous", Format("Best", 12), Set Values([0,0]))
);
input_col_list = {"a", "b", "c"};
x = 0.1;

// using Or
or_expr = Expr(Or());
// https://community.jmp.com/t5/JSL-Cookbook-Archived/Insert-one-expression-into-another-using-Eval-Insert-Eval-Expr/ta-p/48998
For Each({col_name}, input_col_list,
 col_expr = Substitute(
  expr(_col_ref_ >= _comparison_value_),
  Expr(_col_ref_), NameExpr(AsColumn(Column(dt, col_name))),
  Expr(_comparison_value_), x
 );
 Insert Into(or_expr, Name Expr(col_expr));
);
// Show(name expr(or_expr));
Eval(EvalExpr(dt << New Column("d", Numeric, Continuous, Formula(
 If(Expr(name expr(or_expr)), 1, 0)
))));


// using matrix and any
col_refs = Transform Each({col_name}, input_col_list,
 Name Expr(As Column(Column(dt, col_name)));
);
Eval(EvalExpr(dt << New Column("d", Numeric, Continuous, Formula(
 Any(Matrix(Expr(col_refs)) >= Expr(x))
))));


// function of second option
create_check_col = function({dt, col_input, limit_val}, {Default Local},
 col_refs = Transform Each({col_name}, col_input,
  Name Expr(As Column(Column(dt, col_name)));
 );
 
 new_col = Eval(EvalExpr(dt << New Column("d", Numeric, Continuous, Formula(
  Any(Matrix(Expr(col_refs)) >= Expr(limit_val))
 ))));
 
 return(new_col);
);
create_check_col(dt, input_col_list, x);

Script JSL para crear o condicionar mediante un bucle completo de nombres de columna en una lista

Me gustaría crear una función en jsl que tome una lista dada de nombres de columna como entrada, use esas columnas para hacer una condición OR y genere una columna con esa fórmula OR en bucle. ¿Cómo haces eso?

 

input_col_list = { "a", "b", "c"};
input_dt = dt;
x = 0.1;
input_dt << New Column("d", numeric, continuous, 
formula ( 
If(
(As Column("a") >= x  |  As Column("b") >= x  | As Column("c") >=  x), 
1,
0
) 
));

Para arriba, me gustaría hacer una función como la siguiente:

my_func =
Function(
{input_dt, input_col_list, x},
{//local var},
// function body
...
Return As column("d")
);

Ingeniería de Calidad y Procesosventanas