583933_zh-CN

liliconcom

JSL 问题：从另一列更新缺失的列条目

大家好，

 

我需要使用另一个旧列中的条目更新数据表中缺失的列条目。 使用 JSL 代码，并在 JMP 14 上。

这是我正在尝试工作的代码，但它一直在抛出错误“试图分配给一个对象...... L值访问..”

任何帮助将不胜感激..

 

dt=current data table();
Newcols={ "anew", "bnew", "cnew"};
oldcols={ "a", "b", "c"};
  
  
//---Update entries from old cols if new column entry is missing
For( k = 1 , k <= Length( oldcols ), k++,
    
  
  For Each Row(
   temp = column(dt, Newcols[k]); 
   oldc = column(dt, oldcols[k]);
   column (dt,Newcols[k]) = If( Is Missing( as column(dt,Newcols[k]) ) , oldc , temp) ;
   );
 );

 

 

数据表脚本视窗回复：JSL 问题：从另一列更新缺失的列条目

一种选择是使用 << Set Each Value()

Names Default To Here(1);

dt = New Table("Untitled",
 Add Rows(4),
 New Column("a", Numeric, "Continuous", Format("Best", 12), Set Values([1, 2, 3, 4])),
 New Column("b", Numeric, "Continuous", Format("Best", 12), Set Values([5, 6, 7, 8])),
 New Column("a2", Numeric, "Continuous", Format("Best", 12), Set Values([11, ., 33, 44])),
 New Column("b2", Numeric, "Continuous", Format("Best", 12), Set Values([., ., 77, .]))
);

wait(2); // demo purposes

new_cols = {"a2", "b2"};
old_cols = {"a", "b"};

For(i = 1, i <= N Items(old_cols), i++,
 Column(dt, new_cols[i]) << Set Each Value(
  If(Is Missing(AsColumn(Column(dt, new_cols[i]))),
   AsColumn(Column(dt, old_cols[i]))
  ,
   AsColumn(Column(dt, new_cols[i]))
  )
 )
);

如果你想像你建议的那样添加值，我认为你必须为 Column 提供 [] 或 [Row()]

For(k = 1, k <= Length(old_cols), k++,
 For Each Row(
  new_col_val = Column(dt, new_cols[k])[];
  old_col_val = Column(dt, old_cols[k])[];
  Column(dt, new_cols[k])[] = If(Is Missing(new_col_val), old_col_val, new_col_val)
 )
);

或使用 As Column

For(k = 1, k <= Length(old_cols), k++,
 For Each Row(
  new_col_val = AsColumn(dt, new_cols[k]);
  old_col_val = AsColumn(dt, old_cols[k]);
  AsColumn(dt, new_cols[k])[] = If(Is Missing(new_col_val), old_col_val, new_col_val)
 )
);

回复：JSL 问题：从另一列更新缺失的列条目

非常感谢，这有效！