Hola,
Una posible solución de baja tecnología sería calcular su curva de referencia en una columna separada en su tabla de datos y luego trazarla con el resto de los datos.
Mejor,
TS
Hola,
Al hacer clic con el botón derecho en el gráfico, seleccione "Personalizar" en el menú contextual, haga clic en el icono "+". Desde aquí puede agregar un script usando la función Y función ( ), que toma 2 argumentos: una expresión (la función) y la variable de dominio (aquí, x).
Haga clic en Aceptar y listo.
Esto también es fácil de hacer a través de secuencias de comandos con la función Y ( ). Aquí, se representa y = 2x^2 + 3x -5, correspondiente a los coeficientes [2, 3, -5]. He usado la regla de Horner aquí, ya que facilita las cosas en la siguiente ilustración.
dt = astable(J(40,2,randominteger(-20,20)));
gb = dt << Graph Builder( Variables( X( :Col2 ), Y( :Col1 ) ), Elements( Points( X, Y, Legend( 3 ) ) ) );
report(gb)[framebox(1)] << add graphics script ( Y Function( (2 * x + 3) * x - 5, x ) );
Un problema es que los coeficientes pueden determinarse en tiempo de ejecución, pueden no ser números enteros y el grado del polinomio puede ser desconocido. En este caso, algo como lo siguiente funcionará:
dt = astable(J(40,2,randominteger(-20,20)));
gb = dt << Graph Builder(
Variables( X( :Col2 ), Y( :Col1 ) ),
Elements( Points( X, Y, Legend( 3 ) ) ),
);
// get random uniform coefficient matrix
coef = J(5, 1, randomuniform());
// build an expression using Horner's rule:
for each ( {v, i }, coef,// i = 1; v = coef[i];
if (i > 1,
fctExp = insert ( insert ( expr ( multiply ( ) ), nameExpr ( fctExp ) ), expr ( x ) );
,
fctExp = expr ( 0 );
);
fctExp = insert ( insert ( expr( add ( ) ), nameexpr( fctExp ) ), v );
);
// substitute into a graph script expressison and evaluate
graphAdd = expr (
report(gb)[framebox(1)] << add graphics script ( Y Function( _EXPRESSION_ , x ) )
);
eval ( substitute ( nameexpr(graphAdd), expr( _EXPRESSION_ ), nameexpr ( fctExp ) ) );
//show the expression in the log
show ( fctExp )
Su sugerencia inicial de agregar un script a través de la función de personalización funcionó. ¡Gracias!
Hola.
Estoy trazando datos usando Fit Y by X.
Me gustaría trazar una cuadrática preconocida como línea de referencia (en lugar de ajustar una a los datos que se muestran). Puedo ver cómo se haría esto para un ajuste lineal usando Ajuste especial, lineal, luego restringir la intersección y la pendiente a cualquier valor, pero al seleccionar cuadrático (o órdenes más altos) del cuadro desplegable, no le da un lugar para ingresar los coeficientes adicionales para restringir.
¿Puedo hacerlo a través de un script y, de ser así, cuál sería el formato?
Muchas gracias
