607892_de-DE

liliconcom

Skript - Extrahieren von Spezifikationsgrenzen aus der Verteilungsprozessfähigkeit

Ich versuche, ein Skript (JMP 16.0) zu schreiben, um Spalten aus einem Datensatz auszuwählen, Verteilungen zu erstellen, eine kontinuierliche Anpassung „ALLE“ durchzuführen und die Prozessfähigkeit für die beste Anpassung zu generieren (siehe unten).

Ich habe Probleme damit, herauszufinden, wie ich eine Tabelle mit den Eigenschaften der Verteilungen, insbesondere den generierten Spezifikationsgrenzen, erstellen kann. Außerdem habe ich Schwierigkeiten, alle Verteilungen in einem einzigen Fenster zu kombinieren. Ich wäre für jeden Hinweis sehr dankbar. Ich habe versucht, in der Dokumentation für skriptfähige Objekte nachzuschauen, aber ohne Erfolg.

file = Current Data Table ();
TableList = List ();
For (i = 1, i <= NTable(), i++,
     TableList [i] = Data Table (i) << Get Name
);
ColSelect = Column Dialog (
     Column Use = ColList ("Add", Max Col (N Col()))
);
For (i = 1, i <= N Items(ColSelect["ColumnUse"]), i++,
    colName = ColSelect ["ColumnUse"] [i] << Get Name;
     obj = file << Distribution(
         Continuous Distribution(Column(Eval(colName)), Fit ALL)
     );
     specLimits = obj << (Fit Handle["best"] << Process Capability( Set Sigma Multiplier for Quantile Spec Limits( 3 ), show limits ));
      );

Datenexploration und -visualisierungQualitäts- und ProzesstechnikBetreff: Skript – Extrahieren von Spezifikationsgrenzen aus der Fähigkeit des Verteilungsprozesses

Wie wäre es mit folgendem Skript? Ich hoffe es hilft.

file = Open("$SAMPLE_DATA/Cities.jmp");
ColSelect = Column Dialog( Column Use = ColList( "Add", Max Col( N Col() ) ) );
If( ColSelect["Button"] != 1,
 Throw();
);

spec limit aa = Associative Array();

nw = New Window( "Combined Results",
 H List Box(
  For( i = 1, i <= N Items( ColSelect["ColumnUse"] ), i++,
   colName = ColSelect["ColumnUse"][i] << Get Name;
   obj = file << Distribution(
    Continuous Distribution( Column( Eval( colName ) ), Fit ALL )
   );

   rpt = obj << report;
   best dist = rpt[Outline Box( "Compare Distributions" )][Table Box( 1 )][
   String Col Box( 1 )] << get( 1 );

   Eval(
    Eval Expr(
     obj << (Fit Handle[Expr( best dist )] <<
     Process Capability( Set Sigma Multiplier for Quantile Spec Limits( 3 ) ))
    )
   );

   spec limits = rpt[Outline Box( "Process Capability" )][
   Outline Box( "Process Summary" )][Table Box( 1 )][Number Col Box( 1 )] << get;
   spec limit aa[colName] = Eval List( {spec limits, best dist} );
  )
 )
);

//Save to New Data Table
result dt = New Table( "Results" );
colnames = spec limit aa << get keys;

result dt << addmultiplecolumns( "key", N Items( colnames ), Numeric );

For( i = 1, i <= N Col( result dt ), i++,
 Column( result dt, i ) << set name( colnames[i] )
);

result dt << addrows( 5 );

For( j = 1, j <= N Col( result dt ), j++,
 For Each Row(
  i = Row();
  Try( result dt[i, colnames[j]] = spec limit aa[colnames[j]][1][i] );
 )
);