591001_zh-TW

liliconcom

任何關於如何正確實施的解釋將不勝感激。

 

在 JSL 中向匯總表新增計算

大家好，

回到另一個讓我困惑的問題，嘗試透過建立新列將計算添加到摘要中。我正在嘗試建立名為 GD1 的列，我希望將 N(4) 和 N(5) 列中的值（如果存在）相加。這是我嘗試檢查這些列是否存在並對它們進行求和（如果存在），這似乎在調試器中終止，但我不明白為什麼：

Data Table( "Fun pull" ) << Summary(
	Group( :Name( "90440011_119325" ) ),
	N,
	Subgroup( :Sort_Lot ),
	Freq( "None" ),
	Weight( "None" );

	newcol1 = Expr(
		Current Data Table() << New Column( "GD1",
			Numeric,
			"Continuous",
			Formula( Sum( :Name( "N(1)" ), :Name( "N(2)" ), :Name( "N(3)" ) ) )
		)
	);
	Eval( Eval Expr( newcol1 ) );

	newcol2 = Expr(
		Current Data Table() << New Column( "Test",
			formula(
				If( Contains( Current Data Table() << get column names( string ), "N(4)" ),
					Sum( :GD1, Name( "N(4)" ) ),
					If( Contains( Current Data Table() << get column names( string ), "N(5)" ),
						Sum( :GD1, Name( "N(5)" ) ),
						Sum( :GD1 )
					)
				)
			)
		);
		Eval( Eval Expr( newcol2 ) );
	);
)

任何有關如何正確實現這一點的解釋將不勝感激。

品質和工藝工程回复：將計算添加到 JSL 中的匯總表

JSL 的主要問題是摘要平台的右括號包括用於創建新列的所有 JSL。摘要平台需要完成，然後添加新列。

其次，由於在摘要平台中創建的數據表中列的實際名稱的細節，因此不需要使用您嘗試的複雜代碼。在下面的示例中，我簡化了您的代碼。

第三，我更改了您的代碼，使數據表引用更具體，從而使代碼更具可讀性，並確保 JMP 確切知道要處理的數據表。此外，我更改了對結構中具有復雜名稱的列的引用

:Name( "name" )

到

:"name"n

這是將在未來使用的已宣布結構。

Data Table( "semiconductor capability" ) << Summary(
 Group( :"90440011_119325"n ),
 N,
 Subgroup( :Sort_Lot ),
 Freq( "None" ),
 Weight( "None" ),
 Output Table( "New Table" )
);

Data Table( "New Table" ) << New Column( "GD1",
 Numeric,
 "Continuous",
 Formula( Sum( :"N(1)"n, :"N(2)"n, :"N(3)"n ) )
);

Current Data Table() << New Column( "Test",
 formula(
  If( Contains( Data Table( "New Table" ) << get column names( string ), "N(4)" ),
   Sum( :GD1, :"N(4)"n ),
   If( Contains( Data Table( "New Table" ) << get column names( string ), "N(5)" ),
    Sum( :GD1, :"N(5)"n ),
    Sum( :GD1 )
   )
  )
 )
);

 

 

回复：將計算添加到 JSL 中的匯總表

非常清晰的解釋，非常感謝！