Predicting an unknown from a trend line

ACooper

Simple question and would appreciate some assistance.  I am not a stats wiz.

 

 

the absorbance of the unknown is 0.027

I need to find the concentration of the unknown.

Someone, please just tell me what test to run and how to populate the cells of the test.

Thank you in advance.

A. Cooper

 

 

gzmorgan0

This is not a statistical test. This task is fitting a model, and equation, and estimating the unknown from the model.

1. See link https://www.wikihow.com/Calculate-Molar-Absorptivity
                Abs = e*l*Conc or Conc = k*Abs where k = 1/(e*l)
2. Main Menu >Analyze>Fit Y by X, specify Conc for Y and Abs for X, press OK
3. Find the red menu icon above the graph, select > Fit Special. Check the box next to Constrain the intercept to 0 , press OK
4. Find the red menu icon below the graph, select > Save Predicteds. The table now has the predicted values [points on the line] and there is a value for the last row where Abs = 0.027

If this is a class assignment, this method might not be what is expected of you. [Read your class notes.]  I attached a JSL script, with comments (green text) that describe the point and click steps to customize the report.

Names Default to Here(1);

//create the table
dt = New Table( "Fit",
	Add Rows( 6 ),
	New Column( "Conc",
		Numeric,
		"Continuous",
		Format( "Best", 12 ),
		Set Values( [0, 0.2, 0.5, 1, 2, .] )
	),
	New Column( "Abs",
		Numeric,
		"Continuous",
		Format( "Best", 12 ),
		Set Values( [0, 0.011, 0.063, 0.112, 0.243, 0.027] )
	)
);

//See link https://www.wikihow.com/Calculate-Molar-Absorptivity
//Abs = e*l*Conc or Conc = k*Abs where k = 1/(e*l)

//

//draw the graph
fm = dt <<  Fit Y by X(
	Y( :Conc ),
	X( :Abs )
);

//From the red inverted triangle menu icon, select> Fit Special, then check 
//the box to Constarin Intercept to 0
fm << Fit Special( Intercept( 0 ), {Line Color( {212, 73, 88} )} );

//From the red inverted triangle menu below the graph select > Save Predicteds
fm << (Curve[1] << Save Predicteds);

//Double click on the X-axis and check the boxes for Grid, Major and Minor
report(fm) [ScaleBox(1)] <<	{Label Row( {Show Major Grid( 1 ), Show Minor Grid( 1 )} )};

//Double click on the Y-axis and check the boxes for Grid, Major and Minor
report(fm) [ScaleBox(2)] <<	{Label Row( {Show Major Grid( 1 ), Show Minor Grid( 1 )} )};

//Double click on the X-axis again and in the lower box labeled Reference Lines
//enter 0.027, select a color and line style
report(fm) [ScaleBox(1)] <<	{Add Ref Line( 0.027, "Dotted", "Medium Dark Red", "", 2 )};

report(fm)[FrameBox(1)] <<	Add Text Annotation(
          Text( "Abs =0.027 \!N Pred Conc = 0.xxx" ),  //enter the predicted value 
		  Text Box( {85, 192, 199, 232} ),
		  Background Color( "Light Yellow" )
      );