Oggetto: Salva riepiloghi per più grafici in un report utilizzando JSLFare clic con il tasto destro su una delle tabelle di riepilogo e selezionare Trasforma in tabella combinata. Funziona per te?
Ri: Salva riepiloghi per più grafici in un report utilizzando JSLGrazie per il suggerimento!
In realtà non sto utilizzando le tabelle di riepilogo per questo, sto cercando di utilizzare il pulsante "Salva riepiloghi" sul Generatore di carte di controllo utilizzando JSL. Ho bisogno di salvare i riepiloghi di molti grafici che esistono all'interno di una singola scheda del rapporto. Per favore fatemi sapere se posso fornire ulteriori informazioni su questo, grazie!
Ri: Salva riepiloghi per più grafici in un report utilizzando JSLVuoi salvare tutti i riepiloghi che compaiono a destra della carta di controllo? Vuoi che i riepiloghi siano riuniti in un'unica tabella di dati?
Il mio suggerimento precedente inserirà tutte queste informazioni in una tabella di dati simile a questa per il mio esempio:
Questo codice illustra come ottenere questo risultato da uno script:
Names Default to Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
ccb = dt << Control Chart Builder( Variables( Y( :height, :weight ) ), Show Control Panel( 0 ) );
summary = Report( ccb )[TableBox(1)] << Make Combined Data Table;
Oggetto: Salva riepiloghi per più grafici in un report utilizzando JSL@Mark_Bailey grazie per questo! Vedo che questo può essere molto utile per ottenere un riepilogo dell'intero grafico per più grafici in un rapporto. Tuttavia, se possibile, mi piacerebbe poter ottenere i riepiloghi di ciascun punto su ciascun grafico. Esattamente come funziona quando si utilizza il pulsante nell'immagine allegata.
È possibile farlo usando JSL?
Vedo ora che funziona quando si utilizza questo: summary = Report( ccb ) << Save Summary;
Tuttavia, ho un altro livello nel mio set di dati che lo rende meno semplice. Nel mio set di dati, nel report viene utilizzato più di un singolo Control Chart Builder in base al numero di righe presenti in un'altra tabella. Quindi, quando eseguo <
Nel frattempo cercherò di adattare il set di dati di Big Class per rendere più chiaro ciò che sto cercando di fare.
Ri: Salva riepiloghi per più grafici in un report utilizzando JSLSì, questo codice è la base per una soluzione:
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
obj = dt << Control Chart Builder( Variables( Y( :weight, :height ) ) );
dt = obj << Save Summaries;
Stai avviando Control Chart Builder per più di una risposta alla volta? In tal caso, dovresti ottenere una tabella di dati per ogni risposta. Stai ripetendo le risposte e avviando Control Chart Builder per una risposta alla volta?
Oggetto: Salva riepiloghi per più grafici in un report utilizzando JSLEHI @Mark_Bailey , Credo che questo qui dovrebbe dare un'idea migliore di come sono impostati i miei dati. Ho adattato il set di dati di Big Class aggiungendo questo:
Names Default to Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Window ("Charts",
For ( i = 1, i <= N Row(dt), i++,
name = dt:Name[i];
obj = dt << Control Chart Builder( Variables( Y( :height, :weight ) ), Show Control Panel( 0 ), SendToReport(
Dispatch(
{},
"graph display 1 title",
TextEditBox,
{Set Text( name || " Individual & Moving Range chart of height" )}
)
) );
); );
dt = obj << Save Summaries;Le pozioni "nuova finestra" e "per" sono state aggiunte per riflettere ciò che sto cercando. Se viene eseguito quanto sopra, all'interno della finestra "Grafici" ci sono 40 grafici con tutti gli stessi dati. Per il bene di ciò che stiamo facendo qui, supponiamo che ogni grafico contenga dati diversi e, per questo motivo, riepiloghi diversi. Quando "Salva riepiloghi" viene eseguito in fondo a questo, non ottengo riepiloghi per tutti i grafici, solo l'ultimo grafico nella finestra "Grafici".
C'è un modo per me di dire a questo codice di estrarre i riepiloghi di uno qualsiasi dei grafici che ha eseguito? Ad esempio, se desidero i riepiloghi per il grafico 35 nella finestra "Grafici", posso ottenerlo utilizzando JSL come nell'esempio precedente? o sarei in grado di tirarli tutti in qualche modo?
Per favore fatemi sapere se posso fornire ulteriori informazioni. Per rispondere alla tua domanda di prima, credo che ciò che sta accadendo sia che ogni istanza stia iterando su se stessa, quindi non sono in grado di salvare i riepiloghi delle variabili. Spero di esserti stato d'aiuto, grazie per il tuo aiuto!
Oggetto: Salva riepiloghi per più grafici in un report utilizzando JSLDi seguito sono riportati tre suggerimenti nell'ordine in cui li proverei.
Potresti provare a creare una tabella di dati combinati tramite script
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
nw = New Window("Charts",
For(i = 1, i <= N Row(dt), i++,
name = dt:Name[i];
obj = dt << Control Chart Builder(
Variables(Y(:height, :weight)),
Show Control Panel(0),
SendToReport(
Dispatch(
{},
"graph display 1 title",
TextEditBox,
{Set Text(name || " Individual & Moving Range chart of height")}
)
)
);
)
);
dt_summaries = nw["Control Chart Builder", "height Limit Summaries", Table Box(1)] << Make Combined Data Table;
Oppure puoi memorizzare i riferimenti a quei creatori di grafici di controllo durante il ciclo e quindi ripetere il ciclo con Salva riepiloghi (molto probabilmente dovresti salvare i valori all'interno del ciclo e quindi chiudere le tabelle):
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
ccb_list = {};
nw = New Window("Charts",
For(i = 1, i <= N Row(dt), i++,
name = dt:Name[i];
obj = dt << Control Chart Builder(
Variables(Y(:height, :weight)),
Show Control Panel(0),
SendToReport(
Dispatch(
{},
"graph display 1 title",
TextEditBox,
{Set Text(name || " Individual & Moving Range chart of height")}
)
)
);
Insert Into(ccb_list, obj);
);
);
For(i = 1, i <= N Items(ccb_list), i++,
dt_temp = ccb_list[i] << Save Summaries;
show(dt_temp);
//Close(dt_temp, no save);
);
Oppure puoi usare XPath per ottenere i riferimenti (e li farei di nuovo in loop per evitare di aprire troppe tabelle)
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
nw = New Window("Charts",
For(i = 1, i <= N Row(dt), i++,
name = dt:Name[i];
obj = dt << Control Chart Builder(
Variables(Y(:height, :weight)),
Show Control Panel(0),
SendToReport(
Dispatch(
{},
"graph display 1 title",
TextEditBox,
{Set Text(name || " Individual & Moving Range chart of height")}
)
)
);
);
);
//((nw << XPath("//OutlineBox[text()='Control Chart Builder']")) << get scriptable object) << Save Summaries;
Se il << salvataggio dei riepiloghi apre più di una tabella, potrebbe essere necessario utilizzare qualcosa come Get Data Table List(); per vedere quali sono quelli nuovi, maneggiarli e poi chiuderli.
Oggetto: Salva riepiloghi per più grafici in un report utilizzando JSLGrazie per questo! Ho finito per usare la seconda versione che mi hai inviato ed era perfetta per quello che sto facendo.
Grazie!
Salva riepiloghi per più grafici in un report utilizzando JSLHo un rapporto che eseguo che sputa ovunque tra 2 e 26 grafici in una scheda del rapporto in modo che possano essere visualizzati tutti contemporaneamente, in un'unica scheda. Mi piacerebbe trovare un modo per esportare i riepiloghi di salvataggio per tutti i grafici nel rapporto utilizzando JSL. Al momento, faccio semplicemente CTRL + clic sul pulsante nell'immagine allegata ed esporta tutto ciò di cui ho bisogno in molte tabelle di dati.
Esiste un modo per forzare JMP a estrarre i riepiloghi di salvataggio su un report utilizzando semplicemente JSL? Sarebbe opportuno inserire i riepiloghi nelle tabelle dati uno per uno. Tutti gli altri esempi che ho visto includono l'assegnazione del Control Chart Builder a un oggetto, quindi il salvataggio di tali riepiloghi. Preferirei non farlo, ma posso farlo se è la mia unica opzione.
Grazie!
Personalizzazione di massafinestre
