Re: 평균 열에 대한 JMP 스크립트안녕하세요 @hsjoyner ,
column() 함수를 조사했습니까? 열 이름을 사용하는 대신 인덱스를 사용할 수 있습니다.이것은 for() 루프에서 유용할 수 있습니다.
Re: 평균 열에 대한 JMP 스크립트열의 수가 고정되어 있으면 하드 코딩할 수 있습니다. 수단 ,
"등"인 경우 가변적이므로 일부가 필요할 수 있습니다. 에 집어 넣다 그리고 평가(대체()):
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
offset = 5;
nc = N Col( dt );
length = 10;
groups = Floor((nc - offset) / length);
For( group = 1, group <= groups, group++,
myFormula = Expr( Mean() );
For( i = 1, i <= length, i++,
Insert Into( myFormula, NameExpr(As Column( offset + (group-1)*length +i ) ))
);
myName = "average" || Char( group );
Eval(Substitute(Expr(new Column(__myName__,Formula(__myFormula__))),Expr(__myFormula__),NameExpr(myFormula),Expr(__myName__),NameExpr(myName) ));
);
Re: 평균 열에 대한 JMP 스크립트다음은 귀하가 찾고 있는 것을 생성하기를 바라는 스크립트입니다.결정되지 않은 열 수에 대해 10개의 열 그룹을 평균화하는 새 열을 만듭니다.
names default to here(1);
// Create an example data table to use for illustration of how to
// create the sets of average columns
dt =
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
// Delete the first 3 columns to match the description
// of the suggested data table structure
dt << delete columns({"lot_id","wafer","wafer ID in lot ID"});
// Create new columns that have the groups of 10 columns
startingNCol = N Cols(dt);
start = 2;
groupSize = 10;
while(start+groupSize<=startingNCol,
eval(substitute(expr(
dt << New Column("Average " || char( start ) || "-" || char(start + groupSize),
set each value(Mean(current data table()[row(),index(theStart,theEnd)])));
),
expr(theStart), start, expr(theEnd), start+groupSize
));
start=start+groupSize;
);
Re: 평균 열에 대한 JMP 스크립트Mean(current data table()[row(),index(theStart,theEnd)])
와우, 매우 우아합니다. 열 참조로 평균을 수동으로 채우는 것보다 훨씬 좋습니다!
평균 열에 대한 JMP 스크립트열 세트를 평균값으로 새 열로 평균화하는 명령을 작성하려고 하는 초보 JMP 스크립트 작성자입니다. 이는 열을 강조 표시한 다음 새 수식 열 > 결합 > 평균을 선택하는 것과 같습니다. 그러나 스크립트 라이브러리나 온라인에서 이 작업을 수행할 수 있는 항목을 찾을 수 없습니다. 누구든지 제안이 있습니까?
복잡함을 더하기 위해 스크립트가 2-11, 12-21, 22-31 등의 열을 가져와서 각 열 그룹의 평균을 내길 원합니다. 열에는 이름이 설정되어 있지 않으므로 스크립트에 열 이름을 넣을 수는 없습니다(열 이름은 샘플 이름이므로 이름을 일관성 있게 유지해야 하기 때문에 이름을 일관되게 만들 수 없습니다). 각 JMP 파일의 샘플 수가 크게 다를 수 있으므로 각 JMP 파일의 열 그룹 수는 일관되지 않습니다. 간단한 방법이 있습니까?
도움이 된다면 Mac에서 JMP 17.0.0을 사용하고 있습니다. 도움을 주시면 감사하겠습니다!
데이터 혼합 및 정리맥 OSRe: 평균 열에 대한 JMP 스크립트수식 열이 평균 2-12 열과 동일한 값을 생성하지 못하는 이유는 무엇입니까?
평균( :NPN1, :PNP1, :PNP2, :NPN2, :PNP3, :IVP1, :PNP4, :NPN3, :IVP2, :NPN4, :SIT1 )
편집: 댓글을 쓰는 동안 주의가 산만해져서 위의 공식이 일치하는 값을 생성합니다.
추가 답변: Mean()은 열 형식 속성에 매우 민감한 것 같습니다. 열을 고정 십진수 너비 15, 십진수 3으로 설정한 경우와 최적 너비 12로 설정한 경우 내 데이터 테이블에서 다른 결과가 나왔습니다. 이 문제를 피하기 위한 권장 사항이 있습니까?
Re: 평균 열에 대한 JMP 스크립트안녕하세요 @hsjoyner ,
제가 제대로 이해했다면, 모든 열 그룹의 평균을 원하신다면 테이블에서 열 그룹 목록을 가져온 다음, 해당 그룹 이름을 반복하여 각 그룹의 열을 동적으로 가져오는 수식 열을 만들 수 있을 겁니다. 다음과 같은 방식입니다.
dt = Current Data Table();
groupNames = dt << get column groups names;
For Each( {groupName, index}, groupNames,
Eval(
Eval Expr(
dt << New Column( groupName || " Mean",
Formula( Mean( Current Data Table() << get column group( Expr( groupName ) ) ) )
)
)
)
);
도움이 되길 바랍니다!
@줄리안
수정: 메시지와 답글을 다시 읽어본 결과, 테이블에서 실제로 그룹화된 열이 아니라 열 그룹(열 집합)에 대해 말씀하시는 것 같습니다. 따라서 이 답변은 도움이 되지 않겠지만, 혹시라도 그런 상황에 처하신 분이 계실까 봐 여기에 남겨둡니다!:grinning_face:
