578022_ja-JP

liliconcom

スクリプトでの GR&R 計算

やあ、

JMPスクリプトを使用して、JMPによって計算され、変数に格納されたGR&R結果が必要ないくつかのテストパラメータがあります。 具体的には、スクリプトの変数として GR&R 分析 (以下に示す) で報告された値が必要です。 スクリプトで呼び出すことにより、これらの結果 (またはその一部) をその関数の戻り値として取得できる関数があると仮定します。 Variability Gauge ウィンドウをスクリプトとして保存しようとしましたが、内容が役に立たないようです (以下にコピー)。 スクリプトを使用して GR&R の結果を変数に保存し、出力する方法を教えてもらえますか?

 

 

Variability Chart(
 Y( :"Check DUT Tx Output Power > Limit"n ),
 MSA Metadata(
  :"Check DUT Tx Output Power > Limit"n(
   Lower Tolerance( -10 ),
   Upper Tolerance( 8 ),
   Tolerance Range( 18 )
  )
 ),
 Model( "Crossed" ),
 X( :Operator, :UUT ),
 Variability Analysis(
  :"Check DUT Tx Output Power > Limit"n,
  "Gauge R&R Report"n( 1 )
 ),
 SendToReport(
  Dispatch(
   {"Variability Gauge Analysis for Check DUT Tx Output Power > Limit"},
   "Variability Chart for Check DUT Tx Output Power > Limit",
   OutlineBox,
   {Close( 1 )}
  ),
  Dispatch(
   {"Variability Gauge Analysis for Check DUT Tx Output Power > Limit",
   "Gauge R&R"},
   "Variance Components for Gauge R&R",
   OutlineBox,
   {Close( 1 )}
  )
 )
);

分析Re: スクリプトでの GR&R 計算

以下は、R&R レポートからデータのベクトルを取得し、それを新しいレポートに配置する簡単な例です。ここから、必要なデータを取得して、スクリプトの次のステップに渡すことができるはずです。

names default to here(1);
dt = open("$SAMPLE_DATA/Variability Data/Gasket.jmp");

Variability Chart(invisible,
 Y( :Y ),
 X( :Operator, :Part ),
 Model( "Crossed" ),
 Historical Sigma( 0 ),
 Analysis Type( "Choose best analysis (EMS REML)" ),
 Connect Cell Means( 1 ),
 Show Grand Mean( 1 ),
 XBar Control Limits( 1 ),
 S Control Limits( 1 ),
 Mean of Std Dev( 1 ),
 Gauge RR( 6, 0, 0, 0 ),
 Gauge RR Report( 1 )
);
rp = Current Report();
// Get the Variation data from the Output Display
VariationText = rp["Gauge R&R"][StringColBox(1)] << get;
Variation = rp["Gauge R&R"][NumberColBox(2)] << get;
// Get the Summary and Gauge R&R Statistics
Stats = rp["Gauge R&R"][NumberColBox(5)] << get;
StatsText = rp["Gauge R&R"][StringColBox(5)] << get;

// Build a new report
NW = New Window("my report",
 table box(
  string col box("Meas Source", variationText),
  number col box("Variation", variation)
 ),
 spacer box(0,20),
 table box(
  number col box("", stats), string col box("", statsText)
 )
);

rp << close window;

表示オブジェクトの読み取りと操作については、ヘルプ プルダウン メニューからアクセスできる JMP ドキュメント ライブラリのスクリプト ガイドに記載されています。