Ciao,
Ho diversi parametri di test per i quali ho bisogno dei loro risultati GR&R calcolati da JMP e memorizzati in una variabile, utilizzando lo script JMP. Nello specifico, ho bisogno dei valori riportati sull'analisi GR&R (mostrata sotto) come variabili in uno script. Presumo che esista una funzione che chiamandola in uno script posso ottenere questi risultati (o alcuni di essi) come valore di ritorno di quella funzione. Ho provato a salvare la finestra Variability Gauge come script, ma i contenuti non sembrano utili (copiati sotto). Qualcuno può mostrarmi come utilizzare gli script per memorizzare i risultati GR&R in una variabile e stamparli?
Variability Chart(
Y( :"Check DUT Tx Output Power > Limit"n ),
MSA Metadata(
:"Check DUT Tx Output Power > Limit"n(
Lower Tolerance( -10 ),
Upper Tolerance( 8 ),
Tolerance Range( 18 )
)
),
Model( "Crossed" ),
X( :Operator, :UUT ),
Variability Analysis(
:"Check DUT Tx Output Power > Limit"n,
"Gauge R&R Report"n( 1 )
),
SendToReport(
Dispatch(
{"Variability Gauge Analysis for Check DUT Tx Output Power > Limit"},
"Variability Chart for Check DUT Tx Output Power > Limit",
OutlineBox,
{Close( 1 )}
),
Dispatch(
{"Variability Gauge Analysis for Check DUT Tx Output Power > Limit",
"Gauge R&R"},
"Variance Components for Gauge R&R",
OutlineBox,
{Close( 1 )}
)
)
);Ecco un semplice esempio che estrae un vettore di dati dal report R&R e lo inserisce in un nuovo report.Dovresti essere in grado di andare da qui solo per ottenere i dati di cui hai bisogno e passarli ai passaggi successivi del tuo script.
names default to here(1);
dt = open("$SAMPLE_DATA/Variability Data/Gasket.jmp");
Variability Chart(invisible,
Y( :Y ),
X( :Operator, :Part ),
Model( "Crossed" ),
Historical Sigma( 0 ),
Analysis Type( "Choose best analysis (EMS REML)" ),
Connect Cell Means( 1 ),
Show Grand Mean( 1 ),
XBar Control Limits( 1 ),
S Control Limits( 1 ),
Mean of Std Dev( 1 ),
Gauge RR( 6, 0, 0, 0 ),
Gauge RR Report( 1 )
);
rp = Current Report();
// Get the Variation data from the Output Display
VariationText = rp["Gauge R&R"][StringColBox(1)] << get;
Variation = rp["Gauge R&R"][NumberColBox(2)] << get;
// Get the Summary and Gauge R&R Statistics
Stats = rp["Gauge R&R"][NumberColBox(5)] << get;
StatsText = rp["Gauge R&R"][StringColBox(5)] << get;
// Build a new report
NW = New Window("my report",
table box(
string col box("Meas Source", variationText),
number col box("Variation", variation)
),
spacer box(0,20),
table box(
number col box("", stats), string col box("", statsText)
)
);
rp << close window;
La lettura e la manipolazione degli oggetti Display è documentata nella Guida allo scripting nella Libreria della documentazione di JMP, disponibile nel menu a discesa Guida.
