255334_ja-JP

liliconcom

グラフ ビルダー: 動的注釈配置の軸の最大、最小、および範囲の計算

JMP コミュニティの皆様、こんにちは。

 

変数 (:VAR_CAT) に基づいてグループ化された 1 つのテーブルの一連の列からデータをプロットし、グラフ ビルダーを使用して別のテーブルからテキストを動的に追加するスクリプトがあります。 このスクリプトはうまく機能しますが、動的に追加されたテキストの縦方向の配置に問題がありました (以下のスクリプトを参照)。

 

具体的には、次のようなさまざまなアプローチを試しました。

1. YMax = 列平均 (YCOL) + (列標準偏差 (YCOL)/sqrt(列番号 (YCOL)));しかし、これは、Overlay 変数によって定義されたサブセットではなく、列全体の YMAX を返すため、十分に機能しません。 --> グループ化されたデータの実際の Y 軸の最大値を動的に計算するための正しいコード行は何でしょうか?オーバーレイ カテゴリ (「By」オプションは For Each Row 構造内でのみ機能することを知っています)?
2. YMAX = レポート (gb)[軸ボックス (2)] << Get Max;これは、GB Y 軸の実際の最大値を取得しますが、このアプローチでは、式をもう一度評価する必要があり、効率的またはエレガントに見えません。

Names Default to Here (1);

dt1 = Data Table ("DATA_TABLE.JMP");
dt2 = Data Table ("PVALUE_TABLE.JMP");
CList = dt1 << Get Column Names(string);

 gbe = Expr (Graph Builder(
    Size( 497, 507 ),
    Variables(
     X( :DURATION ),
     Y( _YS_ ),
     Overlay( :VAR_CAT ),
     Interval( _ES_)
    ),
    Elements( Points( X, Y, Legend( 9 ) ), Line( X, Y, Legend( 11 ) ) ),
    SendToReport(
     Dispatch(
      {},
      _LABEL_,
      ScaleBox,
      {Add Ref Line( 0, "Dotted", "Black", "", 2 )}
     ),
     Dispatch(
      {},
      "DURATION",
      ScaleBox,
      {Min( -1.0 ), Max( 16 ), Inc( 2 ), Minor Ticks( 0 )}
     ),
     Dispatch(
      {},
      "400",
      ScaleBox,
      {Legend Model(
       9,
       Base( 0, 0, 0, Item ID( "CAT1", 1 ) ),
       Base( 1, 0, 0, Item ID( "CAT2", 1 ) )
      )}
     ),
     
     Dispatch(
      {},
      "Graph Builder",
      FrameBox,
      {Marker Size( 6 ), Add Graphics Script(
       2,
       Description( "Script" ),
       Text( Center Justified, {3.8, _TP_}, _TXT1_ );
       Text( Center Justified, {13.6, _TP_}, _TXT2_ );
      ), Grid Line Order( 1 ), Reference Line Order( 3 )}
     )
    )
   )
  );
For (i = 5, i <= 96, i++, //96

 YCOL = Column (dt1, i);
 ECOL = Column (dt1, i+92);
 LBL = CList [i];
 
 YMax = Col Mean (YCOL) + (Col Std Dev (YCOL)/sqrt(Col Number(YCOL)));
 YMin = Col Mean (YCOL) - (Col Std Dev (YCOL)/sqrt(Col Number(YCOL)));
 
 YRANGE = abs (YMax - Y Min);
 
 If (YRANGE < 1.0, 
       YMax = YMax + 0.5;
       YMin = YMin - 0.3 
       );
 
 TOPY = YMax-0.1;
 
 
 PVAL1 = "p VAL " || CHAR(Format(Column(dt2, 2)[i-4], "PValue"));
 PVAL2 = "p VAL " || CHAR(Format(Column(dt2, 3)[i-4], "PValue"));
 
 gbx = Substitute (Name Expr (gbe),  Expr (_YS_), YCOL,
          Expr (_ES_), ECOL,
          Expr (_LABEL_), LBL,
          Expr (_TP_), TOPY,
          Expr (_TXT1_), PVAL1,
          Expr (_TXT2_), PVAL2
           
     );
 gb = Eval (gbx);
 
 Yaxis = report (gb)[Axis Box (2)];
 
 LocYMin = Yaxis << Get Min;
 LocYMax = Yaxis << Get Max;
 
 LocRange = LocYMax - LocYMin;
 
 mytitle = substitute (LBL, "Least Sq Mean LOG2 FC ", "");
 
 report (gb) [OutlineBox (1)] << Set Title (mytitle);
  
 if(abs (LocRange) < 1.0, 
  Yaxis << Max (LocYMax + 0.5);
  Yaxis << Min (LocYMin - 0.3);
  Yaxis << Inc (0.2),.);

 
 gb << Journal;
 gb << close window;
 

);   

Re: グラフ ビルダー: 動的注釈配置の軸の最大、最小、および範囲の計算

軸ボックスに直接尋ねることもできます:

 

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
biv = Bivariate( Y( :weight ), X( :height ), FitLine );
rbiv = biv << report;
axisbox = rbiv[axis box( 1 )];
axisbox << Get Max;

([ヘルプ] > [スクリプト インデックス] から)

Re: グラフ ビルダー: 動的注釈配置の軸の最大、最小、および範囲の計算

軸ボックスのスクリプトを取得してから、Min() および Max() 設定の引数を見つけることができます。

 

dt = Open( "$SAMPLE_DATA\Big Class.jmp" );
biv = Bivariate( Y( :weight ), X( :height ), Fit Line( {Line Color( {212, 73, 88} )} ) );
y_axis_script = Report( biv )[axis box( 1 )] << get script;

/*
y_axis_script will be a list: {Scale( "Linear" ), Format( "Fixed Dec", 12, 0 ), Min( 60 ), Max( 180 ),
Interval( "Numeric" ), Inc( 20 ), Minor Ticks( 0 ), Label Row Nesting( 1 ),
Label Row(
 {Automatic Font Size( 0 ), Automatic Tick Marks( 0 ), Inside Ticks( 0 ),
 Label Alignment( "Near" ), Label Buffer Scale( 1 ),
 Label Orientation( "Horizontal" ), Lax Label Range( 0 ),
 Major Grid Line Color( -14145495 ), Minimum Depth( 0 ), Minimum Font Size( 8 ),
 Minor Grid Line Color( -15790320 ), Show Major Grid( 0 ), Show Major Labels( 1 ),
 Show Major Ticks( 1 ), Show Minor Grid( 0 ), Show Minor Labels( 0 ),
 Show Minor Ticks( 1 ), Tick Offset( 0 ), Wrap Lines( 0 )}
)}
*/

//get the arguments for the 3rd and 4th elements of that list
minimum = Arg( y_axis_script[3], 1 );
maximum = Arg( y_axis_script[4], 1 );

 

Re: グラフ ビルダー: 動的注釈配置の軸の最大、最小、および範囲の計算やあ、
この提案を提供していただきありがとうございますが、それが私の問題に対処しているとは思いません。 問題の明確な説明を提供していない可能性があります。達成しようとしているのは、データから計算するか、GB から Y 軸の最大値を抽出して、動的なテキスト スクリプト コンテンツをグラフに正確に配置することです。

プロットに動的に注釈を付けるには、テキスト スクリプトを直接使用する代わりに、キャプション ボックスを使用するべきだと提案したのかもしれません。 その場合、キャプション ボックスのテキスト コンテンツを動的に置き換えることができるかどうかはわかりません (間違っている場合は修正してください)。

ご協力ありがとうございました。
心から、
TSRe: グラフ ビルダー: 動的注釈配置の軸の最大、最小、および範囲の計算

これらのいずれかをグラフ ビルダーの要素リストに追加してみてください。

Caption Box( Y, Legend( 4 ), Summary Statistic( "Max" ) )

それで：

gbe = Expr (Graph Builder(
    Size( 497, 507 ),
    Variables(
     X( :DURATION ),
     Y( _YS_ ),
     Overlay( :VAR_CAT ),
     Interval( _ES_)
    ),
    Elements(
                                  Points( X, Y, Legend( 9 ) ),
                                  Line( X, Y, Legend( 11),
                                  Caption Box( Y, Legend( 4 ), Summary Statistic( "Max" ) )<BR />                ) ),<BR />//the&nbsp;rest&nbsp;of&nbsp;your&nbsp;code

これは、グラフ ビルダーを右クリックしてキャプション ボックスを追加することで、視覚的に行うことができます。 次に、左側のリストで要約統計量を必要なものに変更し、計算に使用する変数を変更します。