607892_fr-FR

liliconcom

Script - Extraction des limites de spécifications à partir de la capacité du processus de distribution

J'essaie d'écrire un script (JMP 16.0) pour sélectionner des colonnes à partir d'un ensemble de données, créer des distributions, effectuer un ajustement continu « TOUS » et générer une capacité de processus sur le meilleur ajustement (voir ci-dessous).

Ce qui me pose problème, c'est de savoir comment générer un tableau avec les caractéristiques des distributions, en particulier les limites de spécifications générées. J'ai également des difficultés à combiner toutes les distributions dans une seule fenêtre. Tout conseil serait grandement apprécié, j'ai essayé de consulter la documentation des objets scriptables sans succès.

file = Current Data Table ();
TableList = List ();
For (i = 1, i <= NTable(), i++,
     TableList [i] = Data Table (i) << Get Name
);
ColSelect = Column Dialog (
     Column Use = ColList ("Add", Max Col (N Col()))
);
For (i = 1, i <= N Items(ColSelect["ColumnUse"]), i++,
    colName = ColSelect ["ColumnUse"] [i] << Get Name;
     obj = file << Distribution(
         Continuous Distribution(Column(Eval(colName)), Fit ALL)
     );
     specLimits = obj << (Fit Handle["best"] << Process Capability( Set Sigma Multiplier for Quantile Spec Limits( 3 ), show limits ));
      );

Exploration et visualisation des donnéesIngénierie de la qualité et des procédésRe : Script - Extraction des limites de spécification de la capacité du processus de distribution

Qu'en est-il du script suivant ? J'espère que cela aide.

file = Open("$SAMPLE_DATA/Cities.jmp");
ColSelect = Column Dialog( Column Use = ColList( "Add", Max Col( N Col() ) ) );
If( ColSelect["Button"] != 1,
 Throw();
);

spec limit aa = Associative Array();

nw = New Window( "Combined Results",
 H List Box(
  For( i = 1, i <= N Items( ColSelect["ColumnUse"] ), i++,
   colName = ColSelect["ColumnUse"][i] << Get Name;
   obj = file << Distribution(
    Continuous Distribution( Column( Eval( colName ) ), Fit ALL )
   );

   rpt = obj << report;
   best dist = rpt[Outline Box( "Compare Distributions" )][Table Box( 1 )][
   String Col Box( 1 )] << get( 1 );

   Eval(
    Eval Expr(
     obj << (Fit Handle[Expr( best dist )] <<
     Process Capability( Set Sigma Multiplier for Quantile Spec Limits( 3 ) ))
    )
   );

   spec limits = rpt[Outline Box( "Process Capability" )][
   Outline Box( "Process Summary" )][Table Box( 1 )][Number Col Box( 1 )] << get;
   spec limit aa[colName] = Eval List( {spec limits, best dist} );
  )
 )
);

//Save to New Data Table
result dt = New Table( "Results" );
colnames = spec limit aa << get keys;

result dt << addmultiplecolumns( "key", N Items( colnames ), Numeric );

For( i = 1, i <= N Col( result dt ), i++,
 Column( result dt, i ) << set name( colnames[i] )
);

result dt << addrows( 5 );

For( j = 1, j <= N Col( result dt ), j++,
 For Each Row(
  i = Row();
  Try( result dt[i, colnames[j]] = spec limit aa[colnames[j]][1][i] );
 )
);