613797_ko-KR

liliconcom

스크립팅 그래프 빌더 질문

스크립터를 위한 또 다른 수수께끼...

다음과 같은 그래프가 있는 경우:

dt = Open("$Sample_Data/Big Class.jmp");

graph = dt << Graph Builder(
 Size( 532, 452 ),
 Show Control Panel( 0 ),
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) )
);

 

그래프 창을 만들고 그래프 작성기 자체에 메시지만 사용한 후(즉, 테이블에서 행 상태를 고려하자) 아래와 같이 보이게 하려면 어떻게 해야 합니까? GUI를 통해 범례의 "높이" 옆에 있는 마커를 마우스 오른쪽 버튼으로 클릭하고 마커와 색상을 변경합니다. 그래도 JSL 메시징을 통해 수행하는 방법을 알 수 없습니다.  

dt = Open("$Sample_Data/Big Class.jmp");<BR /><BR />graph = Graph Builder(
 Size( 532, 452 ),
 Show Control Panel( 0 ),
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    3,
    Properties(
     0,
     {Line Color( 51 ), Marker( "Filled Down Triangle" )},
     Item ID( "height", 1 )
    )
   )}
  )
 )
);

생각?

 

중

Re: 스크립팅 그래프 빌더 질문

안녕 마이크-

범례 서버와 범례 항목을 사용하여 범례에 값을 설정하면 이렇게 할 수 있다고 생각합니다. 나는 최근에 비슷한 것을 시도하고 있었고 이러한 기능을 발견했습니다.

names default to here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

gb = Graph Builder(
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) )
);

server = gb << get legend server;
item1 = server << get legend item( 3, 1 );
item1 << set properties(
 {
  marker size ( 5 ),
  marker ("Filled Down Triangle"),
  Line Color ( 19 )
 }
);

item2 = server << get legend item( 4, 1 );
item2 << set properties(
 {
  Line Color ( 25 ),
  Line Style ( 2 )
 }
);

-스콧

Re: 스크립팅 그래프 빌더 질문

저도 같은 생각을 하고 있었는데, 대시보드/애플리케이션 빌더 창 내부에 있을 때 제대로 작동하지 않는 전략에 대해 뭔가가 있는 것 같습니다. Legend Server에 연결할 수 없는 것 같습니다.