578022_de-DE

liliconcom

GR&R-Berechnung im Skript

Hallo,

Ich habe mehrere Testparameter, deren GR&R-Ergebnisse von JMP berechnet und mithilfe des JMP-Skripts in einer Variablen gespeichert werden müssen. Insbesondere benötige ich die in der GR&R-Analyse (siehe unten) gemeldeten Werte als Variablen in einem Skript. Ich gehe davon aus, dass es eine Funktion gibt, mit deren Aufruf ich in einem Skript diese Ergebnisse (oder einige davon) als Rückgabewert dieser Funktion erhalten kann. Ich habe versucht, das Fenster „Variabilitätsanzeige“ als Skript zu speichern, aber der Inhalt scheint nicht hilfreich zu sein (unten kopiert). Kann mir jemand zeigen, wie man mithilfe von Skripten die GR&R-Ergebnisse in einer Variablen speichert und ausdruckt?

 

 

Variability Chart(
 Y( :"Check DUT Tx Output Power > Limit"n ),
 MSA Metadata(
  :"Check DUT Tx Output Power > Limit"n(
   Lower Tolerance( -10 ),
   Upper Tolerance( 8 ),
   Tolerance Range( 18 )
  )
 ),
 Model( "Crossed" ),
 X( :Operator, :UUT ),
 Variability Analysis(
  :"Check DUT Tx Output Power > Limit"n,
  "Gauge R&R Report"n( 1 )
 ),
 SendToReport(
  Dispatch(
   {"Variability Gauge Analysis for Check DUT Tx Output Power > Limit"},
   "Variability Chart for Check DUT Tx Output Power > Limit",
   OutlineBox,
   {Close( 1 )}
  ),
  Dispatch(
   {"Variability Gauge Analysis for Check DUT Tx Output Power > Limit",
   "Gauge R&R"},
   "Variance Components for Gauge R&R",
   OutlineBox,
   {Close( 1 )}
  )
 )
);

Automatisierung und SkripterstellungInhaltsorganisationErgebnisse teilen und kommunizierenBetreff: GR&R-Berechnung im Skript

Hier ist ein einfaches Beispiel, das einen Datenvektor aus dem R&R-Bericht abruft und ihn dann in einen neuen Bericht einfügt.Von hier aus sollten Sie in der Lage sein, nur die Daten abzurufen, die Sie benötigen, und sie an die nächsten Schritte in Ihrem Skript weiterzugeben.

names default to here(1);
dt = open("$SAMPLE_DATA/Variability Data/Gasket.jmp");

Variability Chart(invisible,
 Y( :Y ),
 X( :Operator, :Part ),
 Model( "Crossed" ),
 Historical Sigma( 0 ),
 Analysis Type( "Choose best analysis (EMS REML)" ),
 Connect Cell Means( 1 ),
 Show Grand Mean( 1 ),
 XBar Control Limits( 1 ),
 S Control Limits( 1 ),
 Mean of Std Dev( 1 ),
 Gauge RR( 6, 0, 0, 0 ),
 Gauge RR Report( 1 )
);
rp = Current Report();
// Get the Variation data from the Output Display
VariationText = rp["Gauge R&R"][StringColBox(1)] << get;
Variation = rp["Gauge R&R"][NumberColBox(2)] << get;
// Get the Summary and Gauge R&R Statistics
Stats = rp["Gauge R&R"][NumberColBox(5)] << get;
StatsText = rp["Gauge R&R"][StringColBox(5)] << get;

// Build a new report
NW = New Window("my report",
 table box(
  string col box("Meas Source", variationText),
  number col box("Variation", variation)
 ),
 spacer box(0,20),
 table box(
  number col box("", stats), string col box("", statsText)
 )
);

rp << close window;

Das Lesen und Bearbeiten von Anzeigeobjekten ist im Skripthandbuch in der JMP-Dokumentationsbibliothek dokumentiert, das im Pulldown-Menü „Hilfe“ verfügbar ist.