579120_es-ES

liliconcom

Extraer números de una cadena

Hola,

 

Quiero extraer todos los números contenidos en [] y almacenarlos en la lista. ¿Hay alguna manera de lograr esto con jsl?

 

Me gustaría extraer números de la columna y almacenarlos en la lista que debería verse así:

 

contenedores = {"52","79","39 41 43", "38 40 42", "1"};

Cualquier consejo sería muy útil.

Gracias

Automatización y secuencias de comandosInvestigación del Consumidor y del MercadoRe: Extraer números de una cadena

Aquí hay otro enfoque. ¡Hay mucha capacidad para procesar cadenas, listas y columnas de datos en JMP!

 

Names Default to Here( 1 );'

// create sample
dt = New Table( "Sample",
 New Column( "Values", "Character", "Nominal",
  Values( { "", "", "[52]", "[79]", "[39 41 43]", "[38 40 42]", "", "", "", "[1]" } )
 )
);

// use sample
val = :Values << Get Values;

// find 
bins = List();

For( i = 1, i <= N Items( val ), i++,
 If( val[i] != "",
  Insert Into( bins,
   Substitute( val[i],
    "[", "",
    "]", ""
   );
  );
 );
);

Show( bins );

Re: Extraer números de una cadena

Gracias Jim

Re: Extraer números de una cadena

Hay un par de maneras diferentes de hacer esto.

 

Puede obtener los valores para su columna Valores en una lista usando el < a la columna

 

Deberá deshacerse de los valores faltantes de esa lista. Es fácil hacer esto localizando las filas que faltan en la tabla de datos con Obtener filas donde() . Entonces el Eliminar de() La función eliminará esos elementos de la lista.

 

Luego use For Each() y la función Word() para deshacerse de los corchetes (es decir, "[]").

 

dt = Data Table( "Sample.jmp" );

//locate the missing values
missings = dt << get rows where( Is Missing( :values ) );

//get a list of the Values column
lst = :Values << get values;

//Remove the missings from the list
Remove From( lst, As List( missings ) );

//strip the square brackets
For Each( {item, i}, lst, lst[i] = Word( 1, item, "[]" ) );

También puede hacer todo esto en la tabla de datos agregando una nueva columna de fórmula con la función Word() para eliminar los corchetes y luego obtener los valores de la nueva columna.

dt=Data Table("Sample.jmp");
new_col = dt << New Column( "New Values", Character,
 formula( Word( 1, :Values, "[]" ) )
);
lst = (new_col << get values)[dt <<
get rows where( !Is Missing( :New Values ) )];

La función Word() es mi favorita: Si aprende solo una función del Editor de fórmulas, Word() es la única

Re: Extraer números de una cadena

Aquí hay un ejemplo simple que lee en su tabla de datos de muestra y produce una lista con los valores

x = {"52", "79", "39", "41", "43", "38", "40", "42", "1"};

Names Default To Here( 1 );
dt = current data table();
x = {};
For Each Row(
 If( :values != "",
  y = Eval( Parse( :values ) );
  For Each( {value}, y, Insert Into( x, Char( value ) ) );
 )
);

Show( x );