583933_fr-FR

liliconcom

Question JSL : Mettre à jour les entrées de colonne manquantes d'une autre colonne

Salut tout le monde,

 

Je dois mettre à jour les entrées de colonne manquantes dans une table de données, avec les entrées d'une autre colonne plus ancienne. En utilisant le code JSL, et sur JMP 14.

Voici le code que j'essaie de travailler, mais il continue de générer une erreur "tentative d'assignation à un objet ... Accès à la valeur L."

Toute aide serait appréciée..

 

dt=current data table();
Newcols={ "anew", "bnew", "cnew"};
oldcols={ "a", "b", "c"};
  
  
//---Update entries from old cols if new column entry is missing
For( k = 1 , k <= Length( oldcols ), k++,
    
  
  For Each Row(
   temp = column(dt, Newcols[k]); 
   oldc = column(dt, oldcols[k]);
   column (dt,Newcols[k]) = If( Is Missing( as column(dt,Newcols[k]) ) , oldc , temp) ;
   );
 );

 

 

Tableau de donnéesScriptles fenêtresRe : Question JSL : Mettre à jour les entrées de colonne manquantes d'une autre colonne

Une option serait d'utiliser << Set Each Value ()

Names Default To Here(1);

dt = New Table("Untitled",
 Add Rows(4),
 New Column("a", Numeric, "Continuous", Format("Best", 12), Set Values([1, 2, 3, 4])),
 New Column("b", Numeric, "Continuous", Format("Best", 12), Set Values([5, 6, 7, 8])),
 New Column("a2", Numeric, "Continuous", Format("Best", 12), Set Values([11, ., 33, 44])),
 New Column("b2", Numeric, "Continuous", Format("Best", 12), Set Values([., ., 77, .]))
);

wait(2); // demo purposes

new_cols = {"a2", "b2"};
old_cols = {"a", "b"};

For(i = 1, i <= N Items(old_cols), i++,
 Column(dt, new_cols[i]) << Set Each Value(
  If(Is Missing(AsColumn(Column(dt, new_cols[i]))),
   AsColumn(Column(dt, old_cols[i]))
  ,
   AsColumn(Column(dt, new_cols[i]))
  )
 )
);

Je pense que vous devez fournir Column avec [] ou [Row ()] si vous souhaitez ajouter des valeurs comme vous l'avez suggéré

For(k = 1, k <= Length(old_cols), k++,
 For Each Row(
  new_col_val = Column(dt, new_cols[k])[];
  old_col_val = Column(dt, old_cols[k])[];
  Column(dt, new_cols[k])[] = If(Is Missing(new_col_val), old_col_val, new_col_val)
 )
);

ou utilisez Comme colonne

For(k = 1, k <= Length(old_cols), k++,
 For Each Row(
  new_col_val = AsColumn(dt, new_cols[k]);
  old_col_val = AsColumn(dt, old_cols[k]);
  AsColumn(dt, new_cols[k])[] = If(Is Missing(new_col_val), old_col_val, new_col_val)
 )
);

Re : Question JSL : Mettre à jour les entrées de colonne manquantes d'une autre colonne

Merci beaucoup, cela a fonctionné!