620720_ja-JP

liliconcom

jslを使用して分位範囲外れ値の列を選択する方法

こんにちは、JMP チームです。

Explore Outliers を使用して、自動化された外れ値分析を行う予定です。 この自動化の目的は、外れ値のある行アイテムと列アイテムのみを表示する、きちんとした見やすいテーブルを取得することです (これには、外れ値でない列と行を除外する必要があります)。 以下の例のように水処理を使用して、外れ値なしで行項目を削除します。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Water Treatment.jmp" );
obj = dt << Explore Outliers(
 Y( dt << Get Column Group( "Sensor Measurements" ) )
);

obj << Show only columns with outliers(1);
obj << Tail Quantile( 0.1 );
obj << Q(3);
obj << Quantile Range Outliers;
obj << ColorCells(dt << Get Column Group( "Sensor Measurements" ));
obj << SelectRows(dt << Get Column Group( "Sensor Measurements" ));
obj << ExcludeRows(dt << Get Column Group( "Sensor Measurements" ));

dt << select where( Excluded(Row State()) != 1 );
dt << Delete rows;

jslコードを使用して異常値でない列を除外する方法について質問がありますか?

 

よろしく、

XH低

 

分析データ表スクリプティングウィンドウズRe: 変位値範囲外れ値の列をjslで選択する方法

スクリプトの最後に、外れ値のない列を削除する数行のコードを追加しました。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Water Treatment.jmp" );
obj = dt << Explore Outliers( Y( dt << Get Column Group( "Sensor Measurements" ) ) );

obj << Show only columns with outliers( 1 );
obj << Tail Quantile( 0.1 );
obj << Q( 3 );
obj << Quantile Range Outliers;
obj << ColorCells( dt << Get Column Group( "Sensor Measurements" ) );
obj << SelectRows( dt << Get Column Group( "Sensor Measurements" ) );
obj << ExcludeRows( dt << Get Column Group( "Sensor Measurements" ) );

dt << select where( Excluded( Row State() ) != 1 );
dt << Delete rows;

allEvaluatedList = Report( obj )["Quantile Range Outliers", String Col Box( "Column" )] << get;
obj << Show only columns with outliers( 1 );
colList = Report( obj )["Quantile Range Outliers", String Col Box( "Column" )] << get;

For Each( {col, i}, allEvaluatedList,
 If( Contains( colList, col ) == 0,
  dt << delete columns( col )
 )
);

 

 

Re: 変位値範囲外れ値の列をjslで選択する方法

こんにちはジム、

 

コードをありがとう。

上記のコードを試してみましたが、私の JMP15 は For Each() をサポートしていませんでした。 For Each から For ループにいくつかの変更を加えます。

ただし、外れ値以外の列を削除することはできません。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Water Treatment.jmp" );
obj = dt << Explore Outliers( Y( dt << Get Column Group( "Sensor Measurements" ) ) );

obj << Show only columns with outliers( 1 );
obj << Tail Quantile( 0.1 );
obj << Q( 3 );
obj << Quantile Range Outliers;
obj << ColorCells( dt << Get Column Group( "Sensor Measurements" ) );
obj << SelectRows( dt << Get Column Group( "Sensor Measurements" ) );
obj << ExcludeRows( dt << Get Column Group( "Sensor Measurements" ) );

dt << select where( Excluded( Row State() ) != 1 );
dt << Delete rows;

allEvaluatedList = Report( obj )["Quantile Range Outliers", String Col Box( "Column" )] << get;
obj << Show only columns with outliers( 1 );
colList = Report( obj )["Quantile Range Outliers", String Col Box( "Column" )] << get;


For( i=1, i <= N Items(allEvaluatedList), i++, col=allEvaluatedList[i];
 If( Contains( colList, col ) == 0 ,
  dt << delete columns( col )
 )
);

以下のデータ テーブルには、外れ値以外の列がまだ存在します。

何か不足していますか？

 

 

Re: 変位値範囲外れ値の列をjslで選択する方法

デフォルトでは、JMP 15 の [外れ値を調べる] プラットフォームの出力には、外れ値のある列のみが表示されます。私が提供したスクリプトは、分析用に指定されたすべての列が表示されることを想定していました。「allEvaluatedList」が適切に入力されるように、すべての列を強制的に表示するようにコードを変更しました。JMP 15 でコードをテストしたところ、iit が動作するようになりました。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Water Treatment.jmp" );
obj = dt << Explore Outliers( Y( dt << Get Column Group( "Sensor Measurements" ) ) );

obj << Show only columns with outliers( 1 );
obj << Tail Quantile( 0.1 );
obj << Q( 3 );
obj << Quantile Range Outliers;
obj << ColorCells( dt << Get Column Group( "Sensor Measurements" ) );
obj << SelectRows( dt << Get Column Group( "Sensor Measurements" ) );
obj << ExcludeRows( dt << Get Column Group( "Sensor Measurements" ) );

dt << select where( Excluded( Row State() ) != 1 );
dt << Delete rows;

obj << Show only columns with outliers( 0 );
allEvaluatedList = Report( obj )["Quantile Range Outliers", String Col Box( "Column" )] << get;
obj << Show only columns with outliers( 1 );
colList = Report( obj )["Quantile Range Outliers", String Col Box( "Column" )] << get;


For( i=1, i <= N Items(allEvaluatedList), i++, col=allEvaluatedList[i];
 If( Contains( colList, col ) == 0 ,
  dt << delete columns( col )
 )
);

Re: 変位値範囲外れ値の列をjslで選択する方法

素晴らしい！！ それは今動作します。

ありがとうジム。