분포 플랫폼의 기하 평균에 대한 신뢰 구간여보세요,
배포 플랫폼에서 기하 평균에 대한 신뢰 구간을 얻을 수 있는 지름길이 있습니까?
해석학Re: 분포 플랫폼의 기하 평균에 대한 신뢰 구간해당 결과는 배포 플랫폼이나 JMP의 다른 위치에서 사용할 수 없습니다. 이 지침을 사용하여 계산을 스크립팅할 수 있습니다. DO 루프 블로그 게시물 . SAS/IML은 JMP JSL과 유사하므로 변환이 나쁘지 않습니다.
Re: 분포 플랫폼의 기하 평균에 대한 신뢰 구간안녕 마크,
빠른 피드백 정말 감사합니다.
Re: 분포 플랫폼의 기하 평균에 대한 신뢰 구간또 다른 방법은 JSL이 없지만 동일한 Log-Normal 분포를 가정하는 것입니다. 배포 플랫폼을 사용하여 데이터의 자연 로그를 분석합니다. 획득한 평균 및 신뢰 범위는 Exp를 통해 역변환될 수 있습니다. 결과 구간은 GM의 신뢰 구간입니다.
Re: 분포 플랫폼의 기하 평균에 대한 신뢰 구간세부 사항을 지침과 비교하지 않았습니다. @Mark_Bailey 따옴표를 사용할 수 있지만 부트스트랩도 시도할 수 있습니다(대화식으로 또는 JSL을 통해). 예를 들어:
NamesDefaultToHere(1);
// Get some data
dt = Open("$SAMPLE_DATA/Big Class.jmp");
// Use Distribution
dist = dt << Distribution(
Continuous Distribution(
Column( :height ),
Quantiles( 0 ),
Vertical( 0 ),
Outlier Box Plot( 0 ),
Customize Summary Statistics(
Mean( 0 ),
Std Dev( 0 ),
Std Err Mean( 0 ),
Upper Mean Confidence Interval( 0 ),
Lower Mean Confidence Interval( 0 ),
N( 0 ),
N Missing( 0 ),
Geometric Mean( 1 )
)
)
);
// Bootstrp the statistic in question (note 'dt2' is a list)
dt2 = Report(dist)[TableBox(1)] << Bootstrap(1000);
// Inspect the bootstrp distribution
dist2 = dt2[2] << runScript("Distribution");
// Get the confidence interval for the statistic by inspection or further JSL . . .Re: 분포 플랫폼의 기하 평균에 대한 신뢰 구간그리고 간격만 신경쓰면 이런 종류의 접근 방식을 사용하여 얻을 수 있습니다. 이는 부트스트랩의 일반성이 요구하는 모든 플랫폼 시작의 오버헤드가 없기 때문에 훨씬 빠릅니다.
NamesDefaultToHere(1);
// Get some data
dt = Open("$SAMPLE_DATA/Big Class.jmp");
n = NRow(dt);
dataVec = dt[0, "height"]; // Get the requisite data as a vector
nb = 100000; // Number of bootstrsp samples
gms = J(nb, 1, .); // Vector to hold the geometric mean of each bootstrap sample
for(s=1, s<=nb, s++, // Loop over bootstrap samples
pickMe = J(n, 1, RandomInteger(1, n)); // Indices of elements to compose this bootstrap sample
bootstrapSampleVec = dataVec[pickMe]; // Values in this bootstrap sample
gm = exp(Mean(ln(bootstrapSampleVec))); // Geometric mean of this bootstrap sample
gms[s] = gm;
);
gm95 = Quantile(0.95, gms);
gm05 = Quantile(0.05, gms);
Print("The Geometric Mean lies betweeen "||Char(Round(gm05, 3))||" and "||Char(Round(gm95, 3))||".");
아마도 이 코드는 더 빠르게 만들기 위해 병렬화될 수 있지만 일부 가독성이 손실됩니다.
Re: 분포 플랫폼의 기하 평균에 대한 신뢰 구간안녕 이안,
저건 완벽 해. 제안해 주셔서 감사합니다.
