583933_it-IT

liliconcom

Domanda JSL: aggiorna le voci di colonna mancanti da un'altra colonna

Ciao a tutti,

 

Devo aggiornare le voci di colonna mancanti in una tabella di dati, con le voci di un'altra colonna precedente. Utilizzando il codice JSL e su JMP 14.

Ecco il codice che sto cercando di lavorare, ma continua a generare errori "tentativo di assegnazione a un oggetto... Accesso al valore L.."

Qualsiasi aiuto sarà apprezzato..

 

dt=current data table();
Newcols={ "anew", "bnew", "cnew"};
oldcols={ "a", "b", "c"};
  
  
//---Update entries from old cols if new column entry is missing
For( k = 1 , k <= Length( oldcols ), k++,
    
  
  For Each Row(
   temp = column(dt, Newcols[k]); 
   oldc = column(dt, oldcols[k]);
   column (dt,Newcols[k]) = If( Is Missing( as column(dt,Newcols[k]) ) , oldc , temp) ;
   );
 );

 

 

Tabella datiScriptingfinestreOggetto: domanda JSL: aggiorna le voci di colonna mancanti da un'altra colonna

Un'opzione sarebbe usare << Imposta ogni valore ()

Names Default To Here(1);

dt = New Table("Untitled",
 Add Rows(4),
 New Column("a", Numeric, "Continuous", Format("Best", 12), Set Values([1, 2, 3, 4])),
 New Column("b", Numeric, "Continuous", Format("Best", 12), Set Values([5, 6, 7, 8])),
 New Column("a2", Numeric, "Continuous", Format("Best", 12), Set Values([11, ., 33, 44])),
 New Column("b2", Numeric, "Continuous", Format("Best", 12), Set Values([., ., 77, .]))
);

wait(2); // demo purposes

new_cols = {"a2", "b2"};
old_cols = {"a", "b"};

For(i = 1, i <= N Items(old_cols), i++,
 Column(dt, new_cols[i]) << Set Each Value(
  If(Is Missing(AsColumn(Column(dt, new_cols[i]))),
   AsColumn(Column(dt, old_cols[i]))
  ,
   AsColumn(Column(dt, new_cols[i]))
  )
 )
);

Penso che devi fornire Column con [] o [Row ()] se vuoi aggiungere valori come hai suggerito

For(k = 1, k <= Length(old_cols), k++,
 For Each Row(
  new_col_val = Column(dt, new_cols[k])[];
  old_col_val = Column(dt, old_cols[k])[];
  Column(dt, new_cols[k])[] = If(Is Missing(new_col_val), old_col_val, new_col_val)
 )
);

oppure usa Come colonna

For(k = 1, k <= Length(old_cols), k++,
 For Each Row(
  new_col_val = AsColumn(dt, new_cols[k]);
  old_col_val = AsColumn(dt, old_cols[k]);
  AsColumn(dt, new_cols[k])[] = If(Is Missing(new_col_val), old_col_val, new_col_val)
 )
);

Oggetto: domanda JSL: aggiorna le voci di colonna mancanti da un'altra colonna

Molte grazie, ha funzionato!