608588_zh-TW

liliconcom

將表達式插入列表

你好，

 

我正在學習如何處理表情操作，但我很難理解它。

 

在下面程式碼的第一部分中，我可以成功地將字串列名稱插入到 column() 表達式中，但無法將生成的表達式插入到列表中。

 

第二部分分解交互項（這是來自 SLS 的效果列表），將它們插入到它們自己的 column() 表達式中，將它們重新組合在一起作為交互項，然後將其插入到列表中。這部分不起作用。

 

有沒有人有任何有用的提示或看到我對表達操作如何運作的誤解？提前謝謝您！

 

names default to here(1);

// Basic need below - but only works for single column names
collist = { "Col 1", "Col 2", "Col 3", "Col 4", "Col 5" };

newlist = {};

for( i = 1, i <= N items(collist), i++,

 // Empty arg to identify cols by names
 name_arg = Expr( column() );

 insert into( name_arg, eval insert( collist[i] ) ); // result: column("Col 1"), or other cols inserted <-- Working as intended
 
 show( name_arg );  // Shows successful insert into's
 
 insert into( newlist, insert into( name_arg, eval insert( collist[i] ) ) );
 // Nested insert into doesn't work
 // Need to insert the result of the first insert into, into newlist

);

show( newlist ); // Currently shows empty list

/////////////////////////////////////////  DOES NOT WORK, BELOW

// Advanced flow - interaction detection 
collist2 = { "Col 1", "Col 2", "Col 3", "Col 4", "Col 5", "Col 1*Col 2", "Col 2*Col 4", "Col 5*Col 5" };

newlist2 = {};

for( a = 1, a <= N items( collist2 ), a++,

 // Empty arg to identify cols by names
 name_arg = Expr( column() );
 
 // For whatever the match below, the result must be added to newlist2
 // Regex works, as per regex101.com
 if( !contains( collist2[a], "*" ), insert into( name_arg2, eval insert( collist2[a] ) ), // single term insert, refer to basic needs flow above
  insert into( name_arg2, eval insert( regex( collist2[a], "^(.*)\*(.*)$", "\1" ) ) ); // Breaks apart 1st group to insert into column()
  insert into( name_arg2, eval insert( regex( collist2[a], "^(.*)\*(.*)$", "\2" ) ) ); // Breaks apart 2nd group to insert into column()
  
  // The line below is a mockup of joining back together the first and second group together as interaction terms - doesn't work
  //eval expr( expr( insert into( name_arg2, eval insert( regex( mylist2[a], "^(.*)\*(.*)$", "\1" ) ) )*insert into( name_arg2, eval insert( regex( mylist2[a], "^(.*)\*(.*)$", "\2" ) ) );
 )
 
);

Desired_output = { column("Col 1"), column("Col 2"), column("Col 3"), column("Col 4"), column("Col 5"), column("Col 1")*column("Col 2"),
 column("Col 2")*column("Col 4"), column("Col 5")*column("Col 5") };

品質和工藝工程視窗回覆：將表達式插入列表

讓腳本的第二部分開始工作，即帶有交互項的部分！

</CODE></PRE><P>&nbsp;</P><PRE><CODE class=" language-jsl">for( a = 1, a <= N items( collist2 ), a++,

 // Empty arg to identify cols by names
 name_arg = Expr( column() );
 name_arg2 = Expr( column() );
 
 // For whatever the match below, the result must be added to newlist2
 // Regex works, as per regex101.com
 if( !contains( collist2[a], "*" ), insert into( name_arg, eval insert( collist2[a] ) );
   insert into( newlist2, name expr( name_arg ) ), // single term insert, refer to basic needs flow above
  insert into( name_arg, eval insert( regex( collist2[a], "^(.*)\*(.*)$", "\1" ) ) ); // Breaks apart 1st group to insert into column()
  insert into( name_arg2, eval insert( regex( collist2[a], "^(.*)\*(.*)$", "\2" ) ) ); // Breaks apart 2nd group to insert into column()
  insert into( newlist2, Eval Expr( expr( name_arg )*expr( name_arg2 ) ) );

 );
 
);

show( newlist2 );

Output:
newlist2 = {Column("Col 1"), Column("Col 2"), Column("Col 3"), Column("Col 4"), Column("Col 5"), Column("Col 1") * Column("Col 2"), Column("Col 2") * Column("Col 4"), Column("Col 5") * Column("Col 5")};

希望這有助於指導其他人學習表達操作。 這是一段漫長的旅程 - 但它很強大且值得！

回覆：將表達式插入列表

第一部分，我想將表達式插入到列表中，可以透過下面的程式碼行輕鬆解決。

 

insert into( newlist, name expr( name_arg ) );

繼續解決下一節！