Re : Enregistrer les résumés de plusieurs graphiques dans un seul rapport à l'aide de JSLCliquez avec le bouton droit sur l'un des tableaux récapitulatifs et sélectionnez Transformer en tableau combiné. Est-ce que ça marche pour toi?
Re : Enregistrer les résumés de plusieurs graphiques dans un seul rapport à l'aide de JSLMerci pour la suggestion!
Je n'utilise pas réellement les tableaux récapitulatifs pour cela, j'essaie d'utiliser le bouton "Enregistrer les résumés" sur le générateur de cartes de contrôle à l'aide de JSL. Je dois enregistrer les résumés de nombreux graphiques qui existent dans un seul onglet de rapport. S'il vous plaît laissez-moi savoir si je peux fournir des informations supplémentaires à ce sujet, merci!
Re : Enregistrer les résumés de plusieurs graphiques dans un seul rapport à l'aide de JSLVoulez-vous enregistrer tous les résumés qui apparaissent à droite de la carte de contrôle ? Souhaitez-vous que les résumés soient regroupés dans un seul tableau de données ?
Ma suggestion précédente mettra toutes ces informations dans une table de données qui ressemble à ceci pour mon exemple :
Ce code illustre comment obtenir ce résultat à partir d'un script :
Names Default to Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
ccb = dt << Control Chart Builder( Variables( Y( :height, :weight ) ), Show Control Panel( 0 ) );
summary = Report( ccb )[TableBox(1)] << Make Combined Data Table;
Re : Enregistrer les résumés de plusieurs graphiques dans un seul rapport à l'aide de JSL@Mark_Bailey Merci pour ça! Je vois que cela peut être très utile pour obtenir un résumé de l'ensemble du graphique pour plusieurs graphiques dans un seul rapport. Cependant, si possible, j'aimerais pouvoir obtenir les résumés de chaque point sur chaque graphique. Exactement comment cela fonctionne lorsque vous utilisez le bouton dans l'image ci-jointe.
Est-ce possible de le faire en utilisant JSL?
Je vois maintenant que cela fonctionne lors de l'utilisation de ceci : summary = Report( ccb ) << Save Summaries;
Cependant, j'ai une autre couche dans mon ensemble de données, ce qui rend cela moins simple. Dans mon ensemble de données, plus qu'un seul générateur de graphique de contrôle est utilisé dans le rapport en fonction du nombre de lignes dans une autre table. Ainsi, lors de l'exécution de << Enregistrer les résumés sur l'objet auquel j'ai attribué le générateur de carte de contrôle, je n'obtiens que les résumés du dernier graphique créé, plutôt que tous. Existe-t-il un moyen de dire à JMP de consulter les autres graphiques afin que je puisse enregistrer ces résumés ?
Je vais essayer d'adapter l'ensemble de données Big Class en attendant pour clarifier ce que je cherche à faire.
Re : Enregistrer les résumés de plusieurs graphiques dans un seul rapport à l'aide de JSLOui, ce code est la base d'une solution :
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
obj = dt << Control Chart Builder( Variables( Y( :weight, :height ) ) );
dt = obj << Save Summaries;
Lancez-vous Control Chart Builder pour plusieurs réponses à la fois ? Si tel est le cas, vous devriez obtenir un tableau de données pour chaque réponse. Répétez-vous les réponses et lancez-vous Control Chart Builder pour une réponse à la fois ?
Re : Enregistrer les résumés de plusieurs graphiques dans un seul rapport à l'aide de JSLHé @Mark_Bailey , je pense que cela devrait donner une meilleure idée de la configuration de mes données. J'ai adapté le jeu de données Big Class en ajoutant ceci :
Names Default to Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Window ("Charts",
For ( i = 1, i <= N Row(dt), i++,
name = dt:Name[i];
obj = dt << Control Chart Builder( Variables( Y( :height, :weight ) ), Show Control Panel( 0 ), SendToReport(
Dispatch(
{},
"graph display 1 title",
TextEditBox,
{Set Text( name || " Individual & Moving Range chart of height" )}
)
) );
); );
dt = obj << Save Summaries;Les potions "nouvelle fenêtre" et "pour" ont été ajoutées pour refléter ce que je recherche. Si ce qui précède est exécuté, la fenêtre "Graphiques" contient 40 graphiques avec toutes les mêmes données. Dans l'intérêt de ce que nous faisons ici, veuillez supposer que chaque graphique aurait des données différentes, et à cause de cela, des résumés différents. Lorsque "Enregistrer les résumés" est exécuté au bas de celui-ci, je n'obtiens pas de résumés pour tous les graphiques, juste le dernier graphique de la fenêtre "Graphiques".
Existe-t-il un moyen pour moi de dire à ce code de tirer les résumés de l'un des graphiques qu'il a exécutés? Comme par exemple, si je veux les résumés du graphique 35 dans la fenêtre "Graphiques", puis-je l'obtenir en utilisant JSL comme dans l'exemple ci-dessus ? ou serais-je capable de les tirer tous d'une manière ou d'une autre ?
S'il vous plaît laissez-moi savoir si je peux fournir des informations supplémentaires. Pour répondre à votre question d'avant, je crois que ce qui se passe, c'est que chaque instance itère sur elle-même, donc je ne peux pas enregistrer les résumés des variables. J'espère que ça t'aidera, merci pour ton aide !
Re : Enregistrer les résumés de plusieurs graphiques dans un seul rapport à l'aide de JSLVous trouverez ci-dessous trois suggestions dans l'ordre dans lequel je les essayerais.
Vous pouvez essayer de créer un script Make Combined Data table
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
nw = New Window("Charts",
For(i = 1, i <= N Row(dt), i++,
name = dt:Name[i];
obj = dt << Control Chart Builder(
Variables(Y(:height, :weight)),
Show Control Panel(0),
SendToReport(
Dispatch(
{},
"graph display 1 title",
TextEditBox,
{Set Text(name || " Individual & Moving Range chart of height")}
)
)
);
)
);
dt_summaries = nw["Control Chart Builder", "height Limit Summaries", Table Box(1)] << Make Combined Data Table;
Ou vous pouvez stocker des références à ces générateurs de cartes de contrôle pendant la boucle, puis boucler à nouveau avec Enregistrer les résumés (vous devriez très probablement enregistrer les valeurs à l'intérieur de la boucle, puis fermer les tables) :
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
ccb_list = {};
nw = New Window("Charts",
For(i = 1, i <= N Row(dt), i++,
name = dt:Name[i];
obj = dt << Control Chart Builder(
Variables(Y(:height, :weight)),
Show Control Panel(0),
SendToReport(
Dispatch(
{},
"graph display 1 title",
TextEditBox,
{Set Text(name || " Individual & Moving Range chart of height")}
)
)
);
Insert Into(ccb_list, obj);
);
);
For(i = 1, i <= N Items(ccb_list), i++,
dt_temp = ccb_list[i] << Save Summaries;
show(dt_temp);
//Close(dt_temp, no save);
);
Ou vous pouvez utiliser XPath pour obtenir les références (et je les bouclerais à nouveau pour éviter d'ouvrir trop de tables)
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
nw = New Window("Charts",
For(i = 1, i <= N Row(dt), i++,
name = dt:Name[i];
obj = dt << Control Chart Builder(
Variables(Y(:height, :weight)),
Show Control Panel(0),
SendToReport(
Dispatch(
{},
"graph display 1 title",
TextEditBox,
{Set Text(name || " Individual & Moving Range chart of height")}
)
)
);
);
);
//((nw << XPath("//OutlineBox[text()='Control Chart Builder']")) << get scriptable object) << Save Summaries;
Si le << enregistrer les résumés ouvre plus d'une table, vous devrez peut-être utiliser quelque chose comme Get Data Table List (); pour voir quels sont les nouveaux, manipulez-les puis fermez-les.
Re : Enregistrer les résumés de plusieurs graphiques dans un seul rapport à l'aide de JSLMerci pour ça! J'ai fini par utiliser la deuxième version que vous m'avez envoyée et c'était parfait pour ce que je fais.
Merci!
Enregistrer les résumés de plusieurs graphiques dans un seul rapport à l'aide de JSLJ'ai un rapport que j'exécute et qui génère entre 2 et 26 graphiques dans un onglet de rapport afin qu'ils puissent tous être consultés en même temps, dans un seul onglet. J'aimerais trouver un moyen d'exporter les résumés de sauvegarde pour tous les graphiques du rapport à l'aide de JSL. À l'heure actuelle, je viens de CTRL + clic sur le bouton dans l'image ci-jointe et il exporte tout ce dont j'ai besoin dans de nombreuses tables de données.
Existe-t-il un moyen de forcer JMP à extraire les résumés de sauvegarde d'un rapport uniquement en utilisant JSL ? Tirer les résumés dans des tableaux de données un par un serait très bien. Tous les autres exemples que j'ai vus incluent l'attribution du générateur de cartes de contrôle à un objet, puis l'enregistrement de ces résumés. Je préférerais ne pas le faire, mais je peux le faire si c'est ma seule option.
Merci!
Personnalisation de masseles fenêtres
