617205_ja-JP

liliconcom

JSL Open 関数は、オプションの引数「列の選択」に基づいてサブセットを作成していません

こんにちは、みんな、

 

Open メソッドを使用して、さまざまな構造化データ ファイルを jmp データフレームにインポートする作業を行っています。 最初のコードブロックで希望するようにメソッドを使用してサブセット化できるため、2番目のケースで何が間違っているのかを理解するのに苦労しています。 どんな助けでも大歓迎です！

 

[ファイル名] は、変数参照ではなく、ファイル名の文字列形式です。 会社の方針でフルネームは省略しております。

 

列の選択を使用した作業サブセット:

sl = Open(Pick File()/"[file name].xls",
 Select Columns ("Description", "Sample Mix", "Analyte Type", :Name("Threshold (nA)"), "Expected Outcome", "Lane", "Heater")
) << Set Name ("Sample Lookup");

サブセットが機能していません (元の列をすべて取得しています):

sd = Open (Pick File()/"[file name].csv", 
 Select Columns ("Accession Number", "Pad Name", " Warnings")
) << Set Name("Signal Data");

一番下のケースが列に基づいてサブセット化されない理由は、xls と csv のデータ形式が異なることだけです。 しかし、これが事実である場合、これを修正するにはどうすればよいでしょうか? ありがとう！

分析データ表スクリプティングRe: JSL Open 関数は、オプションの引数「Select Columns」に基づいてサブセットを作成していません

やあ、

CSV インポート パラメータに正しい行が列ヘッダーとして含まれていることを確認しましたか? Open ステートメントを、正しいパラメーターを使用した Import Data ステートメントに置き換えるだけの簡単なことかもしれません。

 

ちょっとした考え。

 

一番

TS

Re: JSL Open 関数は、オプションの引数「Select Columns」に基づいてサブセットを作成していません

列を省略する csv 固有の方法があります。 select columns() が JMP データ テーブルに固有のものであることを示すには、おそらくいくつかのドキュメントが必要です。 (編集: 開発チームに送信されたメモ)

編集: csv インポート ウィザードを使用した後のソース スクリプトからの JSL

Open(
 "$DOWNLOADS/Big_Class.csv",
 columns(
  New Column( "name", Character, "Nominal" ),
  Omitted Column( . ), // leave out the "age" column
  New Column( "sex", Character, "Nominal" ),
  Omitted Column( . ), // leave out the "height" column
  New Column( "weight", Numeric, "Continuous", Format( "Best", 12 ) )
 ),
 Import Settings(
  End Of Line( CRLF, CR, LF ),
  End Of Field( Comma, CSV( 0 ) ),
  Strip Quotes( 1 ),
  Use Apostrophe as Quotation Mark( 0 ),
  Use Regional Settings( 0 ),
  Scan Whole File( 1 ),
  Treat empty columns as numeric( 0 ),
  CompressNumericColumns( 0 ),
  CompressCharacterColumns( 0 ),
  CompressAllowListCheck( 0 ),
  Labels( 1 ),
  Column Names Start( 1 ),
  First Named Column( 1 ),
  Data Starts( 2 ),
  Lines To Read( "All" ),
  Year Rule( "20xx" )
 )
)

編集：省略交換できます新しいこのような

Omitted Column( "age", Numeric, "Continuous", Format( "Best", 12 ) ),

省略されたものを文書化します。 値が無視されていると確信しています。 無視する列がたくさんある場合は、JSL の編集も簡単になります。

Re: JSL Open 関数は、オプションの引数「Select Columns」に基づいてサブセットを作成していません

こんにちはティエリー、

 

私はJMPのJSL側に慣れていないので、現在「開く」がすべてのタイプの主な機能だと思っていましたが、csvタイプのファイルの「データのインポート」を調べます。 ご指導よろしくお願いします！

 

ありがとう、

ニール・スレジャン

Re: JSL Open 関数は、オプションの引数「Select Columns」に基づいてサブセットを作成していません

クレイジさん、こんにちは。

 

画面記録の問題を解決し、JMP がインポートと除外のプロセスをどのように記録するかを示し、そのソース コードをコピーしていただき、ありがとうございます。 それは非常に有益であり、同様に、「列の選択」についてさらにドキュメントを要求してくれたことに感謝します。 助けてくれてありがとう！

 

謹んで、

ニール・スレジャン