DoE를 생성할 때 각 열은 일반적으로 2~3개의 서로 다른 값(높은 값과 낮은 값, 경우에 따라 중앙 값)의 혼합입니다. 나 자신과 동료들에게 DoE 설정을 더 잘 설명하기 위해 각 열의 셀에 수동으로 색상을 지정합니다. 높은 값은 빨간색, 중간 값은 녹색, 낮은 값은 파란색으로 표시됩니다. 이 착색 과정을 자동화하는 것이 도움이 될 것입니다. 위의 설명에 따라 선택한 열의 셀에 색상을 지정하는 스크립트를 실행할 수 있기를 원합니다.이상적으로 스크립트는 선택한 여러 열에 대해 이 프로세스를 동시에 수행할 수 있어야 합니다. 그러한 스크립트가 어떻게 생겼는지에 대한 제안이 있습니까?
낮음, 높음(때로는 중간)을 어떻게 정의합니까? 항상 최대 3개의 값만 있습니까? 결정이 내려진 후에는 여기에 언급된 방법과 함께 값 색상 열 속성을 사용하여 스크립팅하는 것이 매우 간단해야 합니다. Eval Insert, Eval Expr, Parse 및 Substitute를 사용하여 한 표현식을 다른 표현식에 삽입 JMP 제공 코드 기반(<< 선택한 열 가져오기 및 루프 포함)
Data Table("Untitled 10"):Column 1 << Set Property(
"Value Colors",
{1 = -15113984, 2 = -5682409}
);
감사 @jthi ,
대부분의 경우 최대값과 최소값의 두 가지 값만 있습니다. 중심값이면 최소값과 최대값 사이의 산술 평균입니다.그만큼 값 색상 열 속성은 스크립팅 없이도 확실히 올바른 도구입니다. 여러 열에서 동시에 사용하면 프로세스가 확실히 간소화됩니다!
아래는 스크립트의 예입니다(Transform Each() 및 For Each()로 인해 JMP16 필요).
Names Default To Here(1);
If(Is Empty(Current Data Table()),
Throw("No tables open.");
, // else
dt = Current Data Table();
);
sel_cols = dt << Get Selected Columns();
If(N Items(sel_cols) == 0,
Throw("No columns selected");
);
// color "globals", fairly free to choose which type of "JMP Color" to use
LOW_COLOR = 67;
MIDDLE_COLOR = -13948116;
HIGH_COLOR = "Light Green";
For Each({col_ref}, sel_cols,
col_name = col_ref << get name; // I don't like using :COLNAME format at all
// get values in column
// Associative Array seems to have a bug so we use Summarize
Summarize(dt, val_strs = By(Column(col_name)));
// Summarize returns list of characters, so we will convert them to numbers
vals = Transform Each({val}, val_strs, Num(val));
min_val = Remove From(vals, 1)[1];
max_val = Remove From(vals, -1)[1];
// This method should be fairly robust, but it does looks complicated
weird_jmp_list = {};
Eval(Substitute(Expr(
Insert Into(weird_jmp_list, Expr(_value_ = _color_))
),
Expr(_value_), min_val,
Expr(_color_), LOW_COLOR
));
Eval(Substitute(Expr(
Insert Into(weird_jmp_list, Expr(_value_ = _color_))
),
Expr(_value_), max_val,
Expr(_color_), HIGH_COLOR
));
// color rest with middle color
For Each({val}, vals,
Eval(Substitute(Expr(
Insert Into(weird_jmp_list, Expr(_value_ = _color_))
),
Expr(_value_), val,
Expr(_color_), MIDDLE_COLOR
));
);
Column(dt, col_name) << set property( "Value Colors", weird_jmp_list) << Color Cell By Value(1);
);
감사!
직접 작동하는 완벽한 솔루션!
이것은 실제로 JMP에서 DOE 플랫폼의 일부여야 합니다. 위시리스트에 추가해도 괜찮을까요 @jthi ?
@Steffen_Bugge 새로운 아이디어가 떠오르면 위시리스트에 적어 두는 것이 좋습니다.
