583933_es-ES

liliconcom

Pregunta JSL: actualice las entradas de columna faltantes de otra columna

Hola a todos,

 

Necesito actualizar las entradas de columna que faltan en una tabla de datos, con entradas de otra columna anterior. Usando código JSL, y en JMP 14.

Aquí está el código que estoy tratando de trabajar, pero sigue arrojando el error "intentando asignar a un objeto... Acceso al valor L.."

Cualquier ayuda será apreciada..

 

dt=current data table();
Newcols={ "anew", "bnew", "cnew"};
oldcols={ "a", "b", "c"};
  
  
//---Update entries from old cols if new column entry is missing
For( k = 1 , k <= Length( oldcols ), k++,
    
  
  For Each Row(
   temp = column(dt, Newcols[k]); 
   oldc = column(dt, oldcols[k]);
   column (dt,Newcols[k]) = If( Is Missing( as column(dt,Newcols[k]) ) , oldc , temp) ;
   );
 );

 

 

Tabla de datossecuencias de comandosventanasRe: Pregunta de JSL: actualizar las entradas de columna faltantes de otra columna

Una opción sería usar << Establecer cada valor ()

Names Default To Here(1);

dt = New Table("Untitled",
 Add Rows(4),
 New Column("a", Numeric, "Continuous", Format("Best", 12), Set Values([1, 2, 3, 4])),
 New Column("b", Numeric, "Continuous", Format("Best", 12), Set Values([5, 6, 7, 8])),
 New Column("a2", Numeric, "Continuous", Format("Best", 12), Set Values([11, ., 33, 44])),
 New Column("b2", Numeric, "Continuous", Format("Best", 12), Set Values([., ., 77, .]))
);

wait(2); // demo purposes

new_cols = {"a2", "b2"};
old_cols = {"a", "b"};

For(i = 1, i <= N Items(old_cols), i++,
 Column(dt, new_cols[i]) << Set Each Value(
  If(Is Missing(AsColumn(Column(dt, new_cols[i]))),
   AsColumn(Column(dt, old_cols[i]))
  ,
   AsColumn(Column(dt, new_cols[i]))
  )
 )
);

Creo que debe proporcionar Columna con [] o [Row()] si desea agregar valores como sugirió

For(k = 1, k <= Length(old_cols), k++,
 For Each Row(
  new_col_val = Column(dt, new_cols[k])[];
  old_col_val = Column(dt, old_cols[k])[];
  Column(dt, new_cols[k])[] = If(Is Missing(new_col_val), old_col_val, new_col_val)
 )
);

o usar como columna

For(k = 1, k <= Length(old_cols), k++,
 For Each Row(
  new_col_val = AsColumn(dt, new_cols[k]);
  old_col_val = AsColumn(dt, old_cols[k]);
  AsColumn(dt, new_cols[k])[] = If(Is Missing(new_col_val), old_col_val, new_col_val)
 )
);

Re: Pregunta de JSL: actualizar las entradas de columna faltantes de otra columna

¡Muchas gracias, esto funcionó!