620195_de-DE

liliconcom

Betreff: Zusammenfassungen für mehrere Diagramme in einem Bericht mit JSL speichern

Klicken Sie mit der rechten Maustaste auf eine der Übersichtstabellen und wählen Sie In kombinierte Tabelle erstellen aus. Funktioniert das für dich?

Betreff: Zusammenfassungen für mehrere Diagramme in einem Bericht mit JSL speichern

Danke für den Vorschlag!

 

Ich verwende dafür eigentlich keine Übersichtstabellen, ich versuche, die Schaltfläche "Zusammenfassungen speichern" im Control Chart Builder mit JSL zu verwenden. Ich muss die Zusammenfassungen vieler Diagramme speichern, die auf einer einzigen Berichtsregisterkarte vorhanden sind. Bitte lassen Sie mich wissen, wenn ich weitere Informationen dazu geben kann, danke!

Betreff: Zusammenfassungen für mehrere Diagramme in einem Bericht mit JSL speichern

Möchten Sie alle Zusammenfassungen speichern, die rechts neben dem Regeldiagramm angezeigt werden? Möchten Sie die Zusammenfassungen zusammen in einer Datentabelle?

 

 

Mein vorheriger Vorschlag wird all diese Informationen in eine Datentabelle einfügen, die für mein Beispiel so aussieht:

 

 

Dieser Code veranschaulicht, wie Sie dieses Ergebnis aus einem Skript erzielen:

 

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

ccb = dt << Control Chart Builder( Variables( Y( :height, :weight ) ), Show Control Panel( 0 ) );

summary = Report( ccb )[TableBox(1)] << Make Combined Data Table;

Betreff: Zusammenfassungen für mehrere Diagramme in einem Bericht mit JSL speichern

@Mark_Bailey Danke dafür! Ich sehe, dass dies sehr hilfreich sein kann, um eine Zusammenfassung des gesamten Diagramms für mehrere Diagramme in einem Bericht zu erhalten. Wenn möglich, würde ich jedoch gerne in der Lage sein, die Zusammenfassungen jedes Punktes in jedem Diagramm zu erhalten. Genau wie es funktioniert, wenn Sie die Schaltfläche im angehängten Bild verwenden.

 

Ist dies mit JSL möglich?

 

Ich sehe jetzt, dass dies funktioniert, wenn ich Folgendes verwende: summary = Report( ccb ) << Save Summarys;

 

Ich habe jedoch eine andere Ebene in meinem Datensatz, was dies weniger einfach macht. In meinem Datensatz wird mehr als nur ein einzelner Control Chart Builder im Bericht verwendet, basierend darauf, wie viele Zeilen in einer anderen Tabelle vorhanden sind. Wenn ich also << Zusammenfassungen speichern für das Objekt ausführe, dem ich den Kontrolldiagramm-Generator zugewiesen habe, erhalte ich nur die Zusammenfassungen für das zuletzt erstellte Diagramm und nicht alle. Gibt es eine Möglichkeit, JMP anzuweisen, sich die anderen Diagramme anzusehen, damit ich diese Zusammenfassungen speichern kann?

 

Ich werde in der Zwischenzeit versuchen, den Big Class-Datensatz anzupassen, um klarer zu machen, was ich vorhabe.

Betreff: Zusammenfassungen für mehrere Diagramme in einem Bericht mit JSL speichern

Ja, dieser Code ist die Basis für eine Lösung:

 

Names Default To Here( 1 );

dt = Open(  "$SAMPLE_DATA/Big Class.jmp" );

obj = dt << Control Chart Builder( Variables( Y( :weight, :height ) ) );

dt = obj << Save Summaries;

Starten Sie den Control Chart Builder für mehr als eine Antwort gleichzeitig? In diesem Fall sollten Sie für jede Antwort eine Datentabelle erhalten. Wiederholen Sie die Antworten und starten Sie den Control Chart Builder für jeweils eine Antwort?

Betreff: Zusammenfassungen für mehrere Diagramme in einem Bericht mit JSL speichern

Hey @Mark_Bailey , ich glaube, das hier sollte eine bessere Vorstellung davon geben, wie meine Daten eingerichtet sind. Ich habe den Big Class-Datensatz angepasst, indem ich Folgendes hinzugefügt habe:

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Window ("Charts",
For ( i = 1, i <= N Row(dt), i++,
 name = dt:Name[i];
 obj = dt << Control Chart Builder( Variables( Y( :height, :weight ) ), Show Control Panel( 0 ), SendToReport(
  Dispatch(
   {},
   "graph display 1 title",
   TextEditBox,
   {Set Text( name || " Individual & Moving Range chart of height" )}
  )
 ) );
); );

dt = obj << Save Summaries;

Die „Neues-Fenster“- und „Für“-Tränke wurden hinzugefügt, um zu reflektieren, wonach ich suche. Wenn das obige ausgeführt wird, befinden sich im Fenster "Diagramme" 40 Diagramme mit denselben Daten. Für das, was wir hier tun, gehen Sie bitte davon aus, dass jede Grafik unterschiedliche Daten und daher unterschiedliche Zusammenfassungen haben würde. Wenn „Zusammenfassungen speichern“ unten ausgeführt wird, erhalte ich keine Zusammenfassungen für alle Diagramme, sondern nur das letzte Diagramm im Fenster „Diagramme“.

 

Gibt es eine Möglichkeit für mich, diesem Code mitzuteilen, dass er die Zusammenfassungen aller Graphen abrufen soll, die er ausgeführt hat? Wenn ich zum Beispiel die Zusammenfassungen für die 35 Diagramme im Fenster "Diagramme" haben möchte, kann ich das mit JSL wie im obigen Beispiel erhalten? oder kann ich die alle irgendwie ziehen?

 

Bitte lassen Sie mich wissen, wenn ich zusätzliche Informationen liefern kann. Um Ihre Frage von vorhin zu beantworten, glaube ich, dass jede Instanz über sich selbst iteriert, sodass ich die Variablenzusammenfassungen nicht speichern kann. Hoffentlich hilft das, danke für deine Hilfe!

Betreff: Zusammenfassungen für mehrere Diagramme in einem Bericht mit JSL speichern

Unten sind drei Vorschläge in der Reihenfolge, in der ich sie ausprobieren würde.

 

Sie könnten versuchen, ein Skript für die Tabelle „Kombinierte Daten erstellen“ zu erstellen

 

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("Charts",
 For(i = 1, i <= N Row(dt), i++,
  name = dt:Name[i];
  obj = dt << Control Chart Builder(
   Variables(Y(:height, :weight)),
   Show Control Panel(0),
   SendToReport(
    Dispatch(
     {},
     "graph display 1 title",
     TextEditBox,
     {Set Text(name || " Individual & Moving Range chart of height")}
    )
   )
  );
 )
);

dt_summaries = nw["Control Chart Builder", "height Limit Summaries", Table Box(1)] << Make Combined Data Table;

Oder Sie könnten Verweise auf diese Kontrolldiagrammersteller während der Schleife speichern und dann mit Save Summaries erneut eine Schleife ausführen (Sie sollten höchstwahrscheinlich Werte innerhalb der Schleife speichern und dann die Tabellen schließen):

 

 

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

ccb_list = {};

nw = New Window("Charts",
 For(i = 1, i <= N Row(dt), i++,
  name = dt:Name[i];
  obj = dt << Control Chart Builder(
   Variables(Y(:height, :weight)),
   Show Control Panel(0),
   SendToReport(
    Dispatch(
     {},
     "graph display 1 title",
     TextEditBox,
     {Set Text(name || " Individual & Moving Range chart of height")}
    )
   )
  );
  Insert Into(ccb_list, obj);
 );
);

For(i = 1, i <= N Items(ccb_list), i++,
 dt_temp = ccb_list[i] << Save Summaries;
 show(dt_temp); 
 //Close(dt_temp, no save);
);

Oder Sie können XPath verwenden, um die Referenzen abzurufen (und ich würde sie erneut wiederholen, um zu vermeiden, zu viele Tabellen zu öffnen).

 

 

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("Charts",
 For(i = 1, i <= N Row(dt), i++,
  name = dt:Name[i];
  obj = dt << Control Chart Builder(
   Variables(Y(:height, :weight)),
   Show Control Panel(0),
   SendToReport(
    Dispatch(
     {},
     "graph display 1 title",
     TextEditBox,
     {Set Text(name || " Individual & Moving Range chart of height")}
    )
   )
  );
 );
);

//((nw << XPath("//OutlineBox[text()='Control Chart Builder']")) << get scriptable object) << Save Summaries;

Wenn die << Zusammenfassungen speichern öffnet mehr als eine Tabelle, Sie müssen möglicherweise so etwas wie Get Data Table List () verwenden; Um zu sehen, welche die neuen sind, behandeln Sie sie und schließen Sie sie dann.

 

Betreff: Zusammenfassungen für mehrere Diagramme in einem Bericht mit JSL speichern

Danke dafür! Am Ende habe ich die zweite Version verwendet, die Sie mir geschickt haben, und sie war perfekt für das, was ich tue.

 

Danke!

Speichern Sie Zusammenfassungen für mehrere Diagramme in einem Bericht mit JSL

Ich habe einen Bericht, den ich ausführe und der zwischen 2 und 26 Diagramme auf einer Berichtsregisterkarte ausgibt, sodass sie alle gleichzeitig auf einer Registerkarte angezeigt werden können. Ich würde gerne eine Möglichkeit finden, die gespeicherten Zusammenfassungen für alle Diagramme im Bericht mithilfe von JSL zu exportieren. Im Moment klicke ich einfach bei gedrückter STRG-Taste auf die Schaltfläche im angehängten Bild und es exportiert alles, was ich brauche, in viele Datentabellen.

 

Gibt es eine Möglichkeit, JMP zu zwingen, die Speicherzusammenfassungen für einen Bericht nur mithilfe von JSL abzurufen? Es wäre in Ordnung, die Zusammenfassungen einzeln in Datentabellen zu ziehen. Alle anderen Beispiele, die ich gesehen habe, beinhalten die Zuweisung des Control Chart Builder zu einem Objekt und das anschließende Speichern dieser Zusammenfassungen. Ich würde das lieber nicht tun, kann es aber, wenn das meine einzige Option ist.

 

Danke!

MassenanpassungWindows