591001_de-DE

liliconcom

Jede Erklärung, wie dies korrekt implementiert werden kann, wäre sehr willkommen.

 

Hinzufügen einer Berechnung zur Übersichtstabelle in JSL

Hallo zusammen,

Ich bin mit einer weiteren Frage zurück, die mich verblüfft hat, als ich versuchte, einer Zusammenfassung eine Berechnung hinzuzufügen, indem ich eine neue Spalte erstellte. Ich versuche eine Spalte namens GD1 zu erstellen, in der ich die Werte in den Spalten N(4) und N(5) summieren möchte, sofern vorhanden. Hier ist mein Versuch, das Vorhandensein dieser Spalten zu überprüfen und sie zu summieren, falls sie vorhanden sind. Dies scheint im Debugger abzubrechen, aber ich verstehe nicht, warum:

Data Table( "Fun pull" ) << Summary(
	Group( :Name( "90440011_119325" ) ),
	N,
	Subgroup( :Sort_Lot ),
	Freq( "None" ),
	Weight( "None" );

	newcol1 = Expr(
		Current Data Table() << New Column( "GD1",
			Numeric,
			"Continuous",
			Formula( Sum( :Name( "N(1)" ), :Name( "N(2)" ), :Name( "N(3)" ) ) )
		)
	);
	Eval( Eval Expr( newcol1 ) );

	newcol2 = Expr(
		Current Data Table() << New Column( "Test",
			formula(
				If( Contains( Current Data Table() << get column names( string ), "N(4)" ),
					Sum( :GD1, Name( "N(4)" ) ),
					If( Contains( Current Data Table() << get column names( string ), "N(5)" ),
						Sum( :GD1, Name( "N(5)" ) ),
						Sum( :GD1 )
					)
				)
			)
		);
		Eval( Eval Expr( newcol2 ) );
	);
)

Für jede Erklärung, wie dies korrekt umgesetzt werden kann, wären wir sehr dankbar.

Qualitäts- und VerfahrenstechnikBetreff: Berechnung zur Übersichtstabelle in JSL hinzufügen

Das Hauptproblem bei der JSL besteht darin, dass die schließenden Klammern für die Zusammenfassungsplattform die gesamte JSL für die Erstellung der neuen Spalten enthalten.Die Summary Platform muss vervollständigt werden und dann werden die neuen Spalten hinzugefügt.

Zweitens, da die Einzelheiten der tatsächlichen Namen für die Spalten in der Datentabelle, die in der Zusammenfassungsplattform erstellt werden, nicht erforderlich sind, die Komplexität des Codes zu verwenden, den Sie versuchen.In meinem Beispiel unten habe ich Ihren Code vereinfacht.

Drittens habe ich Ihren Code geändert, um Datentabellenreferenzen spezifischer zu machen, um den Code besser lesbar zu machen und um sicherzustellen, dass JMP genau weiß, an welcher Datentabelle gearbeitet werden soll.Außerdem habe ich die Verweise auf Spalten mit komplexen Namen aus der Struktur geändert

:Name( "name" )

zu

:"name"n

Dies ist die angekündigte Struktur, die in Zukunft verwendet wird.

Data Table( "semiconductor capability" ) << Summary(
 Group( :"90440011_119325"n ),
 N,
 Subgroup( :Sort_Lot ),
 Freq( "None" ),
 Weight( "None" ),
 Output Table( "New Table" )
);

Data Table( "New Table" ) << New Column( "GD1",
 Numeric,
 "Continuous",
 Formula( Sum( :"N(1)"n, :"N(2)"n, :"N(3)"n ) )
);

Current Data Table() << New Column( "Test",
 formula(
  If( Contains( Data Table( "New Table" ) << get column names( string ), "N(4)" ),
   Sum( :GD1, :"N(4)"n ),
   If( Contains( Data Table( "New Table" ) << get column names( string ), "N(5)" ),
    Sum( :GD1, :"N(5)"n ),
    Sum( :GD1 )
   )
  )
 )
);

 

 

Betreff: Berechnung zur Übersichtstabelle in JSL hinzufügen

Sehr klare Erklärung, sehr zu schätzen!