Salut,
J'ai plusieurs paramètres de test pour lesquels j'ai besoin de leurs résultats GR&R calculés par JMP et stockés dans une variable, à l'aide du script JMP. Plus précisément, j'ai besoin des valeurs rapportées sur l'analyse GR&R (illustrées ci-dessous) en tant que variables dans un script. Je suppose qu'il existe une fonction qui, en l'appelant dans un script, peut obtenir ces résultats (ou certains d'entre eux) comme valeur de retour de cette fonction. J'ai essayé d'enregistrer la fenêtre de la jauge de variabilité en tant que script, mais le contenu ne semble pas utile (copié ci-dessous). Quelqu'un peut-il me montrer comment utiliser des scripts pour stocker les résultats GR&R dans une variable et les imprimer ?
Variability Chart(
Y( :"Check DUT Tx Output Power > Limit"n ),
MSA Metadata(
:"Check DUT Tx Output Power > Limit"n(
Lower Tolerance( -10 ),
Upper Tolerance( 8 ),
Tolerance Range( 18 )
)
),
Model( "Crossed" ),
X( :Operator, :UUT ),
Variability Analysis(
:"Check DUT Tx Output Power > Limit"n,
"Gauge R&R Report"n( 1 )
),
SendToReport(
Dispatch(
{"Variability Gauge Analysis for Check DUT Tx Output Power > Limit"},
"Variability Chart for Check DUT Tx Output Power > Limit",
OutlineBox,
{Close( 1 )}
),
Dispatch(
{"Variability Gauge Analysis for Check DUT Tx Output Power > Limit",
"Gauge R&R"},
"Variance Components for Gauge R&R",
OutlineBox,
{Close( 1 )}
)
)
);Voici un exemple simple qui extrait un vecteur de données du rapport R&R, puis le place dans un nouveau rapport.À partir de là, vous devriez pouvoir obtenir les données dont vous avez besoin et les transmettre aux étapes suivantes de votre script.
names default to here(1);
dt = open("$SAMPLE_DATA/Variability Data/Gasket.jmp");
Variability Chart(invisible,
Y( :Y ),
X( :Operator, :Part ),
Model( "Crossed" ),
Historical Sigma( 0 ),
Analysis Type( "Choose best analysis (EMS REML)" ),
Connect Cell Means( 1 ),
Show Grand Mean( 1 ),
XBar Control Limits( 1 ),
S Control Limits( 1 ),
Mean of Std Dev( 1 ),
Gauge RR( 6, 0, 0, 0 ),
Gauge RR Report( 1 )
);
rp = Current Report();
// Get the Variation data from the Output Display
VariationText = rp["Gauge R&R"][StringColBox(1)] << get;
Variation = rp["Gauge R&R"][NumberColBox(2)] << get;
// Get the Summary and Gauge R&R Statistics
Stats = rp["Gauge R&R"][NumberColBox(5)] << get;
StatsText = rp["Gauge R&R"][StringColBox(5)] << get;
// Build a new report
NW = New Window("my report",
table box(
string col box("Meas Source", variationText),
number col box("Variation", variation)
),
spacer box(0,20),
table box(
number col box("", stats), string col box("", statsText)
)
);
rp << close window;
La lecture et la manipulation des objets Display sont documentées dans le Guide de création de scripts de la bibliothèque de documentation JMP, disponible dans le menu déroulant Aide.
