583933_ja-JP

liliconcom

JSL の質問: 欠落している列エントリを別の列から更新する

こんにちは、みんな、

 

別の古い列のエントリを使用して、データ テーブル内の欠落している列エントリを更新する必要があります。 JSLコードを使用し、JMP 14で。

これが私が作業しようとしているコードですが、「オブジェクトに割り当てようとしています... L値アクセス..」

どんな助けでも大歓迎です..

 

dt=current data table();
Newcols={ "anew", "bnew", "cnew"};
oldcols={ "a", "b", "c"};
  
  
//---Update entries from old cols if new column entry is missing
For( k = 1 , k <= Length( oldcols ), k++,
    
  
  For Each Row(
   temp = column(dt, Newcols[k]); 
   oldc = column(dt, oldcols[k]);
   column (dt,Newcols[k]) = If( Is Missing( as column(dt,Newcols[k]) ) , oldc , temp) ;
   );
 );

 

 

データ表スクリプティングウィンドウズRe: JSL の質問: 欠落している列エントリを別の列から更新する

1つのオプションは、 << Set Each Value() を使用することです

Names Default To Here(1);

dt = New Table("Untitled",
 Add Rows(4),
 New Column("a", Numeric, "Continuous", Format("Best", 12), Set Values([1, 2, 3, 4])),
 New Column("b", Numeric, "Continuous", Format("Best", 12), Set Values([5, 6, 7, 8])),
 New Column("a2", Numeric, "Continuous", Format("Best", 12), Set Values([11, ., 33, 44])),
 New Column("b2", Numeric, "Continuous", Format("Best", 12), Set Values([., ., 77, .]))
);

wait(2); // demo purposes

new_cols = {"a2", "b2"};
old_cols = {"a", "b"};

For(i = 1, i <= N Items(old_cols), i++,
 Column(dt, new_cols[i]) << Set Each Value(
  If(Is Missing(AsColumn(Column(dt, new_cols[i]))),
   AsColumn(Column(dt, old_cols[i]))
  ,
   AsColumn(Column(dt, new_cols[i]))
  )
 )
);

あなたが提案したように値を追加したい場合は、Columnに[]または[Row()]を提供する必要があると思います

For(k = 1, k <= Length(old_cols), k++,
 For Each Row(
  new_col_val = Column(dt, new_cols[k])[];
  old_col_val = Column(dt, old_cols[k])[];
  Column(dt, new_cols[k])[] = If(Is Missing(new_col_val), old_col_val, new_col_val)
 )
);

または列として使用

For(k = 1, k <= Length(old_cols), k++,
 For Each Row(
  new_col_val = AsColumn(dt, new_cols[k]);
  old_col_val = AsColumn(dt, old_cols[k]);
  AsColumn(dt, new_cols[k])[] = If(Is Missing(new_col_val), old_col_val, new_col_val)
 )
);

Re: JSL の質問: 欠落している列エントリを別の列から更新する

どうもありがとう、これはうまくいきました！