Method not to display some part of the result of 'Unequal Variance'

IkjuShin

Is there good method not to display some part of the result of 'unequal variance'

For example, i don't want to display the row of Bartlett and the result of Welch's test

 

brady_brady

Ikju,

 

This can be done with JSL. Hiding Welch's test is pretty easy. Deleting Bartlett's test takes more code, since for some reason the <<delete row (n) message does not work on the table box (at least for me.)

 

Cheers,

Brady

Names Default To Here( 1 );
New Table( "untitled 4",
	Add Rows( 26 ),
	New Script(
		"Source",
		Data Table( "untitled 3" ) << Stack(
			columns( :Column 1, :Column 2 ),
			Source Label Column( "Label" ),
			Stacked Data Column( "Data" )
		)
	),
	New Column( "Label",
		Character,
		"Nominal",
		Set Values(
			{"Column 1", "Column 2", "Column 1", "Column 2", "Column 1", "Column 2",
			"Column 1", "Column 2", "Column 1", "Column 2", "Column 1", "Column 2",
			"Column 1", "Column 2", "Column 1", "Column 2", "Column 1", "Column 2",
			"Column 1", "Column 2", "Column 1", "Column 2", "Column 1", "Column 2",
			"Column 1", "Column 2"}
		)
	),
	New Column( "Data",
		Numeric,
		"Continuous",
		Format( "Best", 12 ),
		Set Values(
			[1, 2, 2, 4, 3, 6, 4, 8, 5, 10, 6, 12, 7, 14, 8, 16, 9, 18, 10, 20, 11, 22,
			12, 24, 13, 26]
		)
	)
);

ow = Oneway(
	Y( :Data ),
	X( :Label ),
	Means and Std Dev( 1 ),
	Unequal Variances( 1 ),
	Mean Error Bars( 1 ),
	Std Dev Lines( 1 )
);

rep = Report( ow );


//hide Welch's test
rep[Outline Box( "Welch's Test" )] << Set Title( "" ) << Close( 1 );

tb3 = rep[tablebox(3)];

//get names of columns in tablebox
cols = tb3 << get names;

//get numeric values, drop 4th row
mat = tb3 << getasmatrix;
mat = mat[1 :: 3, 0] |/ mat[5, 0];

//get test names, drop 4th row
names = tb3[String Col Box( 1 )] << get;
Remove From( names, 4 );

//delete the table box and write a new one without the 4th row
tb3 << delete;

rep[Outline Box( "Tests that the Variances are Equal" )] <<
append(
	tb1 = Table Box(
		String Col Box( cols[1], names ),
		Number Col Box( cols[2], mat[0, 1] ),
		Number Col Box( cols[3], mat[0, 2] ),
		Number Col Box( cols[4], mat[0, 3] ),
		Number Col Box( cols[5], mat[0, 4] )
	)
);
		
tb1[Number Col Box( 4 )] << set format( "Pvalue" ) <<
set conditional format( "pvalue" );