607892_it-IT

liliconcom

Script - Estrazione dei limiti delle specifiche dalla capacità del processo di distribuzione

Sto tentando di scrivere uno script (JMP 16.0) per selezionare colonne da un set di dati, creare distribuzioni, eseguire un adattamento continuo "ALL" e generare la capacità di processo sul miglior adattamento (vedere sotto).

Ciò con cui ho problemi è capire come generare una tabella con le caratteristiche delle distribuzioni, in particolare i limiti di specifica generati. Inoltre ho difficoltà a combinare tutte le distribuzioni in una singola finestra. Qualsiasi suggerimento sarebbe molto apprezzato, ho provato a cercare nella documentazione degli oggetti scriptabili senza successo.

file = Current Data Table ();
TableList = List ();
For (i = 1, i <= NTable(), i++,
     TableList [i] = Data Table (i) << Get Name
);
ColSelect = Column Dialog (
     Column Use = ColList ("Add", Max Col (N Col()))
);
For (i = 1, i <= N Items(ColSelect["ColumnUse"]), i++,
    colName = ColSelect ["ColumnUse"] [i] << Get Name;
     obj = file << Distribution(
         Continuous Distribution(Column(Eval(colName)), Fit ALL)
     );
     specLimits = obj << (Fit Handle["best"] << Process Capability( Set Sigma Multiplier for Quantile Spec Limits( 3 ), show limits ));
      );

Esplorazione e visualizzazione dei datiIngegneria della qualità e dei processiRi: Script- Estrazione dei limiti delle specifiche dalla capacità del processo di distribuzione

Che ne dici del seguente script? Spero che sia d'aiuto.

file = Open("$SAMPLE_DATA/Cities.jmp");
ColSelect = Column Dialog( Column Use = ColList( "Add", Max Col( N Col() ) ) );
If( ColSelect["Button"] != 1,
 Throw();
);

spec limit aa = Associative Array();

nw = New Window( "Combined Results",
 H List Box(
  For( i = 1, i <= N Items( ColSelect["ColumnUse"] ), i++,
   colName = ColSelect["ColumnUse"][i] << Get Name;
   obj = file << Distribution(
    Continuous Distribution( Column( Eval( colName ) ), Fit ALL )
   );

   rpt = obj << report;
   best dist = rpt[Outline Box( "Compare Distributions" )][Table Box( 1 )][
   String Col Box( 1 )] << get( 1 );

   Eval(
    Eval Expr(
     obj << (Fit Handle[Expr( best dist )] <<
     Process Capability( Set Sigma Multiplier for Quantile Spec Limits( 3 ) ))
    )
   );

   spec limits = rpt[Outline Box( "Process Capability" )][
   Outline Box( "Process Summary" )][Table Box( 1 )][Number Col Box( 1 )] << get;
   spec limit aa[colName] = Eval List( {spec limits, best dist} );
  )
 )
);

//Save to New Data Table
result dt = New Table( "Results" );
colnames = spec limit aa << get keys;

result dt << addmultiplecolumns( "key", N Items( colnames ), Numeric );

For( i = 1, i <= N Col( result dt ), i++,
 Column( result dt, i ) << set name( colnames[i] )
);

result dt << addrows( 5 );

For( j = 1, j <= N Col( result dt ), j++,
 For Each Row(
  i = Row();
  Try( result dt[i, colnames[j]] = spec limit aa[colnames[j]][1][i] );
 )
);