578022_ko-KR

liliconcom

스크립트의 GR&R 계산

안녕,

JMP에서 계산하고 JMP 스크립트를 사용하여 변수에 저장해야 하는 GR&R 결과가 필요한 몇 가지 테스트 매개변수가 있습니다. 특히 스크립트의 변수로 GR&R 분석(아래 표시)에 보고된 값이 필요합니다. 스크립트에서 호출하여 해당 함수의 반환 값으로 이러한 결과(또는 그 중 일부)를 얻을 수 있는 함수가 있다고 가정합니다. 가변성 게이지 창을 스크립트로 저장해 보았으나 내용이 별로 도움이 되지 않는 것 같습니다(아래 복사). 누군가 스크립트를 사용하여 GR&R 결과를 변수에 저장하고 인쇄하는 방법을 보여줄 수 있습니까?

 

 

Variability Chart(
 Y( :"Check DUT Tx Output Power > Limit"n ),
 MSA Metadata(
  :"Check DUT Tx Output Power > Limit"n(
   Lower Tolerance( -10 ),
   Upper Tolerance( 8 ),
   Tolerance Range( 18 )
  )
 ),
 Model( "Crossed" ),
 X( :Operator, :UUT ),
 Variability Analysis(
  :"Check DUT Tx Output Power > Limit"n,
  "Gauge R&R Report"n( 1 )
 ),
 SendToReport(
  Dispatch(
   {"Variability Gauge Analysis for Check DUT Tx Output Power > Limit"},
   "Variability Chart for Check DUT Tx Output Power > Limit",
   OutlineBox,
   {Close( 1 )}
  ),
  Dispatch(
   {"Variability Gauge Analysis for Check DUT Tx Output Power > Limit",
   "Gauge R&R"},
   "Variance Components for Gauge R&R",
   OutlineBox,
   {Close( 1 )}
  )
 )
);

해석학Re: 스크립트의 GR&R 계산

다음은 R&R 보고서에서 데이터 벡터를 가져온 다음 새 보고서에 배치하는 간단한 예입니다.여기에서 필요한 데이터를 가져와서 스크립트의 다음 단계로 전달할 수 있어야 합니다.

names default to here(1);
dt = open("$SAMPLE_DATA/Variability Data/Gasket.jmp");

Variability Chart(invisible,
 Y( :Y ),
 X( :Operator, :Part ),
 Model( "Crossed" ),
 Historical Sigma( 0 ),
 Analysis Type( "Choose best analysis (EMS REML)" ),
 Connect Cell Means( 1 ),
 Show Grand Mean( 1 ),
 XBar Control Limits( 1 ),
 S Control Limits( 1 ),
 Mean of Std Dev( 1 ),
 Gauge RR( 6, 0, 0, 0 ),
 Gauge RR Report( 1 )
);
rp = Current Report();
// Get the Variation data from the Output Display
VariationText = rp["Gauge R&R"][StringColBox(1)] << get;
Variation = rp["Gauge R&R"][NumberColBox(2)] << get;
// Get the Summary and Gauge R&R Statistics
Stats = rp["Gauge R&R"][NumberColBox(5)] << get;
StatsText = rp["Gauge R&R"][StringColBox(5)] << get;

// Build a new report
NW = New Window("my report",
 table box(
  string col box("Meas Source", variationText),
  number col box("Variation", variation)
 ),
 spacer box(0,20),
 table box(
  number col box("", stats), string col box("", statsText)
 )
);

rp << close window;

표시 객체의 읽기 및 조작은 도움말 풀다운 메뉴에서 사용할 수 있는 JMP 설명서 라이브러리의 스크립팅 가이드에 설명되어 있습니다.