613797_zh-TW

liliconcom

腳本圖生成器問題

那裡的腳本編寫者的另一個腦筋急轉彎...

如果我有一個看起來像這樣的圖表：

dt = Open("$Sample_Data/Big Class.jmp");

graph = dt << Graph Builder(
 Size( 532, 452 ),
 Show Control Panel( 0 ),
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) )
);

 

在創建圖形窗口並僅使用圖形生成器本身的消息後（即讓我們考慮表外的行狀態），我將如何使其看起來像下面這樣。 通過 GUI，我會通過右鍵單擊圖例中“高度”旁邊的標記並更改標記和顏色來完成此操作。 不過，我不知道如何通過 JSL 消息傳遞來做到這一點。  

dt = Open("$Sample_Data/Big Class.jmp");<BR /><BR />graph = Graph Builder(
 Size( 532, 452 ),
 Show Control Panel( 0 ),
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    3,
    Properties(
     0,
     {Line Color( 51 ), Marker( "Filled Down Triangle" )},
     Item ID( "height", 1 )
    )
   )}
  )
 )
);

想法？

 

米

回复：腳本圖生成器問題

嗨邁克-

我認為您可以通過使用 Legend Server 和 Legend Item 在圖例中設置值來做到這一點。 我最近試圖做類似的事情並遇到了這些功能。

names default to here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

gb = Graph Builder(
 Variables( X( :weight ), Y( :height ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) )
);

server = gb << get legend server;
item1 = server << get legend item( 3, 1 );
item1 << set properties(
 {
  marker size ( 5 ),
  marker ("Filled Down Triangle"),
  Line Color ( 19 )
 }
);

item2 = server << get legend item( 4, 1 );
item2 << set properties(
 {
  Line Color ( 25 ),
  Line Style ( 2 )
 }
);

-斯科特

回复：腳本圖生成器問題

我也在想同樣的事情，但我想當它在儀表板/應用程序構建器窗口內時，該策略有些地方無法正常工作。 我似乎無法進入傳奇服務器。